emacs-orgmode@gnu.org archives
 help / color / mirror / code / Atom feed
* Contribution: ob-groovy.el
@ 2013-12-26 21:25 Miro Bezjak
  2013-12-27  0:08 ` Thomas S. Dye
  0 siblings, 1 reply; 9+ messages in thread
From: Miro Bezjak @ 2013-12-26 21:25 UTC (permalink / raw)
  To: emacs-orgmode


[-- Attachment #1.1: Type: text/plain, Size: 855 bytes --]

Hi all,

I would like to contribute org-babel functions for Groovy evaluation. I
simply
copy/pasted ob-scala.el and made appropriate changes.

I'm attaching ob-groovy.el as a file.

All 3 tests pass, although I haven't created `testing/test-ob-groovy.el` -
I'll
look into that.

--- testing last result ----------------
#+BEGIN_SRC groovy
println "ignored"
1 + 2
#+END_SRC

#+RESULTS:
: 3
----------------------------------------

--- testing results output --------------
#+BEGIN_SRC groovy :results output
println '1'
println '2'
println 1 + 2
#+END_SRC

#+RESULTS:
=1
2
3
----------------------------------------

--- testing table ----------------------
#+BEGIN_SRC groovy :results verbatim raw
"""
| 1 | 2
|--
| a | b
""".trim()
#+END_SRC

#+RESULTS:
| 1 | 2 |
|---+---|
| a | b |
----------------------------------------


Kind Regards,
Miro Bezjak

[-- Attachment #1.2: Type: text/html, Size: 1163 bytes --]

[-- Attachment #2: ob-groovy.el --]
[-- Type: text/x-emacs-lisp, Size: 4348 bytes --]

;;; ob-groovy.el --- org-babel functions for Groovy evaluation

;; Copyright (C) 2013 Free Software Foundation, Inc.

;; Author: Miro Bezjak
;; Keywords: literate programming, reproducible research
;; Homepage: http://orgmode.org

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:
;; Currently only supports the external execution.  No session support yet.

;;; Requirements:
;; - Groovy language :: http://groovy.codehaus.org
;; - Groovy major mode :: Can be installed from MELPA or
;;   https://github.com/russel/Emacs-Groovy-Mode

;;; Code:
(require 'ob)
(eval-when-compile (require 'cl))

(defvar org-babel-tangle-lang-exts) ;; Autoloaded
(add-to-list 'org-babel-tangle-lang-exts '("groovy" . "groovy"))
(defvar org-babel-default-header-args:groovy '())
(defvar org-babel-groovy-command "groovy"
  "Name of the command to use for executing Groovy code.")

(defun org-babel-execute:groovy (body params)
  "Execute a block of Groovy code with org-babel.  This function is
called by `org-babel-execute-src-block'"
  (message "executing Groovy source code block")
  (let* ((processed-params (org-babel-process-params params))
         (session (org-babel-groovy-initiate-session (nth 0 processed-params)))
         (vars (nth 1 processed-params))
         (result-params (nth 2 processed-params))
         (result-type (cdr (assoc :result-type params)))
         (full-body (org-babel-expand-body:generic
                     body params))
         (result (org-babel-groovy-evaluate
                  session full-body result-type result-params)))

    (org-babel-reassemble-table
     result
     (org-babel-pick-name
      (cdr (assoc :colname-names params)) (cdr (assoc :colnames params)))
     (org-babel-pick-name
      (cdr (assoc :rowname-names params)) (cdr (assoc :rownames params))))))


(defun org-babel-groovy-table-or-string (results)
  "Convert RESULTS into an appropriate elisp value.
If RESULTS look like a table, then convert them into an
Emacs-lisp table, otherwise return the results as a string."
  (org-babel-script-escape results))


(defvar org-babel-groovy-wrapper-method

  "class Runner extends Script {
    def out = new PrintWriter(new ByteArrayOutputStream())
    def run() { %s }
}

println(new Runner().run())
")


(defun org-babel-groovy-evaluate
  (session body &optional result-type result-params)
  "Evaluate BODY in external Groovy process.
If RESULT-TYPE equals 'output then return standard output as a string.
If RESULT-TYPE equals 'value then return the value of the last statement
in BODY as elisp."
  (when session (error "Sessions are not (yet) supported for Groovy"))
  (case result-type
    (output
     (let ((src-file (org-babel-temp-file "groovy-")))
       (progn (with-temp-file src-file (insert body))
              (org-babel-eval
               (concat org-babel-groovy-command " " src-file) ""))))
    (value
     (let* ((src-file (org-babel-temp-file "groovy-"))
            (wrapper (format org-babel-groovy-wrapper-method body)))
       (with-temp-file src-file (insert wrapper))
       (let ((raw (org-babel-eval
                   (concat org-babel-groovy-command " " src-file) "")))
         (org-babel-result-cond result-params
	   raw
           (org-babel-groovy-table-or-string raw)))))))


(defun org-babel-prep-session:groovy (session params)
  "Prepare SESSION according to the header arguments specified in PARAMS."
  (error "Sessions are not (yet) supported for Groovy"))

(defun org-babel-groovy-initiate-session (&optional session)
  "If there is not a current inferior-process-buffer in SESSION
then create.  Return the initialized session.  Sessions are not
supported in Groovy."
  nil)

(provide 'ob-groovy)



;;; ob-groovy.el ends here

^ permalink raw reply	[flat|nested] 9+ messages in thread
end of thread, other threads:[~2014-03-17 15:42 UTC | newest]

Thread overview: 9+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2013-12-26 21:25 Contribution: ob-groovy.el Miro Bezjak
2013-12-27  0:08 ` Thomas S. Dye
2013-12-27 16:44   ` Miro Bezjak
2013-12-27 17:40     ` Thomas S. Dye
2013-12-28 16:12       ` Eric Schulte
2013-12-28 23:47         ` Miro Bezjak
2013-12-30  2:53           ` Eric Schulte
2014-03-17 14:23             ` Miro Bezjak
2014-03-17 15:42               ` Bastien

Code repositories for project(s) associated with this public inbox

	https://git.savannah.gnu.org/cgit/emacs/org-mode.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).