emacs-orgmode@gnu.org archives
 help / color / mirror / code / Atom feed
* Please test links
@ 2008-03-15  8:24 Carsten Dominik
  2008-03-15  9:31 ` Leo
                   ` (2 more replies)
  0 siblings, 3 replies; 18+ messages in thread
From: Carsten Dominik @ 2008-03-15  8:24 UTC (permalink / raw)
  To: org-mode mailing list

Hi,

I have been busy and have split out most of the linking code
in org.el into separate files.  As I am not using most of
the link types myself, I would appreciate if people could systematically
test all link types they are using:  The following link types are
in separate files now:

org-bbdb.el
org-gnus.el
org-info.el
org-irc.el
org-mac-message.el
org-mhe.el
org-rmail.el
org-vm.el
org-wl.el


Please report back which of these link types you are using, and
if they are still working after a pull in your it repo.
If not, I'd appreciate detailed backtraces so that this remaining
issues can be fixed.

Thanks!

- Carsten

P.S. if things are really broken, you can always switch back to an
earlier version in the repo, for example using

git checkout release_5.23a

^ permalink raw reply	[flat|nested] 18+ messages in thread
* Re: Please test links
@ 2008-03-16 14:47 Tokuya Kameshima
  2008-03-17  7:39 ` Carsten Dominik
  0 siblings, 1 reply; 18+ messages in thread
From: Tokuya Kameshima @ 2008-03-16 14:47 UTC (permalink / raw)
  To: Carsten Dominik, emacs-orgmode; +Cc: kames

Hi Carsten,

I checked org-wl.el and it works fine.

BTW, I have another implementation of org-wl.el.  Is it possible to
merge my version to the git?

The differences between git version and mine are:

- Integrated `org-wl-open' function into `org-wl-open'.
- org-wl-store-link: If the message on the cursor line is marked as
  refile ("o"), set the link's folder to the refile destionation
  folder.  I prefer this behavior since I read the email in the inbox
  folder, set the refile mark, and create TODO task using remember
  package from the email before performing the refile operation.
  After I create tasks, I execute the refile.
- Fixed "To:" field extraction problem where the function
  `elmo-message-entity-field' returns a string or a list of strings.
- org-wl-open: Added a workaround for `wl-folder-goto-folder-subr',
  which moves point to the beginning of the current line in the old
  folder.

Thanks,
--Tokuya

> From: Carsten Dominik <dominik <at> science.uva.nl>
> Subject: Re: Re: Please test links
> Newsgroups: gmane.emacs.orgmode
> Date: 2008-03-15 20:35:49 GMT (17 hours and 38 minutes ago)
> 
> At least we got you to learn git! :-)
> 
> Thanks for the analysis, I have fixed this problem for all link
> packages, thanks a lot!!!
> 
> Please, everyone, git it another shot.
> 
> Ahh, I don't know what I would do without all this help.
> 
> - Carsten

\f
;;; org-wl.el - Support for links to Wanderlust messages in Org-mode

;; Copyright (C) 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.

;; Author: Carsten Dominik <carsten at orgmode dot org>
;; Keywords: outlines, hypermedia, calendar, wp
;; Homepage: http://orgmode.org
;; Version: 1.0
;;
;; This file is part of GNU Emacs.
;;
;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 3, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;;; Commentary:

;; This file implements links to Wanderlust messages for Org-mode.
;; Org-mode loads this module by default - if this is not what you want,
;; configure the variable `org-modules'.

(require 'org)

;; Declare external functions and variables
(declare-function elmo-folder-exists-p "ext:elmo" (folder) t)
(declare-function elmo-message-entity-field "ext:elmo-msgdb"
		  (entity field &optional type))
(declare-function elmo-message-field "ext:elmo"
		  (folder number field &optional type) t)
(declare-function elmo-msgdb-overview-get-entity "ext:elmo" (&rest unknown) t)
;; Backward compatibility to old version of wl
(declare-function wl-summary-buffer-msgdb "ext:wl-folder" (&rest unknown) t)
(declare-function wl-folder-get-elmo-folder "ext:wl-folder"
		  (entity &optional no-cache))
(declare-function wl-summary-goto-folder-subr "ext:wl-summary"
		  (&optional name scan-type other-window sticky interactive
			     scoring force-exit))
(declare-function wl-summary-jump-to-msg-by-message-id "ext:wl-summary"
		  (&optional id))
(declare-function wl-summary-line-from "ext:wl-summary" ())
(declare-function wl-summary-line-subject "ext:wl-summary" ())
(declare-function wl-summary-message-number "ext:wl-summary" ())
(declare-function wl-summary-redisplay "ext:wl-summary" (&optional arg))
(defvar wl-summary-buffer-elmo-folder)
(defvar wl-summary-buffer-folder-name)
(defvar wl-summary-buffer-temp-mark-list)

;; Install the link type
(org-add-link-type "wl" 'org-wl-open)
(add-hook 'org-store-link-functions 'org-wl-store-link)

;; Implementation
(defun org-wl-store-link ()
  "Store a link to an WL folder or message."
  (when (eq major-mode 'wl-summary-mode)
    (let* ((msgnum (wl-summary-message-number))
	   (folder-name
	    (let ((elem (assq msgnum wl-summary-buffer-temp-mark-list)))
	      (if (equal (nth 1 elem) "o") ; marked as refile
		  (nth 2 elem)
		wl-summary-buffer-folder-name)))
	   (message-id (elmo-message-field wl-summary-buffer-elmo-folder
					   msgnum 'message-id))
	   (wl-message-entity
	    (if (fboundp 'elmo-message-entity)
		(elmo-message-entity
		 wl-summary-buffer-elmo-folder msgnum)
	      (elmo-msgdb-overview-get-entity
	       msgnum (wl-summary-buffer-msgdb))))
	   (from (wl-summary-line-from))
	   (to (let ((to-field (elmo-message-entity-field wl-message-entity
							  'to)))
		 (if (listp to-field)
		     (car to-field)
		   to-field)))
	   (subject (let (wl-thr-indent-string wl-parent-message-entity)
		      (wl-summary-line-subject)))
	   desc link)
      (org-store-link-props :type "wl" :from from :to to
			    :subject subject :message-id message-id)
      (setq message-id (org-remove-angle-brackets message-id))
      (setq desc (org-email-link-description))
      (setq link (org-make-link "wl:" folder-name
				"#" message-id))
      (org-add-link-props :link link :description desc)
      link)))

(defun org-wl-open (path)
  "Follow an WL message link."
  ;; XXX: The imap-uw's MH folder names start with "%#".
  (if (not (string-match "\\`\\(\\(?:%#\\)?[^#]+\\)\\(#\\(.*\\)\\)?" path))
      (error "Error in Wanderlust link"))
  (let ((folder (match-string 1 path))
	(article (match-string 3 path)))
    (if (not (elmo-folder-exists-p (wl-folder-get-elmo-folder folder)))
	(error "No such folder: %s" folder))
    (let ((old-buf (current-buffer))
	  (old-point (point-marker)))
      (wl-folder-goto-folder-subr folder)
      (save-excursion
	;; XXX: `wl-folder-goto-folder-subr' moves point to the
	;; beginning of the current line.  So, restore the point
	;; in the old buffer.
	(set-buffer old-buf)
	(goto-char old-point))
      (wl-thread-open-all)
      (and (wl-summary-jump-to-msg-by-message-id (org-add-angle-brackets
						  article))
	   (wl-summary-redisplay)))))

(provide 'org-wl)

;;; org-wl.el ends here

^ permalink raw reply	[flat|nested] 18+ messages in thread
end of thread, other threads:[~2008-03-19  6:57 UTC | newest]

Thread overview: 18+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2008-03-15  8:24 Please test links Carsten Dominik
2008-03-15  9:31 ` Leo
2008-03-15  9:48   ` Bastien
2008-03-15 10:09     ` Carsten Dominik
2008-03-15 16:36 ` Thomas Baumann
2008-03-15 18:24   ` Carsten Dominik
2008-03-15 20:17     ` Thomas Baumann
2008-03-15 20:35       ` Carsten Dominik
2008-03-16  7:01         ` Thomas Baumann
2008-03-15 20:26     ` Thomas Baumann
2008-03-15 19:19 ` Bernt Hansen
2008-03-15 21:09   ` Bernt Hansen
2008-03-17 15:28     ` Joel J. Adamson
2008-03-17 18:48       ` Carsten Dominik
  -- strict thread matches above, loose matches on Subject: below --
2008-03-16 14:47 Tokuya Kameshima
2008-03-17  7:39 ` Carsten Dominik
2008-03-18 16:20   ` Tokuya Kameshima
2008-03-19  6:57     ` Carsten Dominik

Code repositories for project(s) associated with this public inbox

	https://git.savannah.gnu.org/cgit/emacs/org-mode.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).