Re: org-bbdb-anniversaries gives error 'bad sexp'

[Leo <sdl.web@gmail.com>]

[-- Attachment #1: Type: text/plain, Size: 325 bytes --]

On 2011-05-16 00:58 +0800, Matt Lundin wrote:
> I'd be happy to take this on. AFAICT, there are three functions in
> org-bbdb that no longer exist in bbdb v3.

If you want you can build on top of my version. The anniversaries is
still broken since I don't use BBDB-anniv.el. The rest works well for
the past few weeks.

Leo


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: org-bbdb.el --]
[-- Type: text/x-org, Size: 14482 bytes --]

;;; org-bbdb.el --- Support for links to BBDB entries from within Org-mode

;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009, 2010
;;   Free Software Foundation, Inc.

;; Author: Carsten Dominik <carsten at orgmode dot org>,
;;         Thomas Baumann <thomas dot baumann at ch dot tum dot de>
;; Keywords: outlines, hypermedia, calendar, wp
;; Homepage: http://orgmode.org
;; Version: 7.5
;;
;; This file is part of GNU Emacs.
;;
;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;;; Commentary:

;; This file implements links to BBDB database entries from within Org-mode.
;; Org-mode loads this module by default - if this is not what you want,
;; configure the variable `org-modules'.

;; It also implements an interface (based on Ivar Rummelhoff's
;; bbdb-anniv.el) for those org-mode users, who do not use the diary
;; but who do want to include the anniversaries stored in the BBDB
;; into the org-agenda.  If you already include the `diary' into the
;; agenda, you might want to prefer to include the anniversaries in
;; the diary using bbdb-anniv.el.
;;
;; Put the following in /somewhere/at/home/diary.org and make sure
;; that this file is in `org-agenda-files`
;;
;; %%(org-bbdb-anniversaries)
;;
;; For example my diary.org looks like:
;; * Anniversaries
;; #+CATEGORY: Anniv
;; %%(org-bbdb-anniversaries)
;;
;;
;; To add an anniversary to a BBDB record, press `C-o' in the record.
;; You will be prompted for the field name, in this case it must be
;; "anniversary".  If this is the first time you are using this field,
;; you need to confirm that it should be created.
;;
;; The format of an anniversary field stored in BBDB is the following
;; (items in {} are optional):
;;
;;     YYYY-MM-DD{ CLASS-OR-FORMAT-STRING}
;;     {\nYYYY-MM-DD CLASS-OR-FORMAT-STRING}...
;;
;; CLASS-OR-FORMAT-STRING is one of two things:
;;
;;  - an identifier for a class of anniversaries (eg. birthday or
;;    wedding) from `org-bbdb-anniversary-format-alist' which then
;;    defines the format string for this class
;;  - the (format) string displayed in the diary.
;;
;; You can enter multiple anniversaries for a single BBDB record by
;; separating them with a newline character.  At the BBDB prompt for
;; the field value, type `C-q C-j' to enter a newline between two
;; anniversaries.
;;
;; If you omit the CLASS-OR-FORMAT-STRING entirely, it defaults to the
;; value of `org-bbdb-default-anniversary-format' ("birthday" by
;; default).
;;
;; The substitutions in the format string are (in order):
;;  - the name of the record containing this anniversary
;;  - the number of years
;;  - an ordinal suffix (st, nd, rd, th) for the year
;;
;; See the documentation of `org-bbdb-anniversary-format-alist' for
;; further options.
;;
;; Example
;;
;;       1973-06-22
;;       20??-??-?? wedding
;;       1998-03-12 %s created bbdb-anniv.el %d years ago
;;
;; From Org's agenda, you can use `C-c C-o' to jump to the BBDB
;; link from which the entry at point originates.
;;
;;; Code:

(require 'org)
(eval-when-compile
  (require 'cl))

;; Declare external functions and variables

(declare-function bbdb "ext:bbdb-com" (regexp &optional layout))
(declare-function bbdb-search-organization "ext:bbdb-com"
		  (regexp &optional layout))
(declare-function bbdb-current-record "ext:bbdb" (&optional full))
(declare-function bbdb-search-name "ext:bbdb-com" (regexp &optional layout))
(declare-function bbdb-record-name "ext:bbdb-com" (record))
(declare-function bbdb-record-organization "ext:bbdb-com" (record))
(declare-function bbdb-record-note-split "ext:bbdb" (record label))
(declare-function bbdb-split "ext:bbdb" (separator string))
(declare-function bbdb-string-trim "ext:bbdb" (string))
(declare-function bbdb-records "ext:bbdb")
(declare-function bbdb-completing-read-record "ext:bbdb-com"
		  (prompt &optional omit-records))
(declare-function diary-ordinal-suffix "diary-lib" (n))

(defvar bbdb-buffer-name)
(defvar date)   ;; dynamically scoped from Org

;; Customization

(defgroup org-bbdb-anniversaries nil
  "Customizations for including anniversaries from BBDB into Agenda."
  :group 'org-bbdb)

(defcustom org-bbdb-default-anniversary-format "birthday"
  "Default anniversary class."
  :type  'string
  :group 'org-bbdb-anniversaries
  :require 'bbdb)

(defcustom org-bbdb-anniversary-format-alist
  '(("birthday" lambda
     (name years suffix)
     (concat "Birthday: [[bbdb:" name "][" name " ("
	     (format "%s" years)        ; handles numbers as well as strings
	     suffix ")]]"))
    ("wedding" lambda
     (name years suffix)
     (concat "[[bbdb:" name "][" name "'s "
	     (format "%s" years)
	     suffix " wedding anniversary]]")))
  "How different types of anniversaries should be formatted.
An alist of elements (STRING . FORMAT) where STRING is the name of an
anniversary class and format is either:
1) A format string with the following substitutions (in order):
    * the name of the record containing this anniversary
    * the number of years
    * an ordinal suffix (st, nd, rd, th) for the year

2) A function to be called with three arguments: NAME YEARS SUFFIX
   (string int string) returning a string for the diary or nil.

3) An Emacs Lisp form that should evaluate to a string (or nil) in the
   scope of variables NAME, YEARS and SUFFIX (among others)."
  :type 'sexp
  :group 'org-bbdb-anniversaries
  :require 'bbdb)

(defcustom org-bbdb-anniversary-field 'anniversary
  "The BBDB field which contains anniversaries.
The anniversaries are stored in the following format

YYYY-MM-DD Class-or-Format-String

where class is one of the customized classes for anniversaries;
birthday and wedding are predefined.  Format-String can take three
substitutions 1) the name of the record containing this
anniversary, 2) the number of years, and 3) an ordinal suffix for
the year.

Multiple anniversaries can be separated by \\n."
  :type    'symbol
  :group   'org-bbdb-anniversaries
  :require 'bbdb)

(defcustom org-bbdb-extract-date-fun 'org-bbdb-anniv-extract-date
  "How to retrieve `month date year' from the anniversary field.

Customize if you have already filled your BBDB with dates
different from YYYY-MM-DD.  The function must return a list (month
date year)."
  :type 'function
  :group 'org-bbdb-anniversaries
  :require 'bbdb)


;; Install the link type
(org-add-link-type "bbdb" 'org-bbdb-open 'org-bbdb-export)
(add-hook 'org-store-link-functions 'org-bbdb-store-link)

;; Implementation
(defun org-bbdb-store-link ()
  "Store a link to a BBDB database entry."
  (when (eq major-mode 'bbdb-mode)
    ;; This is BBDB, we make this link!
    (let* ((name (bbdb-record-name (bbdb-current-record)))
	   (organization (apply #'bbdb-concat 'organization
				(bbdb-record-organization (bbdb-current-record))))
	   (link (org-make-link "bbdb:" name)))
      (org-store-link-props :type "bbdb" :name name :organization organization
			    :link link :description name)
      link)))

(defun org-bbdb-export (path desc format)
  "Create the export version of a BBDB link specified by PATH or DESC.
If exporting to either HTML or LaTeX FORMAT the link will be
italicized, in all other cases it is left unchanged."
  (when (string= desc (format "bbdb:%s" path))
    (setq desc path))
  (cond
   ((eq format 'html) (format "<i>%s</i>" desc))
   ((eq format 'latex) (format "\\textit{%s}" desc))
   (t desc)))

(defun org-bbdb-open (name)
  "Follow a BBDB link to NAME."
  (require 'bbdb)
  (let ((inhibit-redisplay (not debug-on-error))
	(bbdb-electric nil))
    (catch 'exit
      ;; Exact match on name
      (bbdb-search-name (concat "\\`" name "\\'") nil)
      (if (< 0 (buffer-size (get-buffer bbdb-buffer-name))) (throw 'exit nil))
      ;; Exact match on name
      (bbdb-search-organization (concat "\\`" name "\\'") nil)
      (if (< 0 (buffer-size (get-buffer bbdb-buffer-name))) (throw 'exit nil))
      ;; Partial match on name
      (bbdb-search-name name nil)
      (if (< 0 (buffer-size (get-buffer bbdb-buffer-name))) (throw 'exit nil))
      ;; Partial match on company
      (bbdb-search-organization name nil)
      (if (< 0 (buffer-size (get-buffer bbdb-buffer-name))) (throw 'exit nil))
      ;; General match including network address and notes
      (bbdb name nil)
      (when (= 0 (buffer-size (get-buffer bbdb-buffer-name)))
	(delete-window (get-buffer-window bbdb-buffer-name))
	(error "No matching BBDB record")))))

(defun org-bbdb-anniv-extract-date (time-str)
  "Convert YYYY-MM-DD to (month date year).
Argument TIME-STR is the value retrieved from BBDB.  If YYYY- is omitted
it will be considered unknown."
  (multiple-value-bind (a b c) (values-list (bbdb-split "-" time-str))
    (if (eq c nil)
        (list (string-to-number a)
              (string-to-number b)
              nil)
      (list (string-to-number b)
            (string-to-number c)
            (string-to-number a)))))

(defun org-bbdb-anniv-split (str)
  "Split multiple entries in the BBDB anniversary field.
Argument STR is the anniversary field in BBDB."
  (let ((pos (string-match "[ \t]" str)))
    (if pos (list (substring str 0 pos)
		  (bbdb-string-trim (substring str pos)))
      (list str nil))))

(defvar org-bbdb-anniv-hash nil
  "A hash holding anniversaries extracted from BBDB.
The hash table is created on first use.")

(defvar org-bbdb-updated-p t
  "This is non-nil if BBDB has been updated since we last built the hash.")

(defun org-bbdb-make-anniv-hash ()
  "Create a hash with anniversaries extracted from BBDB, for fast access.
The anniversaries are assumed to be stored `org-bbdb-anniversary-field'."

  (let (split tmp annivs)
    (clrhash org-bbdb-anniv-hash)
    (dolist (rec (bbdb-records))
      (when (setq annivs (bbdb-record-note-split
			  rec org-bbdb-anniversary-field))
	(while annivs
          (setq split (org-bbdb-anniv-split (pop annivs)))
          (multiple-value-bind (m d y)
              (values-list (funcall org-bbdb-extract-date-fun (car split)))
            (setq tmp (gethash (list m d) org-bbdb-anniv-hash))
            (puthash (list m d) (cons (list y
                                            (bbdb-record-name rec)
                                            (cadr split))
                                      tmp)
                     org-bbdb-anniv-hash))))))
  (setq org-bbdb-updated-p nil))

(defun org-bbdb-updated (rec)
  "Record the fact that BBDB has been updated.
This is used by Org to re-create the anniversary hash table."
  (setq org-bbdb-updated-p t))

(add-hook 'bbdb-after-change-hook 'org-bbdb-updated)

;;;###autoload
(defun org-bbdb-anniversaries()
  "Extract anniversaries from BBDB for display in the agenda."
  (require 'bbdb)
  (require 'diary-lib)
  (unless (hash-table-p org-bbdb-anniv-hash)
    (setq org-bbdb-anniv-hash
	  (make-hash-table :test 'equal :size 366)))

  (when (or org-bbdb-updated-p
            (= 0 (hash-table-count org-bbdb-anniv-hash)))
    (org-bbdb-make-anniv-hash))

  (let* ((m (car date))    ; month
         (d (nth 1 date))  ; day
         (y (nth 2 date))  ; year
         (annivs (gethash (list m d) org-bbdb-anniv-hash))
         (text ())
         rec recs)

    ;; we don't want to miss people born on Feb. 29th
    (when (and (= m 3) (= d 1)
               (not (null (gethash (list 2 29) org-bbdb-anniv-hash)))
               (not (calendar-leap-year-p y)))
      (setq recs (gethash (list 2 29) org-bbdb-anniv-hash))
      (while (setq rec (pop recs))
        (push rec annivs)))

    (when annivs
      (while (setq rec (pop annivs))
        (when rec
          (let* ((class (or (nth 2 rec)
                            org-bbdb-default-anniversary-format))
                 (form (or (cdr (assoc-string
				 class org-bbdb-anniversary-format-alist t))
                           class))	; (as format string)
                 (name (nth 1 rec))
                 (years (if (eq (car rec) nil)
                            "unknown"
                          (- y (car rec))))
                 (suffix (if (eq (car rec) nil)
                             ""
                           (diary-ordinal-suffix years)))
                 (tmp (cond
                       ((functionp form)
                        (funcall form name years suffix))
                       ((listp form) (eval form))
                       (t (format form name years suffix)))))
	    (org-add-props tmp nil 'org-bbdb-name name)
            (if text
                (setq text (append text (list tmp)))
              (setq text (list tmp)))))
        ))
    text))

(defun org-bbdb-complete-link ()
  "Read a bbdb link with name completion."
  (require 'bbdb-com)
  (concat "bbdb:"
	  (bbdb-record-name (car (bbdb-completing-read-record "Name: ")))))

(defun org-bbdb-anniv-export-ical ()
  "Extract anniversaries from BBDB and convert them to icalendar format."
  (require 'bbdb)
  (require 'diary-lib)
  (unless (hash-table-p org-bbdb-anniv-hash)
    (setq org-bbdb-anniv-hash
	  (make-hash-table :test 'equal :size 366)))
  (when (or org-bbdb-updated-p
	    (= 0 (hash-table-count org-bbdb-anniv-hash)))
    (org-bbdb-make-anniv-hash))
  (maphash 'org-bbdb-format-vevent org-bbdb-anniv-hash))

(defun org-bbdb-format-vevent (key recs)
  (let (rec categ)
    (while (setq rec (pop recs))
      (setq categ (or (nth 2 rec) org-bbdb-default-anniversary-format))
      (princ (format "BEGIN:VEVENT
UID: ANNIV-%4i%02i%02i-%s
DTSTART:%4i%02i%02i
SUMMARY:%s
DESCRIPTION:%s
CATEGORIES:%s
RRULE:FREQ=YEARLY
END:VEVENT\n"
		     (nth 0 rec) (nth 0 key) (nth 1 key)
		     (mapconcat 'identity
				(org-split-string (nth 1 rec) "[^a-zA-Z0-90]+")
				"-")
		     (nth 0 rec) (nth 0 key) (nth 1 key)
		     (nth 1 rec)
		     (concat (capitalize categ) " " (nth 1 rec))
		     categ)))))

(provide 'org-bbdb)

;; arch-tag: 9e4f275d-d080-48c1-b040-62247f66b5c2

;;; org-bbdb.el ends here

[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #3: diff --]
[-- Type: text/x-diff, Size: 7368 bytes --]

commit e263d6604efde8b1c1853f72c781d01571667b62
Author: Leo <sdl.web@gmail.com>
Date:   Thu Apr 21 20:04:46 2011 +0800

    Fix org-bbdb.el for BBDB 3.x
---
 doc/org.texi         |    2 +-
 lisp/org-bbdb.el     |   61 ++++++++++++++++++++++++-------------------------
 lisp/org-capture.el  |    2 +-
 lisp/org-remember.el |    2 +-
 4 files changed, 33 insertions(+), 34 deletions(-)

	Modified doc/org.texi
diff --git a/doc/org.texi b/doc/org.texi
index 844de6da..d891a205 100644
--- a/doc/org.texi
+++ b/doc/org.texi
@@ -6493,7 +6493,7 @@ similar way.}:
 @smallexample
 Link type          |  Available keywords
 -------------------+----------------------------------------------
-bbdb                    |  %:name %:company
+bbdb                    |  %:name %:organization
 irc                     |  %:server %:port %:nick
 vm, wl, mh, mew, rmail  |  %:type %:subject %:message-id
                         |  %:from %:fromname %:fromaddress
	Modified lisp/org-bbdb.el
diff --git a/lisp/org-bbdb.el b/lisp/org-bbdb.el
index b772f442..0f5ed8d9 100644
--- a/lisp/org-bbdb.el
+++ b/lisp/org-bbdb.el
@@ -101,23 +101,22 @@ (eval-when-compile
 
 ;; Declare external functions and variables
 
-(declare-function bbdb "ext:bbdb-com" (string elidep))
-(declare-function bbdb-company "ext:bbdb-com" (string elidep))
-(declare-function bbdb-current-record "ext:bbdb-com"
-		  (&optional planning-on-modifying))
-(declare-function bbdb-name "ext:bbdb-com" (string elidep))
+(declare-function bbdb "ext:bbdb-com" (regexp &optional layout))
+(declare-function bbdb-search-organization "ext:bbdb-com"
+		  (regexp &optional layout))
+(declare-function bbdb-current-record "ext:bbdb" (&optional full))
+(declare-function bbdb-search-name "ext:bbdb-com" (regexp &optional layout))
+(declare-function bbdb-record-name "ext:bbdb-com" (record))
+(declare-function bbdb-record-organization "ext:bbdb-com" (record))
+(declare-function bbdb-record-note-split "ext:bbdb" (record label))
+(declare-function bbdb-split "ext:bbdb" (separator string))
+(declare-function bbdb-string-trim "ext:bbdb" (string))
+(declare-function bbdb-records "ext:bbdb")
 (declare-function bbdb-completing-read-record "ext:bbdb-com"
 		  (prompt &optional omit-records))
-(declare-function bbdb-record-getprop "ext:bbdb" (record property))
-(declare-function bbdb-record-name "ext:bbdb" (record))
-(declare-function bbdb-records "ext:bbdb"
-          (&optional dont-check-disk already-in-db-buffer))
-(declare-function bbdb-split "ext:bbdb" (string separators))
-(declare-function bbdb-string-trim "ext:bbdb" (string))
-
-(declare-function calendar-leap-year-p "calendar" (year))
 (declare-function diary-ordinal-suffix "diary-lib" (n))
 
+(defvar bbdb-buffer-name)
 (defvar date)   ;; dynamically scoped from Org
 
 ;; Customization
@@ -198,9 +197,10 @@ (defun org-bbdb-store-link ()
   (when (eq major-mode 'bbdb-mode)
     ;; This is BBDB, we make this link!
     (let* ((name (bbdb-record-name (bbdb-current-record)))
-	   (company (bbdb-record-getprop (bbdb-current-record) 'company))
+	   (organization (apply #'bbdb-concat 'organization
+				(bbdb-record-organization (bbdb-current-record))))
 	   (link (org-make-link "bbdb:" name)))
-      (org-store-link-props :type "bbdb" :name name :company company
+      (org-store-link-props :type "bbdb" :name name :organization organization
 			    :link link :description name)
       link)))
 
@@ -219,31 +219,31 @@ (defun org-bbdb-open (name)
   "Follow a BBDB link to NAME."
   (require 'bbdb)
   (let ((inhibit-redisplay (not debug-on-error))
-	(bbdb-electric-p nil))
+	(bbdb-electric nil))
     (catch 'exit
       ;; Exact match on name
-      (bbdb-name (concat "\\`" name "\\'") nil)
-      (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
+      (bbdb-search-name (concat "\\`" name "\\'") nil)
+      (if (< 0 (buffer-size (get-buffer bbdb-buffer-name))) (throw 'exit nil))
       ;; Exact match on name
-      (bbdb-company (concat "\\`" name "\\'") nil)
-      (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
+      (bbdb-search-organization (concat "\\`" name "\\'") nil)
+      (if (< 0 (buffer-size (get-buffer bbdb-buffer-name))) (throw 'exit nil))
       ;; Partial match on name
-      (bbdb-name name nil)
-      (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
+      (bbdb-search-name name nil)
+      (if (< 0 (buffer-size (get-buffer bbdb-buffer-name))) (throw 'exit nil))
       ;; Partial match on company
-      (bbdb-company name nil)
-      (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
+      (bbdb-search-organization name nil)
+      (if (< 0 (buffer-size (get-buffer bbdb-buffer-name))) (throw 'exit nil))
       ;; General match including network address and notes
       (bbdb name nil)
-      (when (= 0 (buffer-size (get-buffer "*BBDB*")))
-	(delete-window (get-buffer-window "*BBDB*"))
+      (when (= 0 (buffer-size (get-buffer bbdb-buffer-name)))
+	(delete-window (get-buffer-window bbdb-buffer-name))
 	(error "No matching BBDB record")))))
 
 (defun org-bbdb-anniv-extract-date (time-str)
   "Convert YYYY-MM-DD to (month date year).
 Argument TIME-STR is the value retrieved from BBDB.  If YYYY- is omitted
 it will be considered unknown."
-  (multiple-value-bind (a b c) (values-list (bbdb-split time-str "-"))
+  (multiple-value-bind (a b c) (values-list (bbdb-split "-" time-str))
     (if (eq c nil)
         (list (string-to-number a)
               (string-to-number b)
@@ -274,10 +274,9 @@ (defun org-bbdb-make-anniv-hash ()
   (let (split tmp annivs)
     (clrhash org-bbdb-anniv-hash)
     (dolist (rec (bbdb-records))
-      (when (setq annivs (bbdb-record-getprop
-                          rec org-bbdb-anniversary-field))
-        (setq annivs (bbdb-split annivs "\n"))
-        (while annivs
+      (when (setq annivs (bbdb-record-note-split
+			  rec org-bbdb-anniversary-field))
+	(while annivs
           (setq split (org-bbdb-anniv-split (pop annivs)))
           (multiple-value-bind (m d y)
               (values-list (funcall org-bbdb-extract-date-fun (car split)))
	Modified lisp/org-capture.el
diff --git a/lisp/org-capture.el b/lisp/org-capture.el
index 3327080e..4f89455a 100644
--- a/lisp/org-capture.el
+++ b/lisp/org-capture.el
@@ -245,7 +245,7 @@ (defcustom org-capture-templates nil
 
 Link type               |  Available information
 ------------------------+------------------------------------------------------
-bbdb                    |  %:type %:name %:company
+bbdb                    |  %:type %:name %:organization
 vm, wl, mh, mew, rmail  |  %:type %:subject %:message-id
                         |  %:from %:fromname %:fromaddress
                         |  %:to   %:toname   %:toaddress
	Modified lisp/org-remember.el
diff --git a/lisp/org-remember.el b/lisp/org-remember.el
index cf2d4543..21bd751b 100644
--- a/lisp/org-remember.el
+++ b/lisp/org-remember.el
@@ -162,7 +162,7 @@ (defcustom org-remember-templates nil
 
 Link type          |  Available information
 -------------------+------------------------------------------------------
-bbdb               |  %:type %:name %:company
+bbdb               |  %:type %:name %:organization
 vm, wl, mh, rmail  |  %:type %:subject %:message-id
                    |  %:from %:fromname %:fromaddress
                    |  %:to   %:toname   %:toaddress