[PATCH] Add ob-J.el

[PATCH] Add ob-J.el

[Oleh]

[-- Attachment #1: Type: text/plain, Size: 157 bytes --]

Hi all,

Here's a patch to add babel support for J.
I couldn't figure out how to make ob-J.elc a target for make,
maybe someone can fix this.

regards,
Oleh

[-- Attachment #2: 0001-Add-org-babel-support-for-J.patch --]
[-- Type: text/x-patch, Size: 5170 bytes --]

From 0139af8534dc33911ed1a24a9702a156ae46c99d Mon Sep 17 00:00:00 2001
From: Oleh Krehel <ohwoeowho@gmail.com>
Date: Fri, 20 Dec 2013 14:43:59 +0100
Subject: [PATCH] Add org-babel support for J.

---
 lisp/ob-J.el | 134 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 134 insertions(+)
 create mode 100644 lisp/ob-J.el

diff --git a/lisp/ob-J.el b/lisp/ob-J.el
new file mode 100644
index 0000000..50c1a5a
--- /dev/null
+++ b/lisp/ob-J.el
@@ -0,0 +1,134 @@
+;;; ob-J.el --- org-babel functions for J evaluation
+
+;; Copyright (C) 2011-2013 Free Software Foundation, Inc.
+
+;; Author: Oleh Krehel
+;; Keywords: literate programming, reproducible research
+;; Homepage: http://orgmode.org
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;; Session interaction depends on `j-console'.
+
+;;; Code:
+(require 'ob)
+(require 'j-console)
+
+(defun org-babel-expand-body:J (body params &optional processed-params)
+  "Expand BODY according to PARAMS, return the expanded body.
+PROCESSED-PARAMS isn't used yet."
+  (org-babel-J-interleave-echos-except-functions body))
+
+(defun org-babel-J-interleave-echos (body)
+  "Interleave echo'' between each source line of BODY."
+  (mapconcat #'identity (split-string body "\n") "\necho''\n"))
+
+(defun org-babel-J-interleave-echos-except-functions (body)
+  "Interleave echo'' between source lines of BODY that aren't functions."
+  (if (string-match-m "\\(?:^\\|\n\\)[^\n]*\\(?:1\\|2\\|3\\|4\\) : 0\n.*)" body)
+      (let ((s1 (substring body 0 (match-beginning 0)))
+	    (s2 (match-string 0 body))
+	    (s3 (substring body (match-end 0))))
+	(concat
+	 (org-babel-J-interleave-echos s1)
+	 "\necho''\n"
+	 s2
+	 (org-babel-J-interleave-echos-except-functions s3)))
+    (org-babel-J-interleave-echos body)))
+
+(defun org-babel-execute:J (body params)
+  "Execute a block of J code BODY.
+PARAMS are given by org-babel.
+This function is called by `org-babel-execute-src-block'"
+  (message "executing J source code block")
+  (let* ((processed-params (org-babel-process-params params))
+	 (sessionp (cdr (assoc :session params)))
+         (session (org-babel-j-initiate-session sessionp))
+         (vars (second processed-params))
+         (result-params (third processed-params))
+         (result-type (fourth processed-params))
+         (full-body (org-babel-expand-body:J
+                     body params processed-params))
+	 (tmp-script-file (org-babel-temp-file "J-src")))
+    (org-babel-J-strip-whitespace
+     (if (string= sessionp "none")
+	 (progn
+	   (with-temp-file tmp-script-file
+	     (insert full-body))
+	   (org-babel-eval (format "jconsole < %s" tmp-script-file) ""))
+       (org-babel-J-eval-string full-body)))))
+
+(defun org-babel-J-eval-string (str)
+  "Sends STR to the `j-console-cmd' session and exectues it."
+  (let ((session (j-console-ensure-session)))
+    (with-current-buffer (process-buffer session)
+      (goto-char (point-max))
+      (insert (format "\n%s\n" str))
+      (let ((beg (point)))
+	(comint-send-input)
+	(sit-for .1)
+	(buffer-substring-no-properties
+	 beg (point-max))))))
+
+(defun org-babel-J-strip-whitespace (str)
+  "Remove whitespace from jconsole output STR."
+  (let ((strs (split-string str "\n" t))
+	out cur s)
+    (while (setq s (pop strs))
+      (if (string-match "^ *$" s)
+	  (progn (push (nreverse cur) out)
+		 (setq cur))
+	(push s cur)))
+    (mapconcat #'org-babel-J-print-block
+	       (delq nil (nreverse out))
+	       "\n\n")))
+
+(defun org-babel-J-print-block (x)
+  "Prettify jconsole output X."
+  (if (= 1 (length x))
+      (obj-strip-leading-ws (car x))
+    ;; assume only first row is misaligned
+    (let ((n1 (obj-match-second-space (car x)))
+	  (n2 (obj-match-second-space (cadr x))))
+      (setcar
+       x
+       (if (and n1 n2)
+	   (substring (car x) (- n1 n2))
+	 (obj-strip-leading-ws (car x))))
+      (mapconcat #'identity x "\n"))))
+
+(defun obj-match-second-space (s)
+  "Return position of second space in S or nil."
+  (and (string-match "^ *[^ ]+\\( \\)" s)
+       (match-beginning 1)))
+
+(defun obj-strip-leading-ws (s)
+  "String leading whitespace from S."
+  (and (string-match "^ *\\([^ ].*\\)" s)
+       (match-string 1 s)))
+
+(defun org-babel-j-initiate-session (&optional session)
+  "Initiate a J session.
+SESSION is a parameter given by org-babel."
+  (unless (string= session "none")
+    (require 'j-console)
+    (j-console-ensure-session)))
+
+(provide 'ob-J)
+
+;;; ob-J.el ends here
-- 
1.8.4

Re: [PATCH] Add ob-J.el

[Bastien]

Hi Oleh,

Oleh <ohwoeowho@gmail.com> writes:

> Here's a patch to add babel support for J.

Thanks.  Are you a FSF-signed contributor?  We cannot include
this in Org's core without your copyright assignment, let me know.

> I couldn't figure out how to make ob-J.elc a target for make,
> maybe someone can fix this.

No need to create a specific target.

Some comments on the code below:

> From 0139af8534dc33911ed1a24a9702a156ae46c99d Mon Sep 17 00:00:00 2001
> From: Oleh Krehel <ohwoeowho@gmail.com>
> Date: Fri, 20 Dec 2013 14:43:59 +0100
> Subject: [PATCH] Add org-babel support for J.
>
> ---
>  lisp/ob-J.el | 134 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
>  1 file changed, 134 insertions(+)
>  create mode 100644 lisp/ob-J.el
>
> diff --git a/lisp/ob-J.el b/lisp/ob-J.el
> new file mode 100644
> index 0000000..50c1a5a
> --- /dev/null
> +++ b/lisp/ob-J.el
> @@ -0,0 +1,134 @@
> +;;; ob-J.el --- org-babel functions for J evaluation
> +
> +;; Copyright (C) 2011-2013 Free Software Foundation, Inc.
> +
> +;; Author: Oleh Krehel
> +;; Keywords: literate programming, reproducible research
> +;; Homepage: http://orgmode.org
> +
> +;; This file is part of GNU Emacs.

That's for Org's core (the lisp/ directory) but we can add
ob-J.el in contrib/lisp/ without the copyright assignment.

> +  (mapconcat #'identity (split-string body "\n") "\necho''\n"))
                ^

(mapconcat 'identity ...)

is fine.

> +(defun org-babel-J-strip-whitespace (str)
> +(defun obj-strip-leading-ws (s)

Maybe you can use org-trim here.

> +;;; ob-J.el ends here

Thanks for this contribution!

-- 
 Bastien

Re: [PATCH] Add ob-J.el

[Eric Schulte]

Applied, Thanks!

I've played with APL but never seriously, however I can see it being a
perfect tool for manipulating Org-mode tables.

If you have time to put some documentation up on Worg as a new [1]
linked from [2] that'd be great.

I added ob-J to the org-babel-load-languages customization variable and
it is now compiling with make.

Best,

Oleh <ohwoeowho@gmail.com> writes:

> Hi all,
>
> Here's a patch to add babel support for J.
> I couldn't figure out how to make ob-J.elc a target for make,
> maybe someone can fix this.
>
> regards,
> Oleh
>
> From 0139af8534dc33911ed1a24a9702a156ae46c99d Mon Sep 17 00:00:00 2001
> From: Oleh Krehel <ohwoeowho@gmail.com>
> Date: Fri, 20 Dec 2013 14:43:59 +0100
> Subject: [PATCH] Add org-babel support for J.
>
> ---
>  lisp/ob-J.el | 134 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
>  1 file changed, 134 insertions(+)
>  create mode 100644 lisp/ob-J.el
>
> diff --git a/lisp/ob-J.el b/lisp/ob-J.el
> new file mode 100644
> index 0000000..50c1a5a
> --- /dev/null
> +++ b/lisp/ob-J.el
> @@ -0,0 +1,134 @@
> +;;; ob-J.el --- org-babel functions for J evaluation
> +
> +;; Copyright (C) 2011-2013 Free Software Foundation, Inc.
> +
> +;; Author: Oleh Krehel
> +;; Keywords: literate programming, reproducible research
> +;; Homepage: http://orgmode.org
> +
> +;; This file is part of GNU Emacs.
> +
> +;; GNU Emacs is free software: you can redistribute it and/or modify
> +;; it under the terms of the GNU General Public License as published by
> +;; the Free Software Foundation, either version 3 of the License, or
> +;; (at your option) any later version.
> +
> +;; GNU Emacs is distributed in the hope that it will be useful,
> +;; but WITHOUT ANY WARRANTY; without even the implied warranty of
> +;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
> +;; GNU General Public License for more details.
> +
> +;; You should have received a copy of the GNU General Public License
> +;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
> +
> +;;; Commentary:
> +
> +;; Session interaction depends on `j-console'.
> +
> +;;; Code:
> +(require 'ob)
> +(require 'j-console)
> +
> +(defun org-babel-expand-body:J (body params &optional processed-params)
> +  "Expand BODY according to PARAMS, return the expanded body.
> +PROCESSED-PARAMS isn't used yet."
> +  (org-babel-J-interleave-echos-except-functions body))
> +
> +(defun org-babel-J-interleave-echos (body)
> +  "Interleave echo'' between each source line of BODY."
> +  (mapconcat #'identity (split-string body "\n") "\necho''\n"))
> +
> +(defun org-babel-J-interleave-echos-except-functions (body)
> +  "Interleave echo'' between source lines of BODY that aren't functions."
> +  (if (string-match-m "\\(?:^\\|\n\\)[^\n]*\\(?:1\\|2\\|3\\|4\\) : 0\n.*)" body)
> +      (let ((s1 (substring body 0 (match-beginning 0)))
> +	    (s2 (match-string 0 body))
> +	    (s3 (substring body (match-end 0))))
> +	(concat
> +	 (org-babel-J-interleave-echos s1)
> +	 "\necho''\n"
> +	 s2
> +	 (org-babel-J-interleave-echos-except-functions s3)))
> +    (org-babel-J-interleave-echos body)))
> +
> +(defun org-babel-execute:J (body params)
> +  "Execute a block of J code BODY.
> +PARAMS are given by org-babel.
> +This function is called by `org-babel-execute-src-block'"
> +  (message "executing J source code block")
> +  (let* ((processed-params (org-babel-process-params params))
> +	 (sessionp (cdr (assoc :session params)))
> +         (session (org-babel-j-initiate-session sessionp))
> +         (vars (second processed-params))
> +         (result-params (third processed-params))
> +         (result-type (fourth processed-params))
> +         (full-body (org-babel-expand-body:J
> +                     body params processed-params))
> +	 (tmp-script-file (org-babel-temp-file "J-src")))
> +    (org-babel-J-strip-whitespace
> +     (if (string= sessionp "none")
> +	 (progn
> +	   (with-temp-file tmp-script-file
> +	     (insert full-body))
> +	   (org-babel-eval (format "jconsole < %s" tmp-script-file) ""))
> +       (org-babel-J-eval-string full-body)))))
> +
> +(defun org-babel-J-eval-string (str)
> +  "Sends STR to the `j-console-cmd' session and exectues it."
> +  (let ((session (j-console-ensure-session)))
> +    (with-current-buffer (process-buffer session)
> +      (goto-char (point-max))
> +      (insert (format "\n%s\n" str))
> +      (let ((beg (point)))
> +	(comint-send-input)
> +	(sit-for .1)
> +	(buffer-substring-no-properties
> +	 beg (point-max))))))
> +
> +(defun org-babel-J-strip-whitespace (str)
> +  "Remove whitespace from jconsole output STR."
> +  (let ((strs (split-string str "\n" t))
> +	out cur s)
> +    (while (setq s (pop strs))
> +      (if (string-match "^ *$" s)
> +	  (progn (push (nreverse cur) out)
> +		 (setq cur))
> +	(push s cur)))
> +    (mapconcat #'org-babel-J-print-block
> +	       (delq nil (nreverse out))
> +	       "\n\n")))
> +
> +(defun org-babel-J-print-block (x)
> +  "Prettify jconsole output X."
> +  (if (= 1 (length x))
> +      (obj-strip-leading-ws (car x))
> +    ;; assume only first row is misaligned
> +    (let ((n1 (obj-match-second-space (car x)))
> +	  (n2 (obj-match-second-space (cadr x))))
> +      (setcar
> +       x
> +       (if (and n1 n2)
> +	   (substring (car x) (- n1 n2))
> +	 (obj-strip-leading-ws (car x))))
> +      (mapconcat #'identity x "\n"))))
> +
> +(defun obj-match-second-space (s)
> +  "Return position of second space in S or nil."
> +  (and (string-match "^ *[^ ]+\\( \\)" s)
> +       (match-beginning 1)))
> +
> +(defun obj-strip-leading-ws (s)
> +  "String leading whitespace from S."
> +  (and (string-match "^ *\\([^ ].*\\)" s)
> +       (match-string 1 s)))
> +
> +(defun org-babel-j-initiate-session (&optional session)
> +  "Initiate a J session.
> +SESSION is a parameter given by org-babel."
> +  (unless (string= session "none")
> +    (require 'j-console)
> +    (j-console-ensure-session)))
> +
> +(provide 'ob-J)
> +
> +;;; ob-J.el ends here


Footnotes: 
[1]  http://orgmode.org/worg/org-contrib/babel/languages/ob-doc-j.html

[2]  http://orgmode.org/worg/org-contrib/babel/languages.html

-- 
Eric Schulte
https://cs.unm.edu/~eschulte
PGP: 0x614CA05D

Re: [PATCH] Add ob-J.el

[Oleh]

> Applied, Thanks!
>
> I've played with APL but never seriously, however I can see it being a
> perfect tool for manipulating Org-mode tables.

It's a nice tool, and I wrote this package just to learn J faster.

I wrote some time ago a package that takes a range, maps elisp code over it
and inserts it, e.g m4(* x x) becomes 0 1 4 9 16.
Then I realized that the parens and spaces weren't really necessary
and now this works as well: m4*xx.
After learning some of J, I see that even arguments aren't necessary,
e.g. m4*: describes the same thing in J.

If you want to try the package, it's called "tiny" in MELPA.
It's got one interesting application for org-mode: schedule/deadline
an activity for a span of days:

m0\n4|** TODO Something work-related %(1+ x)\nSCHEDULED: <%(date "mon"
x) 10:00 +1w>

expands to:

** TODO Something work-related 1
SCHEDULED: <2013-12-23 Mon 10:00 +1w>
** TODO Something work-related 2
SCHEDULED: <2013-12-24 Tue 10:00 +1w>
** TODO Something work-related 3
SCHEDULED: <2013-12-25 Wed 10:00 +1w>
** TODO Something work-related 4
SCHEDULED: <2013-12-26 Thu 10:00 +1w>
** TODO Something work-related 5
SCHEDULED: <2013-12-27 Fri 10:00 +1w>

> If you have time to put some documentation up on Worg as a new [1]
> linked from [2] that'd be great.

I'll do this soon.

regards,
Oleh

Re: [BUG] Add ob-J.el

[Rick Frankel]

On Fri, Dec 20, 2013 at 10:12:24AM -0700, Eric Schulte wrote:
> Applied, Thanks!
> 
> I've played with APL but never seriously, however I can see it being a
> perfect tool for manipulating Org-mode tables.
> 
> If you have time to put some documentation up on Worg as a new [1]
> linked from [2] that'd be great.
> 
> I added ob-J to the org-babel-load-languages customization variable and
> it is now compiling with make.

The org-mode build and install now fails for me due to the fact that
ob-J requires j-console, which seems to be part of the package
'j-mode', and is not part of the standard emacs.

Perhaps this should be in contrib, unless the depency on j-console can
be factored out.

rick

Re: [BUG] Add ob-J.el

[Oleh]

>> I added ob-J to the org-babel-load-languages customization variable and
>> it is now compiling with make.
>
> The org-mode build and install now fails for me due to the fact that
> ob-J requires j-console, which seems to be part of the package
> 'j-mode', and is not part of the standard emacs.
>
> Perhaps this should be in contrib, unless the depency on j-console can
> be factored out.
>

Hi Rick,

j-console is required currently for :session eval only. Regular eval
works without it.
You can remove the top level (require 'j-console) now if you want, or I can
remove it a bit later when I get push access.
The top level one isn't needed since it's required again in *-initiate-session.

The actual dependency on j-console to do the work isn't that different
from when other org-babel implementations depend on nrepl or inf-ruby.
But as it's just a simple comint interaction, I could eventually
remove this dependency.

regards,
Oleh

Re: [BUG] Add ob-J.el

[Eric Schulte]

Oleh <ohwoeowho@gmail.com> writes:

>>> I added ob-J to the org-babel-load-languages customization variable and
>>> it is now compiling with make.
>>
>> The org-mode build and install now fails for me due to the fact that
>> ob-J requires j-console, which seems to be part of the package
>> 'j-mode', and is not part of the standard emacs.
>>
>> Perhaps this should be in contrib, unless the depency on j-console can
>> be factored out.
>>
>
> Hi Rick,
>
> j-console is required currently for :session eval only. Regular eval
> works without it.
> You can remove the top level (require 'j-console) now if you want, or I can
> remove it a bit later when I get push access.
> The top level one isn't needed since it's required again in *-initiate-session.
>
> The actual dependency on j-console to do the work isn't that different
> from when other org-babel implementations depend on nrepl or inf-ruby.
> But as it's just a simple comint interaction, I could eventually
> remove this dependency.
>
> regards,
> Oleh
>

I just removed the top-level require, thanks for reporting.

-- 
Eric Schulte
https://cs.unm.edu/~eschulte
PGP: 0x614CA05D

Re: [PATCH] Add ob-J.el

[Thomas S. Dye]

Aloha Oleh,

Oleh <ohwoeowho@gmail.com> writes:

> Hi all,
>
> Here's a patch to add babel support for J.
> I couldn't figure out how to make ob-J.elc a target for make,
> maybe someone can fix this.
>
> regards,
> Oleh
>

Are you willing to draft documentation for ob-J.el? You can find a link
for a documentation template here:

http://orgmode.org/worg/org-contrib/babel/languages.html#develop

I'm happy to proof-read and edit draft documentation, if you'd like.
We're slowly catching up with the documentation for babel languages.

Thanks for your contribution to Org mode!

All the best,
Tom

-- 
Thomas S. Dye
http://www.tsdye.com

Re: [PATCH] Add ob-J.el

[Oleh]

Hi Tom,

Yes, I'll write the documentation some time soon.

regards,
Oleh

On Fri, Dec 20, 2013 at 6:22 PM, Thomas S. Dye <tsd@tsdye.com> wrote:
> Aloha Oleh,
>
> Oleh <ohwoeowho@gmail.com> writes:
>
>> Hi all,
>>
>> Here's a patch to add babel support for J.
>> I couldn't figure out how to make ob-J.elc a target for make,
>> maybe someone can fix this.
>>
>> regards,
>> Oleh
>>
>
> Are you willing to draft documentation for ob-J.el? You can find a link
> for a documentation template here:
>
> http://orgmode.org/worg/org-contrib/babel/languages.html#develop
>
> I'm happy to proof-read and edit draft documentation, if you'd like.
> We're slowly catching up with the documentation for babel languages.
>
> Thanks for your contribution to Org mode!
>
> All the best,
> Tom
>
> --
> Thomas S. Dye
> http://www.tsdye.com

Re: [PATCH] Add ob-J.el

[Oleh]

Hi all,

The doc for ob-J is now available at
http://orgmode.org/worg/org-contrib/babel/languages/ob-doc-J.html

regards,
Oleh

On Fri, Dec 20, 2013 at 6:22 PM, Thomas S. Dye <tsd@tsdye.com> wrote:
> Aloha Oleh,
>
> Oleh <ohwoeowho@gmail.com> writes:
>
>> Hi all,
>>
>> Here's a patch to add babel support for J.
>> I couldn't figure out how to make ob-J.elc a target for make,
>> maybe someone can fix this.
>>
>> regards,
>> Oleh
>>
>
> Are you willing to draft documentation for ob-J.el? You can find a link
> for a documentation template here:
>
> http://orgmode.org/worg/org-contrib/babel/languages.html#develop
>
> I'm happy to proof-read and edit draft documentation, if you'd like.
> We're slowly catching up with the documentation for babel languages.
>
> Thanks for your contribution to Org mode!
>
> All the best,
> Tom
>
> --
> Thomas S. Dye
> http://www.tsdye.com

Re: [PATCH] Add ob-J.el

[Thomas S. Dye]

Aloha Oleh,

The documentation looks good. Thanks for this contribution to Org mode.

All the best,
Tom

Oleh <ohwoeowho@gmail.com> writes:

> Hi all,
>
> The doc for ob-J is now available at
> http://orgmode.org/worg/org-contrib/babel/languages/ob-doc-J.html
>
> regards,
> Oleh
>
> On Fri, Dec 20, 2013 at 6:22 PM, Thomas S. Dye <tsd@tsdye.com> wrote:
>> Aloha Oleh,
>>
>> Oleh <ohwoeowho@gmail.com> writes:
>>
>>> Hi all,
>>>
>>> Here's a patch to add babel support for J.
>>> I couldn't figure out how to make ob-J.elc a target for make,
>>> maybe someone can fix this.
>>>
>>> regards,
>>> Oleh
>>>
>>
>> Are you willing to draft documentation for ob-J.el? You can find a link
>> for a documentation template here:
>>
>> http://orgmode.org/worg/org-contrib/babel/languages.html#develop
>>
>> I'm happy to proof-read and edit draft documentation, if you'd like.
>> We're slowly catching up with the documentation for babel languages.
>>
>> Thanks for your contribution to Org mode!
>>
>> All the best,
>> Tom
>>
>> --
>> Thomas S. Dye
>> http://www.tsdye.com
>
>

-- 
Thomas S. Dye
http://www.tsdye.com