Detect parent with SCHEDULED or DEADLINE

Detect parent with SCHEDULED or DEADLINE

[Christophe Schockaert]

Hi fellow org-moders,


I am seeking to list all actions in "NEXT" state that are not planned
yet (scheduled, deadline or planning tag such as WEEK, MONTH, and other
well known :).

I will consider as planned an action which is in a subtree of a parent
action which is itself planned.

That's easy for tags, since I have inheritance, but according to
http://article.gmane.org/gmane.emacs.orgmode/49215, there is no
inheritance for SCHEDULED and DEADLINE properties.

So, I inspired myself from the proposed solution and I wrote the
following function, used in an agenda block :

#+BEGIN_SRC lisp
;; Function to skip scheduled or deadline
(defun r3v/skip-inherited-scheduled-or-deadline ()
  "Skip tasks that inherit from SCHEDULED or DEADLINE"
  (let ((next-headline (save-excursion (or (outline-next-heading) (point-max))))
        (inherited-scheduled (org-entry-get-with-inheritance "SCHEDULED"))
        (inherited-deadline (org-entry-get-with-inheritance "DEADLINE")))
    ;; I will consider the scheduled part if I can make it work with
    ;; deadlines first
    (if (org-not-nil inherited-deadline)
        next-headline
      nil)))

;; Extract from agenda block
    (tags "-WAITING-CANCELLED-WEEK-MONTH-SOMEDAY/NEXT"
          ((org-agenda-overriding-header "Non planned 'NEXT' actions")
           (org-agenda-skip-function 'r3v/skip-inherited-scheduled-or-deadline)
           ;; I don't think this one is needed, but in case I enabled it:
           (org-use-property-inheritance t)
           (org-agenda-todo-ignore-scheduled t)
           (org-agenda-todo-ignore-deadlines t)
           (org-agenda-todo-ignore-with-date t)
           (org-tags-match-list-sublevels t)
           (org-agenda-sorting-strategy
            '(priority-down todo-state-down effort-up category-up))))
#+END_SRC

However, it never detects a deadline, or scheduled property, *even if
assigned on the heading itself*.

I tried that on a very simple subtree :

#+BEGIN_SRC org
* TODO Parent todo
DEADLINE: <2016-04-15 ven.>
:PROPERTIES:
:ParentProp:   ValPar
:END:
** NEXT SubAction
:PROPERTIES:
:SubProp:   Val
:END:
#+END_SRC


I also tried to eval the following expression, manually from the tree :

#+BEGIN_SRC lisp
;;;;; With DEADLINE properties, the behavior acts strangely ;;;;;

(org-entry-get nil "DEADLINE")
;; As expected:
;; - On "Parent todo", returns <2016-04-15 ven.>
;; - On "SubAction", returns nil

(org-entry-get nil "DEADLINE" t)
;; As expected:
;; - On "Parent todo", returns <2016-04-15 ven.>
;; /!\ NOT expected:
;; - On "SubAction", still returns nil

(org-entry-get-with-inheritance "DEADLINE")
;; /!\ NOT expected:
;; - On "Parent todo", returns nil
;; - On "SubAction", returns nil


;;;;; With custom properties, it works as I expect it ;;;;;

(org-entry-get nil "ParentProp")
;; - On "Parent todo", returns "ValPar"
;; - On "SubAction", returns nil

(org-entry-get nil "ParentProp" t)
;; - On "Parent todo", returns "ValPar"
;; - On "SubAction", returns "ValPar"

(org-entry-get-with-inheritance "ParentProp")
;; - On "Parent todo", returns "ValPar"
;; - On "SubAction", returns "ValPar"
#+END_SRC


Globally, org-use-property-inheritance is set to nil.

I currently have Org "8.3.3-43-g0b97a5-elpaplus" from ELPA as reported.

There might also be an easier way I didn't think of to achieve what I
want (list actions not planned), but I would also like to understand
what's wrong or what should be done to make the function work.


Any help will be appreciated :)
Kind Regards,

Christophe



-- 
--------------->  mailto:R3vLibre@citadels.eu
Once it's perfectly aimed, the flying arrow goes straight to its target.
Thus, don't worry when things go right.
There will be enough time to worry about if they go wrong.
Then, it's time to fire a new arrow towards another direction.
Don't sink.  Adapt yourself !  The archer has to shoot accurately and quickly.
[Words of Erenthar, the bowman ranger] <---------------<<<<

Re: Detect parent with SCHEDULED or DEADLINE

[Adam Porter]

Hi Christophe,

I'm still using Org 8.2.4 from Ubuntu Trusty (I'll upgrade Org one of these
days...), and I tested your code, and it seems to work properly.  For
example, testing on this tree:

#+BEGIN_SRC org
* Test tree
** TODO Parent todo
DEADLINE: <2016-04-15 ven.>
:PROPERTIES:
:ParentProp:   ValPar
:END:

potatoes

*** NEXT SubAction
:PROPERTIES:
:SubProp:   Val
:END: 

sandwiches
#+END_SRC

With point anywhere in the "SubAction" entry, either on the heading line or
after it, when I eval ~(org-entry-get-with-inheritance "DEADLINE")~, I get
"2016-04-15 ven."

But in Org 8.3.4, it fails, just as you said.  I think I see why:

In Org 8.2.4, =org-entry-get-with-inheritance= has this code:

#+BEGIN_SRC elisp
(if (member property org-special-properties)
	  ;; We need a special property.  Use `org-entry-properties'
	  ;; to retrieve it, but specify the wanted property
	  (cdr (assoc property (org-entry-properties nil 'special property)))
...
#+END_SRC

That finds properties like =DEADLINE= that are not inside property drawers.

But in Org 8.3.4, =org-entry-get-with-inheritance= calls
=org-property--local-values=, which calls =org-get-property-block=, which
returns =nil=, and it doesn't check =org-special-properties= at all, so it
seems to only search inside =:PROPERTIES:= drawers.

I think it was caused by commit 188bae9 "Fix property inheritance with
extended values" from 3 Jul 2015.

Re: Detect parent with SCHEDULED or DEADLINE

[Adam Porter]

[-- Attachment #1: Type: text/plain, Size: 268 bytes --]

Hi again Christophe,

This patch seems to fix it in the current master.  Please note, I am not
qualified to patch Org directly, so this should be reviewed by those who
know what they're doing.  But it may at least fix it for you or be a
starting point for fixing it.


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: Patch for org.el --]
[-- Type: text/x-diff, Size: 1168 bytes --]

From 3074c8ad92a7f822374544afa9f9ada61197e4da Mon Sep 17 00:00:00 2001
From: Adam Porter <adam@alphapapa.net>
Date: Wed, 13 Apr 2016 22:37:43 -0500
Subject: [PATCH] org.el: Fix getting special properties

(org-entry-get-with-inheritance): If property is an special property,
get it with org-entry-properties instead of org-property--local-values,
which only searches drawers.

This may have been broken in commit 188bae9 "Fix property inheritance with
extended values".
---
 lisp/org.el | 4 +++-
 1 file changed, 3 insertions(+), 1 deletion(-)

diff --git a/lisp/org.el b/lisp/org.el
index da16da5..39ed6b0 100644
--- a/lisp/org.el
+++ b/lisp/org.el
@@ -15960,7 +15960,9 @@ However, if LITERAL-NIL is set, return the string value \"nil\" instead."
    (let (value)
      (catch 'exit
        (while t
-	 (let ((v (org-property--local-values property literal-nil)))
+	 (let ((v (if (member-ignore-case property (cons "CATEGORY" org-special-properties))
+		      (list (cdar (org-entry-properties nil property)))
+		    (org-property--local-values property literal-nil))))
 	   (when v
 	     (setq value
 		   (concat (mapconcat #'identity (delq nil v) " ")
-- 
2.7.4

Re: Detect parent with SCHEDULED or DEADLINE

[Nicolas Goaziou]

Hello,

Adam Porter <adam@alphapapa.net> writes:

> This patch seems to fix it in the current master.  Please note, I am not
> qualified to patch Org directly, so this should be reviewed by those who
> know what they're doing.  But it may at least fix it for you or be a
> starting point for fixing it.
>
>
> From 3074c8ad92a7f822374544afa9f9ada61197e4da Mon Sep 17 00:00:00 2001
> From: Adam Porter <adam@alphapapa.net>
> Date: Wed, 13 Apr 2016 22:37:43 -0500
> Subject: [PATCH] org.el: Fix getting special properties
>
> (org-entry-get-with-inheritance): If property is an special property,
> get it with org-entry-properties instead of org-property--local-values,
> which only searches drawers.
>
> This may have been broken in commit 188bae9 "Fix property inheritance with
> extended values".

Thanks for the patch.

However, `org-entry-get-with-inheritance' is not meant to be called with
special properties, which have their own inheritance rules, that cannot
be forced.

Actually, `org-entry-get-with-inheritance' is an internal function,
which shouldn't be called at all. The entry point is `org-entry-get',
which can be called with an appropriate INHERIT optional argument.

Regards,

-- 
Nicolas Goaziou

Re: Detect parent with SCHEDULED or DEADLINE

[Adam Porter]

Nicolas Goaziou <mail@nicolasgoaziou.fr> writes:

> Actually, `org-entry-get-with-inheritance' is an internal function,
> which shouldn't be called at all. The entry point is `org-entry-get',
> which can be called with an appropriate INHERIT optional argument.

Ah, I see.  So I guess the solution to Christophe's issue is to use
this:

#+BEGIN_SRC elisp
(defun r3v/skip-inherited-scheduled-or-deadline ()
  "Skip tasks that inherit from SCHEDULED or DEADLINE"
  (let ((next-headline (save-excursion (or (outline-next-heading) (point-max))))
        (inherited-scheduled (org-entry-get "SCHEDULED" t))
        (inherited-deadline (org-entry-get "DEADLINE" t)))
    ;; I will consider the scheduled part if I can make it work with
    ;; deadlines first
    (if (org-not-nil inherited-deadline)
        next-headline
      nil)))
#+END_SRC

At least I learned some more about Org by trying to fix it the wrong
way.  :)  Thanks, Nicolas.

Re: Detect parent with SCHEDULED or DEADLINE

[Nicolas Goaziou]

Adam Porter <adam@alphapapa.net> writes:

> Ah, I see.  So I guess the solution to Christophe's issue is to use
> this:
>
> #+BEGIN_SRC elisp
> (defun r3v/skip-inherited-scheduled-or-deadline ()
>   "Skip tasks that inherit from SCHEDULED or DEADLINE"
>   (let ((next-headline (save-excursion (or (outline-next-heading) (point-max))))
>         (inherited-scheduled (org-entry-get "SCHEDULED" t))
>         (inherited-deadline (org-entry-get "DEADLINE" t)))
>     ;; I will consider the scheduled part if I can make it work with
>     ;; deadlines first
>     (if (org-not-nil inherited-deadline)
>         next-headline
>       nil)))
> #+END_SRC

I don't think so. You cannot force inheritance for a special property,
which obey to its own rules. The optional argument is going to be
ignored. If the OP wants to get the SCHEDULED value of the current
headline or any of its parent, he can move up the hierarchy with
`org-up-heading-safe', calling `org-entry-get' at each stop.

Regards,

Re: Detect parent with SCHEDULED or DEADLINE

[Christophe Schockaert]

Nicolas Goaziou writes:

> Adam Porter <adam@alphapapa.net> writes:
>
>> Ah, I see.  So I guess the solution to Christophe's issue is to use
>> this:
>>
>> #+BEGIN_SRC elisp
[...]
>>         (inherited-scheduled (org-entry-get "SCHEDULED" t))
[...]
>> #+END_SRC
>
> I don't think so. You cannot force inheritance for a special property,
> which obey to its own rules. The optional argument is going to be
> ignored. If the OP wants to get the SCHEDULED value of the current
> headline or any of its parent, he can move up the hierarchy with
> `org-up-heading-safe', calling `org-entry-get' at each stop.
>
> Regards,

Thank you Adam and Nicolas for your answers,


I know have a better picture how things work in Org, and I also
understand why '(org-entry-get "DEADLINE" t)' returned 'nil' when called
directly from the org-file.

I could rewrite my function using 'org-up-heading-safe' and
'org-entry-get', and it gets the expected result in the agenda view :-)

I am starting to enjoy ELisp, and I graduately become better at it.


Cheerful thanks,

Christophe

-- 
--------------->  mailto:R3vLibre@citadels.eu
Once it's perfectly aimed, the flying arrow goes straight to its target.
Thus, don't worry when things go right.
There will be enough time to worry about if they go wrong.
Then, it's time to fire a new arrow towards another direction.
Don't sink.  Adapt yourself !  The archer has to shoot accurately and quickly.
[Words of Erenthar, the bowman ranger] <---------------<<<<

Re: Detect parent with SCHEDULED or DEADLINE

[Christophe Schockaert]

Christophe Schockaert writes:

> Nicolas Goaziou writes:
>
>> Adam Porter <adam@alphapapa.net> writes:
[...]
> Thank you Adam and Nicolas for your answers,
>
[...]
> I could rewrite my function using 'org-up-heading-safe' and
> 'org-entry-get', and it gets the expected result in the agenda view :-)

Sorry for multiple posting, I thought afterwards I could share the
solution I came with:

#+BEGIN_SRC elisp
(defun r3v/skip-inherited-scheduled-or-deadline ()
  "Skip tasks that inherit from SCHEDULED or DEADLINE"
  (let ((next-headline (save-excursion (or (outline-next-heading) (point-max))))
        (inherited-scheduled)
        (inherited-deadline))
    (save-excursion
      (save-restriction
        (widen)
        (while (and (not inherited-scheduled) 
                    (not inherited-deadline)
                    (org-up-heading-safe))
          (setq inherited-scheduled
                (org-entry-get (point) "SCHEDULED"))
          (setq inherited-deadline
                (org-entry-get (point) "DEADLINE"))
          )
        (if (or (org-not-nil inherited-scheduled)
                (org-not-nil inherited-deadline))
            next-headline
          nil)))))
#+END_SRC


Christophe

-- 
--------------->  mailto:R3vLibre@citadels.eu
Once it's perfectly aimed, the flying arrow goes straight to its target.
Thus, don't worry when things go right.
There will be enough time to worry about if they go wrong.
Then, it's time to fire a new arrow towards another direction.
Don't sink.  Adapt yourself !  The archer has to shoot accurately and quickly.
[Words of Erenthar, the bowman ranger] <---------------<<<<

Re: Detect parent with SCHEDULED or DEADLINE

[Adam Porter]

Christophe Schockaert <R3vLibre@citadels.eu> writes:

>     (save-excursion
>       (save-restriction
>         (widen)

Hi Christophe,

Thanks for sharing the solution!  Here's something you might want to add
to it, something I recently discovered.  The `org-with-wide-buffer'
macro can replace those three lines:

#+BEGIN_SRC elisp
(defmacro org-with-wide-buffer (&rest body)
  "Execute body while temporarily widening the buffer."
  `(save-excursion
     (save-restriction
       (widen)
       ,@body)))
#+END_SRC

It's in `org-macs.el' so it's included with Org.

Re: Detect parent with SCHEDULED or DEADLINE

[Christophe Schockaert]

Adam Porter writes:

> Christophe Schockaert <R3vLibre@citadels.eu> writes:
>
>>     (save-excursion
>>       (save-restriction
>>         (widen)
>
> Hi Christophe,
>
> Thanks for sharing the solution!  Here's something you might want to add
> to it, something I recently discovered.  The `org-with-wide-buffer'
> macro can replace those three lines:
Heye, Great \o/

I am amazed to see the many subtlelties under the cover !

Chr.
-- 
--------------->  mailto:R3vLibre@citadels.eu
Once it's perfectly aimed, the flying arrow goes straight to its target.
[...]