From: Federico Beffa <beffa@ieee.org>
To: rasmus@gmx.us, emacs-orgmode@gnu.org
Subject: [PATCH] org.el: make org-paragraph-fill ignore \[...\] regions starting and ending a line
Date: Tue, 5 Aug 2014 23:45:03 +0200 [thread overview]
Message-ID: <CAKrPhPNdp12QOSfx_PqQxFmoQ3FZcO89oU+Rc4zXDN+V+ZBF1A@mail.gmail.com> (raw)
[-- Attachment #1: Type: text/plain, Size: 1496 bytes --]
>>> The current proposal is to make them elements instead of objects in Org
>>> syntax (i.e, a `latex-environment' instead of a `latex-fragment'). In
>>> a nutshell:
>>>
>>> - Pros:
>>> + conform to LaTeX intent,
>>> + impossible to fill.
>>> - Cons:
>>> - documents containing \[...\] mid-line will be broken (such
>>> constructs will not be recognized anymore).
...
> If this is always the case for you, you can "fix" this behavior by
> always putting it in a new paragraph and using a filter.
OK, I understand that the Cons above is a serious issue and nobody wants it.
For this reason I went back to my original idea and modified the
`org-fill-paragraph' function. This provides the two Pros above
without having to introduce the undesired Cons. The behavior is a
follows:
- if \[...\] is inline, behave as before.
- if \[ is the first non space character of a line and the closing \]
is the last non space character of a line (possibly spanning several
lines), then do not fill this region of the paragraph.
Attached you find a patch with the proposed modification. I would
greatly appreciate if you could consider it for inclusion in org-mode
and provide feedback.
I understand that if you are willing to make use of this patch, I will
have to sign a copyright assignment form. This is not a problem, but
please do not make me waste time with forms if you do not want to
include the patch in org-mode. Please provide instructions on how to
proceed.
Regards,
Federico.
[-- Attachment #2: 0001-org.el-make-org-paragraph-fill-ignore-.-regions-star.patch --]
[-- Type: application/octet-stream, Size: 6073 bytes --]
From 13f2b01e2c7b2dc7d11c7c90640d075f02fcc6c3 Mon Sep 17 00:00:00 2001
From: Federico Beffa <beffa@fbengineering.ch>
Date: Tue, 5 Aug 2014 23:08:26 +0200
Subject: [PATCH] org.el: make org-paragraph-fill ignore \[...\] regions
starting and ending a line
* lisp/org.el (org-paragraph-fill): If a LaTeX \[...\] macro starts
a line and ends a line (possibly spanning multiple lines), then do not
change that part of the paragraph.
---
lisp/org.el | 128 ++++++++++++++++++++++++++++++++++++++++++++++++++++-------
1 files changed, 113 insertions(+), 15 deletions(-)
mode change 100644 => 100755 lisp/org.el
diff --git a/lisp/org.el b/lisp/org.el
old mode 100644
new mode 100755
index 0f7a4ef..6cb0cd3
--- a/lisp/org.el
+++ b/lisp/org.el
@@ -22775,6 +22775,118 @@ matches in paragraphs or comments, use it."
(declare-function message-goto-body "message" ())
(defvar message-cite-prefix-regexp) ; From message.el
+
+(defun org-paragraph-find-dmr (beg end)
+ "Find \\=\\[...\\=\\] LaTeX macros starting and ending a line.
+
+This function returns a list of the form ((dm1-beg dm1-end)
+... (dmN-beg dmN-end)) with dmi-beg and dmi-end, i=1,...,N
+denoting the start respectively the end positions of the i-th
+\\=\\[...\\=\\] display math LaTeX macros starting and ending a
+line (possibly spanning multiple-lines). This means that \\=\\[
+must be the first non space character of a line and \\=\\] must
+the the last non space character of a line. The two can be on
+different lines."
+ (let ((dmrl nil) (dmr nil))
+ (save-excursion
+ (goto-char end)
+ (while (setq dmr
+ (if
+ (re-search-backward
+ (concat
+ "\\(^[ \t]*\\\\\\[\\).*\\([\r]?\n\\)*"
+ "\\(.+[\r]?\n\\)*"
+ ".*\\\\\\]"
+ "[ \t]*[\r]?\n") beg t)
+ (list (match-beginning 1) (match-end 0))
+ nil))
+ (setq dmrl (append (list dmr) dmrl))))
+ dmrl))
+
+(defun org-paragraph-find-line-breaks (beg end)
+ "Find org `line-break' objects in a paragraph.
+
+Find the positions of org `line-break' objects and returns a list
+with their position, including BEG and END."
+ (append
+ (cons beg
+ (org-element-map
+ (org-element--parse-objects
+ beg end nil (org-element-restriction 'paragraph))
+ 'line-break
+ (lambda (lb) (org-element-property :end lb))))
+ (list end)))
+
+(defun org-fill-paragraph-construct-regions (lbl dmrl)
+ "Construct paragraph regions to be filled.
+
+This function takes a list LBL with the positions of org
+`line-break' objects and a list DMRL with the start and end
+positions of \\=\\[...\\=\\] LaTeX macros beginning and ending a
+line. It returns a list of the form ((r1-beg r1-end) ... (rN-beg
+rN-end)) with the start end end positions of the paragraph
+regions to be filled."
+ (let ((lbl-new lbl))
+ ;; first we make sure there are no line-breaks within displayed
+ ;; math regions
+ (dolist (lb-elt lbl)
+ (mapc (lambda (x)
+ (when (and (> lb-elt (nth 0 x)) (< lb-elt (nth 1 x)))
+ (setq lbl-new (remove lb-elt lbl-new))))
+ dmrl)
+ )
+ ;; then we construct the regions to be filled
+ (let ((lb-this (car lbl-new)) (dmrl-local dmrl)
+ dmr-elt regions lb-done)
+ (dolist (lb-next (cdr lbl-new))
+ (setq lb-done nil)
+ ;; we have to keep the current line break until we put it at
+ ;; the right place, possibly after some displayed math regions
+ (while (not lb-done)
+ (if (setq dmr-elt (car dmrl-local))
+ (cond
+ ;; line break before next displayed math region
+ ((< lb-next (nth 0 dmr-elt))
+ (setq regions (append regions (list (list lb-this lb-next))))
+ (setq lb-done t)
+ (setq lb-this lb-next))
+ ;; line break after display math region
+ (t
+ (setq regions (append
+ regions
+ (list (list lb-this (nth 0 dmr-elt)))))
+ (setq lb-this (nth 1 dmr-elt))
+ (setq dmrl-local (cdr dmrl-local))
+ (setq lb-done nil)))
+ ;; no displayed math regions left
+ (progn
+ (setq lb-done t)
+ ;; if a displayed math region finishes a paragraph we do
+ ;; not need to fill the region after the ending
+ ;; displayed math region.
+ (unless (eq lb-this lb-next)
+ (setq regions (append
+ regions
+ (list (list lb-this lb-next)))))
+ (setq lb-this lb-next)))))
+ regions)))
+
+(defun org-fill-paragraph-regions (beg end justify)
+ "Fill paragraph starting at BEG and ending at END.
+
+This function is called by `org-fill-paragraph' to fill a
+paragraph. If a LaTeX \\=\\[...\\=\\] macro starts a line and
+ends a line (possibly spanning multiple lines), then do not
+change that part of the paragraph. Respect org `line-break'
+objects."
+ (let* ((dmrl (org-paragraph-find-dmr beg end))
+ (lbl (org-paragraph-find-line-breaks beg end))
+ (fill-regions (org-fill-paragraph-construct-regions lbl dmrl)))
+ ;; fill the various regions starting from the last one
+ (mapc (lambda (r)
+ (fill-region-as-paragraph (nth 0 r) (nth 1 r) justify))
+ (nreverse fill-regions))))
+
(defun org-fill-paragraph (&optional justify)
"Fill element at point, when applicable.
@@ -22846,21 +22958,7 @@ a footnote definition, try to fill the first paragraph within."
;; separators, and fill the parts in reverse order to
;; avoid messing with markers.
(save-excursion
- (goto-char end)
- (mapc
- (lambda (pos)
- (fill-region-as-paragraph pos (point) justify)
- (goto-char pos))
- ;; Find the list of ending positions for line breaks
- ;; in the current paragraph. Add paragraph
- ;; beginning to include first slice.
- (nreverse
- (cons beg
- (org-element-map
- (org-element--parse-objects
- beg end nil (org-element-restriction 'paragraph))
- 'line-break
- (lambda (lb) (org-element-property :end lb)))))))
+ (org-fill-paragraph-regions beg end justify))
t)))
;; Contents of `comment-block' type elements should be
;; filled as plain text, but only if point is within block
--
1.7.9
next reply other threads:[~2014-08-05 21:45 UTC|newest]
Thread overview: 16+ messages / expand[flat|nested] mbox.gz Atom feed top
2014-08-05 21:45 Federico Beffa [this message]
2014-08-09 8:00 ` [PATCH] org.el: make org-paragraph-fill ignore \[...\] regions starting and ending a line Nicolas Goaziou
2014-08-09 10:20 ` Federico Beffa
2014-08-09 23:20 ` Nicolas Goaziou
-- strict thread matches above, loose matches on Subject: below --
2014-08-07 13:56 Federico Beffa
2014-08-10 13:13 Federico Beffa
2014-08-11 13:06 ` Nicolas Goaziou
2014-08-11 18:27 ` Federico Beffa
2014-08-11 19:43 ` Rasmus
2014-08-11 20:44 ` Nicolas Goaziou
2014-08-16 7:50 ` Federico Beffa
2014-08-16 9:46 ` Nicolas Goaziou
2014-08-11 20:40 ` Nicolas Goaziou
2014-08-16 7:38 ` Federico Beffa
2014-08-28 10:10 ` Nicolas Goaziou
2014-08-10 13:15 Federico Beffa
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
List information: https://www.orgmode.org/
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=CAKrPhPNdp12QOSfx_PqQxFmoQ3FZcO89oU+Rc4zXDN+V+ZBF1A@mail.gmail.com \
--to=beffa@ieee.org \
--cc=emacs-orgmode@gnu.org \
--cc=rasmus@gmx.us \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.savannah.gnu.org/cgit/emacs/org-mode.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).