From: Leo Butler <Leo.Butler@umanitoba.ca>
To: Ihor Radchenko <yantar92@posteo.net>
Cc: Org Mode List <emacs-orgmode@gnu.org>
Subject: Re: [BUG] Re: The orgframe construct in the Beamer exporter as a default needs a rethink
Date: Sun, 17 Mar 2024 13:18:12 +0000 [thread overview]
Message-ID: <87cyrt3sks.fsf@t14.reltub.ca> (raw)
In-Reply-To: <87r0g9yyj1.fsf@localhost> (Ihor Radchenko's message of "Sun, 17 Mar 2024 09:53:54 +0000")
[-- Attachment #1: Type: text/plain, Size: 1250 bytes --]
On Sun, Mar 17 2024, Ihor Radchenko <yantar92@posteo.net> wrote:
> Leo Butler <Leo.Butler@umanitoba.ca> writes:
>
>>>> I'd prefer to keep this information in the INFO channel.
>>>> It will be more consistent.
>>
>> Apologies, I messed up the patch in the previous email.
>>
>> Attached is a patch that compiles cleanly and uses INFO.
>
> Thanks!
>
>> + (frame (let ((selection
>> + (or (and fragilep
>> + (or (string-search "\\begin{frame}" contents)
>> + (string-search "\\end{frame}" contents))
>
> Please use `string-match-p'. `string-search' is not available in Emacs
> 27, which we still support.
Done.
>
>> + org-beamer-frame-environment)
>> + "frame")))
>> + (unless (string= selection "frame")
>> + (setq info (plist-put info :define-frame t)))
>
> Let's use "beamer" prefix to indicate that this plist entry is
> beamer backend-specific. Something like :beamer-define-frame.
Done.
Attached is the updated patch. In addition, I have written three
regression tests that are attached in a separate patch.
Leo
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: 0001-lisp-ox-beamer.el-constrain-use-of-org-beamer-frame-.patch --]
[-- Type: text/x-diff; name="0001-lisp-ox-beamer.el-constrain-use-of-org-beamer-frame-.patch", Size: 2991 bytes --]
From 3b10e0013ba98cbc2b441507da359996e3d8701c Mon Sep 17 00:00:00 2001
From: Leo Butler <leo.butler@umanitoba.ca>
Date: Tue, 12 Mar 2024 15:11:27 -0500
Subject: [PATCH 1/2] lisp/ox-beamer.el: constrain use of
org-beamer-frame-environment
* lisp/ox-beamer.el (org-beamer--format-frame, org-beamer-template):
Only use `org-beamer-frame-environment' when a frame is marked as
fragile and the frame's contents include either \begin{frame} or
\end{frame}. When `org-beamer-frame-environment' is used and not
equal to "frame", add the property :beamer-define-frame to INFO and
set it to t. When that property is t, `org-beamer-template' emits a
definition of the alternative frame environment.
Refs: https://list.orgmode.org/orgmode/87bk7jeik8.fsf@localhost/
https://list.orgmode.org/87a5nux3zr.fsf@t14.reltub.ca/T/
---
lisp/ox-beamer.el | 21 +++++++++++++++++----
1 file changed, 17 insertions(+), 4 deletions(-)
diff --git a/lisp/ox-beamer.el b/lisp/ox-beamer.el
index 4fad37b59..8bae93c11 100644
--- a/lisp/ox-beamer.el
+++ b/lisp/ox-beamer.el
@@ -429,8 +429,21 @@ used as a communication channel."
;; among `org-beamer-verbatim-elements'.
(org-element-map headline org-beamer-verbatim-elements 'identity
info 'first-match))
- (frame (or (and fragilep org-beamer-frame-environment)
- "frame")))
+ ;; If FRAGILEP is non-nil and CONTENTS contains an occurrence
+ ;; of \begin{frame} or \end{frame}, then set the FRAME
+ ;; environment to be `org-beamer-frame-environment';
+ ;; otherwise, use "frame". If the selected environment is not
+ ;; "frame", then add the property :beamer-define-frame to
+ ;; INFO and set it to t.
+ (frame (let ((selection
+ (or (and fragilep
+ (or (string-match-p "\\\\begin{frame}" contents)
+ (string-match-p "\\\\end{frame}" contents))
+ org-beamer-frame-environment)
+ "frame")))
+ (unless (string= selection "frame")
+ (setq info (plist-put info :beamer-define-frame t)))
+ selection)))
(concat "\\begin{" frame "}"
;; Overlay specification, if any. When surrounded by
;; square brackets, consider it as a default
@@ -851,8 +864,8 @@ holding export options."
(org-latex--insert-compiler info)
;; Document class and packages.
(org-latex-make-preamble info)
- ;; Define the alternative frame environment.
- (unless (equal "frame" org-beamer-frame-environment)
+ ;; Define the alternative frame environment, if needed.
+ (when (plist-get info :beamer-define-frame)
(format "\\newenvironment<>{%s}[1][]{\\begin{frame}#2[environment=%1$s,#1]}{\\end{frame}}\n"
org-beamer-frame-environment))
;; Insert themes.
--
2.43.0
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #3: 0002-testing-lisp-test-ox-beamer.el-New-regression-tests-.patch --]
[-- Type: text/x-diff; name="0002-testing-lisp-test-ox-beamer.el-New-regression-tests-.patch", Size: 4841 bytes --]
From 4377c4a55d1fe879b92f268edebcf03d72821703 Mon Sep 17 00:00:00 2001
From: Leo Butler <leo.butler@umanitoba.ca>
Date: Sun, 17 Mar 2024 08:14:54 -0500
Subject: [PATCH 2/2] testing/lisp/test-ox-beamer.el: New regression tests for
ox-beamer.
* testing/lisp/test-ox-beamer.el (ox-beamer/orgframe,
ox-beamer/orgframe-in-example, ox-beamer/orgframe-in-one-example): New
file. Regression tests for ox-beamer. Test that the
`org-beamer-frame-environment' is defined only when used.
---
testing/lisp/test-ox-beamer.el | 110 +++++++++++++++++++++++++++++++++
1 file changed, 110 insertions(+)
create mode 100644 testing/lisp/test-ox-beamer.el
diff --git a/testing/lisp/test-ox-beamer.el b/testing/lisp/test-ox-beamer.el
new file mode 100644
index 000000000..be83b12e0
--- /dev/null
+++ b/testing/lisp/test-ox-beamer.el
@@ -0,0 +1,110 @@
+;;; test-ox-beamer.el --- tests for ox-beamer.el -*- lexical-binding: t; -*-
+
+;; Copyright (C) 2024 Leo Butler
+
+;; Author: Leo Butler <leo.butler@umanitoba.ca>
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program. If not, see <https://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;; Tests checking validity of Org Beamer export output.
+
+;;; Code:
+
+(require 'ox-beamer nil t)
+(unless (featurep 'ox-beamer)
+ (signal 'missing-test-dependency "org-export-beamer"))
+
+\f
+
+(ert-deftest ox-beamer/orgframe ()
+ "Test that `org-beamer-frame-environment' is defined and used."
+ (org-test-with-exported-text
+ 'beamer
+ "#+OPTIONS: toc:nil
+* A frame
+Here is an example:
+#+begin_example
+\\begin{frame}
+...
+\\end{frame}
+#+end_example
+"
+ (goto-char (point-min))
+ (should (search-forward (concat "\\newenvironment<>{" org-beamer-frame-environment "}") nil t))
+ (should (search-forward (concat "\\begin{" org-beamer-frame-environment "}") nil t))
+ (should (search-forward (concat "\\end{" org-beamer-frame-environment "}") nil t))))
+
+(ert-deftest ox-beamer/orgframe-in-example ()
+ "Test that `org-beamer-frame-environment' is not defined."
+ (org-test-with-exported-text
+ 'beamer
+ (concat "#+OPTIONS: toc:nil
+* A frame
+Here is an example:
+#+begin_example
+\\begin{" org-beamer-frame-environment "}
+...
+\\end{" org-beamer-frame-environment "}
+#+end_example
+")
+ (goto-char (point-min))
+ (should-not (search-forward
+ (concat "\\newenvironment<>{" org-beamer-frame-environment "}") nil t))
+ (forward-line)
+ (should (search-forward (concat "\\begin{frame}") nil t))
+ (should (search-forward (concat "\\begin{" org-beamer-frame-environment "}")))
+ (should (search-forward (concat "\\end{" org-beamer-frame-environment "}")))
+ (should (search-forward (concat "\\end{frame}") nil t))))
+
+(ert-deftest ox-beamer/orgframe-in-one-example ()
+ "Test that `org-beamer-frame-environment' is defined.
+First frame should use \"frame\" environment, the second uses
+`org-beamer-frame-environment'."
+ (org-test-with-exported-text
+ 'beamer
+ (concat "#+OPTIONS: toc:nil
+* A frame
+Here is an example:
+#+begin_example
+\\begin{" org-beamer-frame-environment "}
+...
+\\end{" org-beamer-frame-environment "}
+#+end_example
+
+* A second frame
+Here is a second example:
+#+begin_example
+\\begin{frame}
+...
+\\end{frame}
+#+end_example
+")
+ (goto-char (point-min))
+ (should (search-forward
+ (concat "\\newenvironment<>{" org-beamer-frame-environment "}") nil t))
+ (forward-line)
+ (org-test-ignore-duplicate
+ (should (search-forward (concat "\\begin{frame}") nil t))
+ (should (search-forward (concat "\\begin{" org-beamer-frame-environment "}")))
+ (should (search-forward (concat "\\end{" org-beamer-frame-environment "}")))
+ (should (search-forward (concat "\\end{frame}") nil t))
+ (should (search-forward (concat "\\begin{" org-beamer-frame-environment "}")))
+ (should (search-forward (concat "\\begin{frame}") nil t))
+ (should (search-forward (concat "\\end{frame}") nil t))
+ (should (search-forward (concat "\\end{" org-beamer-frame-environment "}"))))))
+
+(provide 'test-ox-beamer)
+;;; test-ox-beamer.el ends here
--
2.43.0
next prev parent reply other threads:[~2024-03-17 13:24 UTC|newest]
Thread overview: 25+ messages / expand[flat|nested] mbox.gz Atom feed top
2024-03-01 11:33 The orgframe construct in the Beamer exporter as a default needs a rethink Pedro Andres Aranda Gutierrez
2024-03-01 16:03 ` Fraga, Eric
2024-03-01 16:17 ` Pedro Andres Aranda Gutierrez
2024-03-01 17:23 ` Pedro Andres Aranda Gutierrez
2024-03-01 23:11 ` [BUG] " Leo Butler
2024-03-02 6:24 ` Pedro Andres Aranda Gutierrez
2024-03-02 6:39 ` Pedro Andres Aranda Gutierrez
2024-03-02 8:25 ` Pedro Andres Aranda Gutierrez
2024-03-02 12:22 ` Ihor Radchenko
2024-03-02 19:03 ` Pedro Andres Aranda Gutierrez
2024-03-04 11:10 ` Ihor Radchenko
2024-03-09 8:33 ` Pedro Andres Aranda Gutierrez
2024-03-12 12:33 ` Ihor Radchenko
2024-03-12 20:32 ` Leo Butler
2024-03-13 7:16 ` Pedro Andres Aranda Gutierrez
2024-03-13 13:12 ` Ihor Radchenko
2024-03-14 15:49 ` Leo Butler
2024-03-15 14:02 ` Ihor Radchenko
2024-03-16 13:12 ` Leo Butler
2024-03-16 23:24 ` Leo Butler
2024-03-17 9:53 ` Ihor Radchenko
2024-03-17 13:18 ` Leo Butler [this message]
2024-03-17 14:36 ` Ihor Radchenko
2024-03-02 12:21 ` Ihor Radchenko
2024-03-02 12:20 ` Ihor Radchenko
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
List information: https://www.orgmode.org/
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=87cyrt3sks.fsf@t14.reltub.ca \
--to=leo.butler@umanitoba.ca \
--cc=emacs-orgmode@gnu.org \
--cc=yantar92@posteo.net \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.savannah.gnu.org/cgit/emacs/org-mode.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).