fill paragraph: break after sentence.

fill paragraph: break after sentence.

[Uwe Brauer]

Hello

I would like to modify the auto-fill function such that after every
sentence a new line starts like this

In order to prove our nonlinear instability result, we want to use the
linear growing mode in Proposition to construct small initial data for
the nonlinear problem. 
Since we are involved in the higher-order regularity context, we
cannot simply set the initial data for the nonlinear problem to be a
small constant times the linear growing modes. 

I know about functions doing that for auctex, but does anybody know
about a  similar functionality for orgmode?

Uwe Brauer 

Re: fill paragraph: break after sentence.

[Aaron Ecay]

Hi Uwe,

The following code is what I use.  It uses filladapt mode, but doesn’t
work with auto-fill (I manually refill paragraphs with M-q as I’m
writing).  I wrote the code a long time ago, it works for me, YMMV,
etc.  Hope it is helpful.

#+BEGIN_SRC emacs-lisp
  (defun awe-org-fill-paragraph-function (&rest ignore)
    (let ((bounds (cons (save-excursion (backward-paragraph) (point))
                        (save-excursion (forward-paragraph) (point))))
          beg end end-marker)
      (save-excursion
        (goto-char (cdr bounds))
        (skip-chars-backward "\n")
        (setq end-marker (point-marker))
        (setq end (make-marker))
        (goto-char (car bounds))
        (skip-chars-forward "\n")
        (catch 'exit
          (while t
            (setq beg (point))
            (forward-sentence)
            (move-marker end (point))
            (save-excursion
              (goto-char beg)
              (when (and fill-prefix
                         (not (looking-at-p (regexp-quote fill-prefix))))
                (insert fill-prefix))
              (while (re-search-forward "\n *" end t)
                (replace-match " ")))
            (setq beg (point))
            (skip-chars-forward " \n")
            (move-marker end (point))
            (when (>= (point) end-marker)
              (throw 'exit t))
            (when (/= beg end)
              (delete-region beg end))
            (insert "\n"))))
      (set-marker end-marker nil)
      (set-marker end nil)))

  (defun awe-org-setup-fill-hook ()
    (setq-local sentence-end-base
                (rx (any ".?!")
                    (? "[fn:" (+ (any "0-9" "a-f")) "]")
                    (* (any "]\"'”)}"))))
    (when (featurep 'filladapt)
      (setq-local fill-paragraph-function #'awe-org-fill-paragraph-function)
      (make-local-variable 'filladapt-token-table)
      (make-local-variable 'filladapt-token-match-table)
      (make-local-variable 'filladapt-token-conversion-table)
      (cl-pushnew `(,(rx "#+" (or "caption" "CAPTION") ": ") org-caption)
                  filladapt-token-table :test #'equal)
      (cl-pushnew '(org-caption org-caption)
                  filladapt-token-match-table :test #'equal)
      (cl-pushnew '(org-caption . exact)
                  filladapt-token-conversion-table :test #'equal))
    (visual-line-mode 1)
    (auto-fill-mode 0))
  (add-hook 'org-mode-hook #'awe-org-setup-fill-hook)
#+END_SRC

-- 
Aaron Ecay

Re: fill paragraph: break after sentence.

[Uwe Brauer]

>>> "Aaron" == Aaron Ecay <aaronecay@gmail.com> writes:

Hi Aaron
    > Hi Uwe,
    > The following code is what I use.  It uses filladapt mode, but doesn’t
    > work with auto-fill (I manually refill paragraphs with M-q as I’m
    > writing).  I wrote the code a long time ago, it works for me, YMMV,
    > etc.  Hope it is helpful.

Thanks  a lot. This was precisely what I was looking for.
IMHO should be included somehow in vanilla org, or at least added to
some addon-pkg.


Uwe 

Re: fill paragraph: break after sentence.

[Nicolas Goaziou]

Hello,

Uwe Brauer <oub@mat.ucm.es> writes:

> IMHO should be included somehow in vanilla org,

It seems only remotely related to Org. If robust enough, I might go to
something like "fill.el" instead.

Regards,

-- 
Nicolas Goaziou

Re: fill paragraph: break after sentence.

[Uwe Brauer]

>>> "Nicolas" == Nicolas Goaziou <mail@nicolasgoaziou.fr> writes:

   > Hello,
   > Uwe Brauer <oub@mat.ucm.es> writes:

   >> IMHO should be included somehow in vanilla org,

   > It seems only remotely related to Org. If robust enough, I might go to
   > something like "fill.el" instead.

There are org related lines such as

    (cl-pushnew '(org-caption org-caption)
                  filladapt-token-match-table :test #'equal)
      (cl-pushnew '(org-caption . exact)

But you are right, these are fews. @Aaron I think such a function would
be appreciated in general. I have a particular solution for auctex
provide to me by 
Ingo Lohmar
http://pleasefindattached.blogspot.com/2011/12/emacsauctex-sentence-fill-greatly.html

But your code seems much more general. May I suggest to present that
code in GNU emacs devel?

Uwe 

Re: fill paragraph: break after sentence.

[Andreas Röhler]

On 06.09.2016 10:23, Uwe Brauer wrote:
> Hello
>
> I would like to modify the auto-fill function such that after every
> sentence a new line starts like this
>
> In order to prove our nonlinear instability result, we want to use the
> linear growing mode in Proposition to construct small initial data for
> the nonlinear problem.
> Since we are involved in the higher-order regularity context, we
> cannot simply set the initial data for the nonlinear problem to be a
> small constant times the linear growing modes.
>
> I know about functions doing that for auctex, but does anybody know
> about a  similar functionality for orgmode?
>
> Uwe Brauer
>

In use here is ar-forward-sentence-atpt as part of thing-at-point-utils 
toolkit

https://github.com/andreas-roehler/werkstatt/tree/master/thing-at-point-utils