;;; org-id.el --- Global identifiers for Org entries -*- lexical-binding: t; -*-
;;
;; Copyright (C) 2008-2016 Free Software Foundation, Inc.
;;
;; Author: Carsten Dominik <carsten at orgmode dot org>
;; Keywords: outlines, hypermedia, calendar, wp
;; Homepage: http://orgmode.org
;;
;; This file is part of GNU Emacs.
;;
;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;;; Commentary:

;; This file implements globally unique identifiers for Org entries.
;; Identifiers are stored in the entry as an :ID: property.  Functions
;; are provided that create and retrieve such identifiers, and that find
;; entries based on the identifier.

;; Identifiers consist of a prefix (default "Org" given by the variable
;; `org-id-prefix') and a unique part that can be created by a number
;; of different methods, see the variable `org-id-method'.
;; Org has a builtin method that uses a compact encoding of the creation
;; time of the ID, with microsecond accuracy.  This virtually
;; guarantees globally unique identifiers, even if several people are
;; creating IDs at the same time in files that will eventually be used
;; together.
;;
;; By default Org uses UUIDs as global unique identifiers.
;;
;; This file defines the following API:
;;
;; org-id-get
;;        Get the ID property of an entry.  Using appropriate arguments
;;        to the function, it can also create the ID for this entry.
;;
;; org-id-goto
;;        Command to go to a specific ID, this command can be used
;;        interactively.
;;
;; org-id-get-with-outline-path-completion
;;        Retrieve the ID of an entry, using outline path completion.
;;        This function can work for multiple files.
;;
;; org-id-get-with-outline-drilling
;;        Retrieve the ID of an entry, using outline path completion.
;;        This function only works for the current file.
;;
;; org-id-find
;;        Find the location of an entry with specific id.
;;

;;; Code:

(require 'org)
(require 'cl-lib)

;;; Customization

(defgroup org-id nil
  "Options concerning global entry identifiers in Org-mode."
  :tag "Org ID"
  :group 'org)

(defcustom org-id-link-to-org-use-id nil
  "Non-nil means storing a link to an Org file will use entry IDs.
\\<org-mode-map>\

The variable can have the following values:

t     Create an ID if needed to make a link to the current entry.

create-if-interactive
      If `org-store-link' is called directly (interactively, as a user
      command), do create an ID to support the link.  But when doing the
      job for capture, only use the ID if it already exists.  The
      purpose of this setting is to avoid proliferation of unwanted
      IDs, just because you happen to be in an Org file when you
      call `org-capture' that automatically and preemptively creates a
      link.  If you do want to get an ID link in a capture template to
      an entry not having an ID, create it first by explicitly creating
      a link to it, using `\\[org-insert-link]' first.

create-if-interactive-and-no-custom-id
      Like create-if-interactive, but do not create an ID if there is
      a CUSTOM_ID property defined in the entry.

use-existing
      Use existing ID, do not create one.

nil   Never use an ID to make a link, instead link using a text search for
      the headline text."
  :group 'org-link-store
  :group 'org-id
  :version "24.3"
  :type '(choice
	  (const :tag "Create ID to make link" t)
	  (const :tag "Create if storing link interactively"
		 create-if-interactive)
	  (const :tag "Create if storing link interactively and no CUSTOM_ID is present"
		 create-if-interactive-and-no-custom-id)
	  (const :tag "Only use existing" use-existing)
	  (const :tag "Do not use ID to create link" nil)))

(defconst org-id-uuid-program nil
  "Obsolete and unused.")
(make-obsolete-variable 'org-id-uuid-program "it is no longer needed." "Org 9.0")

(defconst org-id-method nil
  "Obsolete and unused.")
(make-obsolete-variable 'org-id-method "it is no longer needed." "Org 9.0")

(defcustom org-id-prefix nil
  "The prefix for IDs.

This may be a string, or it can be nil to indicate that no prefix is required.
When a string, the string should have no space characters as IDs are expected
to have no space characters in them."
  :group 'org-id
  :type '(choice
	  (const :tag "No prefix")
	  (string :tag "Prefix")))

(defconst org-id-include-domain nil
  "Obsolete and ignored.")
(make-obsolete-variable 'org-id-include-domain "it is no longer needed." "Org 9.0")

(defcustom org-id-track-globally t
  "Non-nil means track IDs through files, so that links work globally.
This work by maintaining a hash table for IDs and writing this table
to disk when exiting Emacs.  Because of this, it works best if you use
a single Emacs process, not many.

When nil, IDs are not tracked.  Links to IDs will still work within
a buffer, but not if the entry is located in another file.
IDs can still be used if the entry with the id is in the same file as
the link."
  :group 'org-id
  :type 'boolean)

(defcustom org-id-locations-file (convert-standard-filename
				  (concat user-emacs-directory ".org-id-locations"))
  "The file for remembering in which file an ID was defined.
This variable is only relevant when `org-id-track-globally' is set."
  :group 'org-id
  :type 'file)

(defvar org-id-locations nil
  "List of files with IDs in those files.")

(defconst org-id-files nil
  "Use the function instead.")
(make-obsolete-variable 'org-id-files "use the identically-named function instead." "Org 9.0")

(defcustom org-id-extra-files 'org-agenda-text-search-extra-files
  "Files to be searched for IDs, besides the agenda files.
When Org reparses files to remake the list of files and IDs it is tracking,
it will normally scan the agenda files, the archives related to agenda files,
any files that are listed as ID containing in the current register, and
any Org file currently visited by Emacs.
You can list additional files here.
This variable is only relevant when `org-id-track-globally' is set."
  :group 'org-id
  :type
  '(choice
    (symbol :tag "Variable")
    (repeat :tag "List of files"
	    (file))))

(defcustom org-id-search-archives t
  "Non-nil means search also the archive files of agenda files for entries.
This is a possibility to reduce overhead, but it means that entries moved
to the archives can no longer be found by ID.
This variable is only relevant when `org-id-track-globally' is set."
  :group 'org-id
  :type 'boolean)

;;; The API functions

;;;###autoload
(defun org-id-get-create (&optional arg)
  "DEPRECATED -- use `org-id-get' instead.

Create an ID for the current entry and return it.
If the entry already has an ID, just return it.
With optional argument FORCE, force the creation of a new ID."
  (interactive "P")
  (org-id-get 'create (when arg 'reset)))
(make-obsolete 'org-id-get-create 'org-id-get "Org 9.0")

;;;###autoload
(defun org-id-copy ()
  "Copy the ID of the entry at point to the kill ring.
Create an ID if necessary."
  (interactive)
  (org-kill-new (org-id-get nil 'create)))

;;;###autoload
(defun org-id-get (&optional create reset)
  "Get the ID property of the entry at point.

If the entry does not have an ID, the function returns nil.
However, when CREATE is non-nil, create an ID if none is present
already.  When RESET is non-nil, the function will remove any
existing ID."
  (interactive (list 'create (when current-prefix-arg 'reset)))
  (when reset
    (org-id--reset))
  (let ((id (org-entry-get nil "ID")))
    (cond
     ((and id (org-string-nw-p id))
      id)
     (create
      (setq id (org-id-new))
      (org-entry-put nil "ID" id)
      (org-id--add-location id (buffer-file-name (buffer-base-buffer)))
      id))))

;;;###autoload
(defun org-id-get-with-outline-path-completion (&optional targets)
  "Use `outline-path-completion' to retrieve the ID of an entry.
TARGETS may be a setting for `org-refile-targets' to define
eligible headlines.  When omitted, all headlines in the current
file are eligible.  This function returns the ID of the entry.
If necessary, the ID is created."
  (let* ((org-refile-targets (or targets '((nil . (:maxlevel . 10)))))
	 (org-refile-use-outline-path
	  (if (caar org-refile-targets) 'file t))
	 (org-refile-target-verify-function nil)
	 (spos (org-refile-get-location "Entry"))
	 (pom (and spos (move-marker (make-marker) (nth 3 spos)
				     (get-file-buffer (nth 1 spos))))))
    (prog1 (org-with-point-at pom (org-id-get 'create))
      (move-marker pom nil))))

;;;###autoload
(defun org-id-get-with-outline-drilling ()
  "Use an outline-cycling interface to retrieve the ID of an entry.
This only finds entries in the current buffer, using `org-get-location'.
It returns the ID of the entry.  If necessary, the ID is created."
  (let* ((spos (org-get-location (current-buffer) org-goto-help))
	 (pom (and spos (move-marker (make-marker) (car spos)))))
    (prog1 (org-with-point-at pom (org-id-get 'create))
      (move-marker pom nil))))

;;;###autoload
(defun org-id-goto (id)
  "Switch to the buffer containing the entry with id ID.
Move the cursor to that entry in that buffer."
  (interactive "sID: ")
  (let ((m (org-id-find id)))
    (unless m
      (error "Cannot find entry with ID \"%s\"" id))
    (pop-to-buffer-same-window (marker-buffer m))
    (goto-char m)
    (move-marker m nil)
    (org-show-context)))

;;;###autoload
(defun org-id-find (id &optional markerp recursing)
  "Return the location of the entry with the id ID.

The return value is a marker, or nil if there is no entry with
that ID.

RECURSING is used internally to detect recursive calls to this
function."
  (when markerp
    (error "The `markerp' argument to `org-id-find' is deprecated."))
  (let* ((file (org-id-find-file-for id))
	 (where (and file (org-id-find-id-in-file id file))))
    (if where
	(move-marker (make-marker) where (or (find-buffer-visiting file)
					     (find-file-noselect file)))
      (unless recursing
	(org-id-update-id-locations nil t)
	(org-id-find id nil t)))))

;;; Internal functions

;; Creating new IDs

;;;###autoload
(defun org-id-new (&optional prefix)
  "Create a new globally unique ID.

An ID consists of two parts separated by a colon:
- a prefix
- a unique part that will be created according to `org-id-method'.

PREFIX can specify the prefix, the default is given by the variable
`org-id-prefix'.  However, if PREFIX is the symbol `none', don't use any
prefix even if `org-id-prefix' specifies one.

So a typical ID could look like \"Org:4nd91V40HI\"."
  (let* ((prefix (if (eq prefix 'none)
		     ""
		   (concat (or prefix org-id-prefix) ":"))))
    (if (equal prefix ":") (setq prefix ""))
    (concat prefix (org-id-uuid))))

(defun org-id-uuid ()
  "Return string with random (version 4) UUID."
  (let ((rnd (md5 (format "%s%s%s%s%s%s%s"
			  (random)
			  (current-time)
			  (user-uid)
			  (emacs-pid)
			  (user-full-name)
			  user-mail-address
			  (recent-keys)))))
    (format "%s-%s-4%s-%s%s-%s"
	    (substring rnd 0 8)
	    (substring rnd 8 12)
	    (substring rnd 13 16)
	    (format "%x"
		    (logior
		     #b10000000
		     (logand
		      #b10111111
		      (string-to-number
		       (substring rnd 16 18) 16))))
	    (substring rnd 18 20)
	    (substring rnd 20 32))))

(defun org-id--reset ()
  "Remove the ID from the entry at point.

FIXME: this function does not remove the ID from the global tracking."
  (org-entry-put nil "ID" nil))

;; Storing ID locations (files)

;;;###autoload
(defun org-id-update-id-locations (&optional files silent)
  "Scan relevant files for IDs.
Store the relation between files and corresponding IDs.
This will scan all agenda files, all associated archives, and all
files currently mentioned in `org-id-locations'.
When FILES is given, scan these files instead.
When SILENT is non-nil, suppress messages in the minibuffer."
  (interactive)
  (unless org-id-track-globally
    (user-error "Please turn on `org-id-track-globally' if you want to track IDs"))
  (setq org-id-locations nil)
  (let* ((org-id-search-archives
	  (or org-id-search-archives
	      ;; `agenda-archives' is a funky bit inherited from the
	      ;; semantics of `org-agenda-text-search-extra-files'.
	      (and (symbolp org-id-extra-files)
		   (memq 'agenda-archives (symbol-value org-id-extra-files)))))
	 (files
	  (or files
	      (remq 'agenda-archives
		    (append
		     ;; Agenda files and all associated archives
		     (org-agenda-files t org-id-search-archives)
		     ;; Explicit extra files
		     (if (symbolp org-id-extra-files)
			 (symbol-value org-id-extra-files)
		       org-id-extra-files)
		     ;; Files associated with live Org buffers
		     (delq nil
			   (mapcar (lambda (b)
				     (with-current-buffer b
				       (and (derived-mode-p 'org-mode) (buffer-file-name))))
				   (buffer-list)))
		     ;; All files known to have IDs
		     (org-id-files)))))
	 (nfiles (length files))
	 (n 0)
	 (ndup 0)
	 org-agenda-new-buffers
	 all-ids done-files)
    (dolist (file files)
      (cl-incf n)
      (unless silent
	(message "Finding ID locations (%d/%d files): %s"
		 n nfiles file))
      (let ((tfile (file-truename file))
	    ids)
	(when (and (file-exists-p file) (not (member tfile done-files)))
	  (push tfile done-files)
	  (with-current-buffer (org-get-agenda-file-buffer file)
	    (org-with-wide-buffer
	     (goto-char (point-min))
	     (while (re-search-forward "^[ \t]*:ID:" nil t)
	       (let ((id (org-id-get)))
		 (when id
		   (if (member id all-ids)
		       (progn
			 (message "Duplicate ID \"%s\", also in file %s"
				  id
				  (or (car (cl-find-if
					    (lambda (x)
					      (member id (cdr x)))
					    org-id-locations))
				      (buffer-file-name)))
			 ;; TODO: bogus?
			 (when (= ndup 0)
			   (ding)
			   (sit-for 2))
			 (setq ndup (1+ ndup)))
		     (push id all-ids)
		     (push id ids)))))
	     (push (cons (abbreviate-file-name file) ids) org-id-locations))))))
    (org-release-buffers org-agenda-new-buffers)
    (org-id-locations-save) ;; This function can also handle the alist form.
    ;; Now convert to a hash.
    (if (> ndup 0)
	(message "WARNING: %d duplicate IDs found, check *Messages* buffer" ndup)
      (message "%d unique files scanned for IDs" (length org-id-locations)))
    (setq org-id-locations (org-id-alist-to-hash org-id-locations))
    org-id-locations))

(defun org-id-locations-save ()
  "Save `org-id-locations' in `org-id-locations-file'."
  (when (and org-id-track-globally org-id-locations)
    (let ((out (if (hash-table-p org-id-locations)
		   (org-id-hash-to-alist org-id-locations)
		 org-id-locations)))
      (with-temp-file org-id-locations-file
	(let ((print-level nil)
	      (print-length nil))
	  (print out (current-buffer)))))))

(defun org-id-locations-load ()
  "Read the data from `org-id-locations-file'."
  (setq org-id-locations nil)
  (when org-id-track-globally
    (with-temp-buffer
      (condition-case nil
	  (progn
	    (insert-file-contents-literally org-id-locations-file)
	    (goto-char (point-min))
	    (setq org-id-locations (read (current-buffer))))
	(error
	 (message "Could not read org-id-values from %s.  Setting it to nil."
		  org-id-locations-file))))
    (setq org-id-locations (org-id-alist-to-hash org-id-locations))))

(defun org-id--add-location (id file)
  "Add the ID with location FILE to the database of ID locations."
  ;; Only if global tracking is on, and when the buffer has a file
  (when (and org-id-track-globally id file)
    (unless org-id-locations (org-id-locations-load))
    (puthash id (abbreviate-file-name file) org-id-locations)))
(define-obsolete-function-alias 'org-id-add-location 'org-id--add-location "Org 9.0")

(defun org-id--remove-location (id)
  "Remove any location associated with ID from `org-id-locations'."
  (remhash id org-id-locations))

(defun org-id-files ()
  (cl-typecase org-id-locations
    (hash-table (cl-remove-duplicates (hash-table-values org-id-locations)))
    (list (mapcar 'car org-id-locations))
    (t (error "Unknown value for `org-id-locations'."))))

;;; TODO: need org-id-remove-location

(unless noninteractive
  (add-hook 'kill-emacs-hook #'org-id-locations-save))

(defun org-id-hash-to-alist (hash)
  "Turn an org-id hash into an alist, so that it can be written to a file."
  (let (res x)
    (maphash
     (lambda (k v)
       (if (setq x (member v res))
	   (setcdr x (cons k (cdr x)))
	 (push (list v k) res)))
     hash)
    res))

(defun org-id-alist-to-hash (list)
  "Turn an org-id location list into a hash table."
  (let ((res (make-hash-table
	      :test 'equal
	      :size (apply #'+ (mapcar #'length list)))))
    (dolist (pair list)
      (let ((file (car pair)))
	(dolist (id (cdr pair))
	  (puthash id file res))))
    res))

;;; TODO: make this function work on a region, rather than a span of
;;; text?  Then we could use org-id-get and the parser.  But that
;;; might make yanking more expensive.
(defun org-id--yank-tracker (txt &optional buffer-or-file)
  "Update any IDs in TXT and assign BUFFER-OR-FILE to them."
  (when org-id-track-globally
    (save-match-data
      (setq buffer-or-file (or buffer-or-file (current-buffer)))
      (when (bufferp buffer-or-file)
	(setq buffer-or-file (or (buffer-base-buffer buffer-or-file)
				 buffer-or-file))
	(setq buffer-or-file (buffer-file-name buffer-or-file)))
      (when buffer-or-file
	(let ((fname (abbreviate-file-name buffer-or-file))
	      (s 0))
	  (while (string-match "^[ \t]*:ID:[ \t]+\\([^ \t\n\r]+\\)" txt s)
	    (setq s (match-end 0))
	    (org-id--add-location (match-string 1 txt) fname)))))))

;; Finding entries with specified id

;;;###autoload
(defun org-id-find-file-for (id)
  "Query the id database for the file in which ID is located."
  (unless org-id-locations (org-id-locations-load))
  (and org-id-locations
       (hash-table-p org-id-locations)
       (gethash id org-id-locations)))
(define-obsolete-function-alias 'org-id-find-id-file 'org-id-find-file-for "Org 9.0")

(defun org-id-find-id-in-file (id file &optional markerp)
  "Return the position of the entry ID in FILE.

If that file does not exist, or if it does not contain this ID,
return nil.  With optional argument MARKERP, return the position
as a new marker."
  ;; TODO: release agenda buffers
  (when (file-exists-p file)
    (with-current-buffer (org-get-agenda-file-buffer file)
      (let ((pos (org-find-entry-with-id id)))
	(when pos
	  (if markerp
	      (move-marker (make-marker) pos (current-buffer))
	    pos))))))

;; id link type

;; Calling the following function is hard-coded into `org-store-link',
;; so we do not have to add it to `org-store-link-functions'.

;;;###autoload
(defun org-id-store-link ()
  "Store a link to the current entry, using its ID."
  (interactive)
  (when (and (buffer-file-name (buffer-base-buffer)) (derived-mode-p 'org-mode))
    (let* ((link (concat "id:" (org-id-get 'create)))
	   (desc (org-element-property :title
				       (org-element-lineage
					(org-element-at-point)
					'(headline)
					'with-self))))
      (org-store-link-props :link link :description desc :type "id")
      link)))

(defun org-id-open (id)
  "Go to the entry with id ID."
  (org-mark-ring-push)
  (let ((m (org-id-find id))
	cmd)
    (unless m
      (error "Cannot find entry with ID \"%s\"" id))
    ;; Use a buffer-switching command in analogy to finding files
    (setq cmd
	  (or
	   (cdr
	    (assq
	     (cdr (assq 'file org-link-frame-setup))
	     '((find-file . switch-to-buffer)
	       (find-file-other-window . switch-to-buffer-other-window)
	       (find-file-other-frame . switch-to-buffer-other-frame))))
	   'switch-to-buffer-other-window))
    (if (not (equal (current-buffer) (marker-buffer m)))
	(funcall cmd (marker-buffer m)))
    (goto-char m)
    (move-marker m nil)
    (org-show-context)))

(org-link-set-parameters "id" :follow #'org-id-open)

(provide 'org-id)

;; Local variables:
;; generated-autoload-file: "org-loaddefs.el"
;; End:

;;; org-id.el ends here