Re: ob-clojure breaks tangling of comments using org-babel-tangle for clojure source code blocks

[Anoop GR <anoopemacs@gmail.com>]

[-- Attachment #1: Type: text/plain, Size: 2162 bytes --]

>
> I guess that we may leave the comments intact if the code block does not
> have :var.
>

I moved the comment stripping code in org-babel-expand-body:clojure to
follow the above idea:-
---
(defun org-babel-expand-body:clojure (body params)
  "Expand BODY according to PARAMS, return the expanded body."
  (let* ((vars (org-babel--get-vars params))
         (backend-override (cdr (assq :backend params)))
         (org-babel-clojure-backend
          (cond
           (backend-override (intern backend-override))
           (org-babel-clojure-backend org-babel-clojure-backend)
           (t (user-error "You need to customize `org-babel-clojure-backend'
or set the `:backend' header argument"))))
         (ns (or (cdr (assq :ns params))
                 (if (eq org-babel-clojure-backend 'cider)
                     (or cider-buffer-ns
                         (let ((repl-buf (cider-current-connection)))
                           (and repl-buf (buffer-local-value
                                          'cider-buffer-ns repl-buf))))
                   org-babel-clojure-default-ns)))
         (result-params (cdr (assq :result-params params)))
         (print-level nil)
         (print-length nil)
         (body (org-trim
                (concat
                 ;; Source block specified namespace :ns.
                 (and (cdr (assq :ns params)) (format "(ns %s)\n" ns))
                 ;; Variables binding.
                 (if (null vars)
                     (org-trim body)
                   (let ((body (replace-regexp-in-string "^[    ]*;+.*$" ""
body)))   ; Remove comments, they break (let [...] ...) bindings
                     (format "(let [%s]\n%s)"
                             (mapconcat
                              (lambda (var)
                                (format "%S '%S" (car var) (cdr var)))
                              vars
                              "\n      ")
                             body)))))))
    (if (or (member "code" result-params)
            (member "pp" result-params))
        (format "(clojure.pprint/pprint (do %s))" body)
      body)))
---

Now, it no longer loses comments on tangling.

[-- Attachment #2: Type: text/html, Size: 3017 bytes --]