emacs-orgmode@gnu.org archives
 help / color / mirror / code / Atom feed
* How to turn off visibility-state messages from 'org-cycle?
@ 2013-07-17 14:13 Thorsten Jolitz
  2013-07-18  8:35 ` Eric S Fraga
  2013-07-18 11:40 ` How to turn off visibility-state messages from 'org-cycle? Jambunathan K
  0 siblings, 2 replies; 15+ messages in thread
From: Thorsten Jolitz @ 2013-07-17 14:13 UTC (permalink / raw)
  To: emacs-orgmode


Hi List, 

when calling Org-mode functionality form an external program, some
functions seem to make use of 'org-cycle', what results in a lot of
"OVERVIEW" messages arriving at stdout/stderr

,---------
| OVERVIEW
| OVERVIEW
| OVERVIEW
| OVERVIEW
| OVERVIEW
| OVERVIEW
| OVERVIEW
| OVERVIEW
| OVERVIEW
| OVERVIEW
| OVERVIEW
| OVERVIEW
| OVERVIEW
| ....
`---------


that are not really helpful and a bit of a hassle.

,-------------------------------------------------------------------------
| (org-cycle &optional ARG)
|  ....
|
| - When this function is called with a prefix argument, rotate the entire
|   buffer through 3 states (global cycling)
|   1. OVERVIEW: Show only top-level headlines.
|   2. CONTENTS: Show all headlines of all levels, but no body text.
|   3. SHOW ALL: Show everything.
`-------------------------------------------------------------------------

Is there a way to turn these message off? I found things like
'org-no-popups or 'org-no-warnings but nothing like
"org-no-visibility-state-messages" or so. Its not really a big problem,
rather an inconvenience, but maybe its easy to solve when knowing where
to look.

-- 
cheers,
Thorsten

^ permalink raw reply	[flat|nested] 15+ messages in thread

* Re: How to turn off visibility-state messages from 'org-cycle?
  2013-07-17 14:13 How to turn off visibility-state messages from 'org-cycle? Thorsten Jolitz
@ 2013-07-18  8:35 ` Eric S Fraga
  2013-07-18  9:32   ` Thorsten Jolitz
  2013-07-18 11:40 ` How to turn off visibility-state messages from 'org-cycle? Jambunathan K
  1 sibling, 1 reply; 15+ messages in thread
From: Eric S Fraga @ 2013-07-18  8:35 UTC (permalink / raw)
  To: Thorsten Jolitz; +Cc: emacs-orgmode

Thorsten Jolitz <tjolitz@gmail.com> writes:

> Hi List, 
>
> when calling Org-mode functionality form an external program, some
> functions seem to make use of 'org-cycle', what results in a lot of
> "OVERVIEW" messages arriving at stdout/stderr
>
> ,---------
> | OVERVIEW

[...]

> Is there a way to turn these message off? I found things like

Unfortunately, no.  The code that outputs these messages does have a
hack to turn off the output when the org file is an attachment in a gnus
message but that's about it.

I also would like to have these turned off when using an emacs batch
command which I often do to synchronise my diary with various online
calendars...

Should be easy to add a variable and then a condition on each
(message...) line in org-cycle-internal-global as all of the relevant
message lines are already within a conditional.

-- 
: Eric S Fraga (0xFFFCF67D), Emacs 24.3.50.1, Org release_8.0.5-337-g9f3bed

^ permalink raw reply	[flat|nested] 15+ messages in thread

* Re: How to turn off visibility-state messages from 'org-cycle?
  2013-07-18  8:35 ` Eric S Fraga
@ 2013-07-18  9:32   ` Thorsten Jolitz
  2013-07-18  9:52     ` Thorsten Jolitz
  0 siblings, 1 reply; 15+ messages in thread
From: Thorsten Jolitz @ 2013-07-18  9:32 UTC (permalink / raw)
  To: emacs-orgmode

Eric S Fraga <e.fraga@ucl.ac.uk> writes:

> Thorsten Jolitz <tjolitz@gmail.com> writes:
>
>> Hi List, 
>>
>> when calling Org-mode functionality form an external program, some
>> functions seem to make use of 'org-cycle', what results in a lot of
>> "OVERVIEW" messages arriving at stdout/stderr
>>
>> ,---------
>> | OVERVIEW
>
> [...]
>
>> Is there a way to turn these message off? I found things like
>
> Unfortunately, no.  The code that outputs these messages does have a
> hack to turn off the output when the org file is an attachment in a gnus
> message but that's about it.
>
> I also would like to have these turned off when using an emacs batch
> command which I often do to synchronise my diary with various online
> calendars...
>
> Should be easy to add a variable and then a condition on each
> (message...) line in org-cycle-internal-global as all of the relevant
> message lines are already within a conditional.

yes, adding this defcustom to org.el

#+begin_src emacs-lisp
  (defcustom org-cycle-silently nil
    "Non-nil means `org-cycle-internal-global' cycles silently.
  
  No messages about changing visibility state of the Org-mode
  buffer will be outputted anymore in that case. This is especially
  useful to avoid having these messages arrive at stdout or stderr
  when calling Org-mode functionality from an external program."
    :group 'org-cycle
    :type 'boolean)
#+end_src

and then changing the four

#+begin_src emacs-lisp
  (unless ga (message "CONTENTS..."))
#+end_src

lines in `org-cycle-internal-global' to something like

#+begin_src emacs-lisp
  (unless (or ga org-cycle-silently)
    (message "CONTENTS..."))
#+end_src

would do the job.

-- 
cheers,
Thorsten

^ permalink raw reply	[flat|nested] 15+ messages in thread

* Re: How to turn off visibility-state messages from 'org-cycle?
  2013-07-18  9:32   ` Thorsten Jolitz
@ 2013-07-18  9:52     ` Thorsten Jolitz
  2013-07-18  9:57       ` Thorsten Jolitz
  0 siblings, 1 reply; 15+ messages in thread
From: Thorsten Jolitz @ 2013-07-18  9:52 UTC (permalink / raw)
  To: emacs-orgmode

Thorsten Jolitz <tjolitz@gmail.com> writes:

> Eric S Fraga <e.fraga@ucl.ac.uk> writes:
>
>> Thorsten Jolitz <tjolitz@gmail.com> writes:
>>
>>> Hi List,
>>>
>>> when calling Org-mode functionality form an external program, some
>>> functions seem to make use of 'org-cycle', what results in a lot of
>>> "OVERVIEW" messages arriving at stdout/stderr
>>>
>>> ,---------
>>> | OVERVIEW
>>
>> [...]
>>
>>> Is there a way to turn these message off? I found things like
>>
>> Unfortunately, no.  The code that outputs these messages does have a
>> hack to turn off the output when the org file is an attachment in a gnus
>> message but that's about it.
>>
>> I also would like to have these turned off when using an emacs batch
>> command which I often do to synchronise my diary with various online
>> calendars...
>>
>> Should be easy to add a variable and then a condition on each
>> (message...) line in org-cycle-internal-global as all of the relevant
>> message lines are already within a conditional.
>
> yes, adding this defcustom to org.el
>
> #+begin_src emacs-lisp
>   (defcustom org-cycle-silently nil
>     "Non-nil means `org-cycle-internal-global' cycles silently.
>
>   No messages about changing visibility state of the Org-mode
>   buffer will be outputted anymore in that case. This is especially
>   useful to avoid having these messages arrive at stdout or stderr
>   when calling Org-mode functionality from an external program."
>     :group 'org-cycle
>     :type 'boolean)
> #+end_src

or, even better, since more dynamic (untested):

#+begin_src emacs-lisp
  (defvar org-cycle-silently nil
    "Suppress visibility-state-change messages when non-nil.")

  (defun org-toggle-silent-cycling (&optional arg)
    "Toggle silent cycling between visibility states.

  When silent cycling is off, visibility state-change messages are
  written to stdout (i.e. the *Messages* buffer), otherwise these
  messages are suppressed. With prefix argument ARG, cycle silently
  if ARG is positive, otherwise write state-change messages."
    (interactive "P")
    (setq org-cycle-silently
          (if (null arg)
              (not truncate-lines)
            (> (prefix-numeric-value arg) 0)))
    (message "Silent visibility cycling %s"
             (if org-cycle-silently "enabled" "disabled")))
#+end_src

> and then changing the four
>
> #+begin_src emacs-lisp
>   (unless ga (message "CONTENTS..."))
> #+end_src
>
> lines in `org-cycle-internal-global' to something like
>
> #+begin_src emacs-lisp
>   (unless (or ga org-cycle-silently)
>     (message "CONTENTS..."))
> #+end_src
>
> would do the job.

--
cheers,
Thorsten

^ permalink raw reply	[flat|nested] 15+ messages in thread

* Re: How to turn off visibility-state messages from 'org-cycle?
  2013-07-18  9:52     ` Thorsten Jolitz
@ 2013-07-18  9:57       ` Thorsten Jolitz
  2013-07-19  9:04         ` Eric S Fraga
  0 siblings, 1 reply; 15+ messages in thread
From: Thorsten Jolitz @ 2013-07-18  9:57 UTC (permalink / raw)
  To: emacs-orgmode

Thorsten Jolitz <tjolitz@gmail.com> writes:

oops, there was a left-over from inspiring `toggle-truncate-lines' in my
example function, here is the fixed version:

#+begin_src emacs-lisp
  (defvar org-cycle-silently nil
    "Suppress visibility-state-change messages when non-nil.")

  (defun org-toggle-silent-cycling (&optional arg)
    "Toggle silent cycling between visibility states.

  When silent cycling is off, visibility state-change messages are
  written to stdout (i.e. the *Messages* buffer), otherwise these
  messages are suppressed. With prefix argument ARG, cycle silently
  if ARG is positive, otherwise write state-change messages."
    (interactive "P")
    (setq org-cycle-silently
          (if (null arg)
              (not org-cycle-silently)
            (> (prefix-numeric-value arg) 0)))
    (message "Silent visibility cycling %s"
             (if org-cycle-silently "enabled" "disabled")))
#+end_src

-- 
cheers,
Thorsten

^ permalink raw reply	[flat|nested] 15+ messages in thread

* Re: How to turn off visibility-state messages from 'org-cycle?
  2013-07-17 14:13 How to turn off visibility-state messages from 'org-cycle? Thorsten Jolitz
  2013-07-18  8:35 ` Eric S Fraga
@ 2013-07-18 11:40 ` Jambunathan K
  2013-07-19  6:18   ` Thorsten Jolitz
  1 sibling, 1 reply; 15+ messages in thread
From: Jambunathan K @ 2013-07-18 11:40 UTC (permalink / raw)
  To: Thorsten Jolitz; +Cc: emacs-orgmode


Try this:

    (defadvice org-cycle-internal-local
      (around org-cycle-internal-local-suppress-messages activate)
      "Do the local cycling action, but suppress messages."
      (letf (((symbol-function 'message) (symbol-function 'ignore)))
        ad-do-it))

    (defadvice org-cycle-internal-global
      (around org-cycle-internal-global-suppress-messages activate)
      "Do the global cycling action, but suppress messages."
      (letf (((symbol-function 'message) (symbol-function 'ignore)))
        ad-do-it))

You can also use `flet' form to `ignore' the `message'.

Thorsten Jolitz <tjolitz@gmail.com> writes:

> Hi List, 
>
> when calling Org-mode functionality form an external program, some
> functions seem to make use of 'org-cycle', what results in a lot of
> "OVERVIEW" messages arriving at stdout/stderr
>
> ,---------
> | OVERVIEW
> | OVERVIEW
> | OVERVIEW
> | OVERVIEW
> | OVERVIEW
> | OVERVIEW
> | OVERVIEW
> | OVERVIEW
> | OVERVIEW
> | OVERVIEW
> | OVERVIEW
> | OVERVIEW
> | OVERVIEW
> | ....
> `---------
>
>
> that are not really helpful and a bit of a hassle.
>
> ,-------------------------------------------------------------------------
> | (org-cycle &optional ARG)
> |  ....
> |
> | - When this function is called with a prefix argument, rotate the entire
> |   buffer through 3 states (global cycling)
> |   1. OVERVIEW: Show only top-level headlines.
> |   2. CONTENTS: Show all headlines of all levels, but no body text.
> |   3. SHOW ALL: Show everything.
> `-------------------------------------------------------------------------
>
> Is there a way to turn these message off? I found things like
> 'org-no-popups or 'org-no-warnings but nothing like
> "org-no-visibility-state-messages" or so. Its not really a big problem,
> rather an inconvenience, but maybe its easy to solve when knowing where
> to look.

^ permalink raw reply	[flat|nested] 15+ messages in thread

* Re: How to turn off visibility-state messages from 'org-cycle?
  2013-07-18 11:40 ` How to turn off visibility-state messages from 'org-cycle? Jambunathan K
@ 2013-07-19  6:18   ` Thorsten Jolitz
  0 siblings, 0 replies; 15+ messages in thread
From: Thorsten Jolitz @ 2013-07-19  6:18 UTC (permalink / raw)
  To: emacs-orgmode

Jambunathan K <kjambunathan@gmail.com> writes:

> Try this:
>
>     (defadvice org-cycle-internal-local
>       (around org-cycle-internal-local-suppress-messages activate)
>       "Do the local cycling action, but suppress messages."
>       (letf (((symbol-function 'message) (symbol-function 'ignore)))
>         ad-do-it))
>
>     (defadvice org-cycle-internal-global
>       (around org-cycle-internal-global-suppress-messages activate)
>       "Do the global cycling action, but suppress messages."
>       (letf (((symbol-function 'message) (symbol-function 'ignore)))
>         ad-do-it))
>
> You can also use `flet' form to `ignore' the `message'.

Thats nice, thank you. 

On the other hand, I wonder if it wouldn't make sense to add my "patch"
to org.el, since unconditionally writing messages for every
visibility-state change produces quite a lot of clutter, so the user
should be able to turn this off IMO.

> Thorsten Jolitz <tjolitz@gmail.com> writes:
>
>> Hi List, 
>>
>> when calling Org-mode functionality form an external program, some
>> functions seem to make use of 'org-cycle', what results in a lot of
>> "OVERVIEW" messages arriving at stdout/stderr
>>
>> ,---------
>> | OVERVIEW
>> | OVERVIEW
>> | OVERVIEW
>> | OVERVIEW
>> | OVERVIEW
>> | OVERVIEW
>> | OVERVIEW
>> | OVERVIEW
>> | OVERVIEW
>> | OVERVIEW
>> | OVERVIEW
>> | OVERVIEW
>> | OVERVIEW
>> | ....
>> `---------
>>
>>
>> that are not really helpful and a bit of a hassle.
>>
>> ,-------------------------------------------------------------------------
>> | (org-cycle &optional ARG)
>> |  ....
>> |
>> | - When this function is called with a prefix argument, rotate the entire
>> |   buffer through 3 states (global cycling)
>> |   1. OVERVIEW: Show only top-level headlines.
>> |   2. CONTENTS: Show all headlines of all levels, but no body text.
>> |   3. SHOW ALL: Show everything.
>> `-------------------------------------------------------------------------
>>
>> Is there a way to turn these message off? I found things like
>> 'org-no-popups or 'org-no-warnings but nothing like
>> "org-no-visibility-state-messages" or so. Its not really a big problem,
>> rather an inconvenience, but maybe its easy to solve when knowing where
>> to look.
>
>

-- 
cheers,
Thorsten

^ permalink raw reply	[flat|nested] 15+ messages in thread

* Re: How to turn off visibility-state messages from 'org-cycle?
  2013-07-18  9:57       ` Thorsten Jolitz
@ 2013-07-19  9:04         ` Eric S Fraga
  2013-07-19 11:57           ` [PATCH] Enable silent visibility cycling (was: How to turn off visibility-state messages from 'org-cycle?) Thorsten Jolitz
  0 siblings, 1 reply; 15+ messages in thread
From: Eric S Fraga @ 2013-07-19  9:04 UTC (permalink / raw)
  To: Thorsten Jolitz; +Cc: emacs-orgmode

Would you wrap it all up in a patch and submit it?  It would be great to
have incorporated.

Thanks,
eric
-- 
: Eric S Fraga (0xFFFCF67D), Emacs 24.3.50.1, Org release_8.0.6-341-g338603

^ permalink raw reply	[flat|nested] 15+ messages in thread

* [PATCH] Enable silent visibility cycling (was: How to turn off visibility-state messages from 'org-cycle?)
  2013-07-19  9:04         ` Eric S Fraga
@ 2013-07-19 11:57           ` Thorsten Jolitz
  2013-07-19 12:23             ` [PATCH] Enable silent visibility cycling Jambunathan K
  2013-07-19 17:54             ` Eric S Fraga
  0 siblings, 2 replies; 15+ messages in thread
From: Thorsten Jolitz @ 2013-07-19 11:57 UTC (permalink / raw)
  To: emacs-orgmode

[-- Attachment #1: Type: text/plain, Size: 243 bytes --]

Eric S Fraga <e.fraga@ucl.ac.uk> writes:

> Would you wrap it all up in a patch and submit it?  It would be great to
> have incorporated.

ok, done. 

PS
I included this into `outshine.el' too, since outline-cycle showed the
same behaviour. 


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: enable silent visibility cycling --]
[-- Type: text/x-patch, Size: 3309 bytes --]

From 0a4dad9119af9aed8e5160a05e81ac35f2bb0044 Mon Sep 17 00:00:00 2001
From: tj <tj@data-driven.de>
Date: Fri, 19 Jul 2013 13:47:20 +0200
Subject: [PATCH] Org: Enable silent visibility cycling

* lisp/org.el: add boolean variable `org-cycle-silently'.
add function `org-toggle-silent-cycling'.
(org-cycle-internal-global): make visibility-state-change messages conditional
on `org-cycle-silently'.

The problem here was that, especially in batch use, unconditionally writing a
message for each visibility-state-change might send a lot of clutter to
stdout.

Modified from a patch proposal by Thorsten Jolitz.
---
 lisp/org.el | 30 ++++++++++++++++++++++++++----
 1 file changed, 26 insertions(+), 4 deletions(-)

diff --git a/lisp/org.el b/lisp/org.el
index fb5099e..1eb511d 100644
--- a/lisp/org.el
+++ b/lisp/org.el
@@ -6494,6 +6494,9 @@ and subscripts."
 
 (defvar org-inlinetask-min-level)
 
+(defvar org-cycle-silently nil
+  "Suppress visibility-state-change messages when non-nil.")
+
 ;;;###autoload
 (defun org-cycle (&optional arg)
   "TAB-action and visibility cycling for Org-mode.
@@ -6661,6 +6664,21 @@ in special contexts.
 	    (org-back-to-heading)
 	    (org-cycle)))))))
 
+(defun org-toggle-silent-cycling (&optional arg)
+  "Toggle silent cycling between visibility states.
+
+  When silent cycling is off, visibility state-change messages are
+  written to stdout (i.e. the *Messages* buffer), otherwise these
+  messages are suppressed. With prefix argument ARG, cycle silently
+  if ARG is positive, otherwise write state-change messages."
+  (interactive "P")
+  (setq org-cycle-silently
+	(if (null arg)
+	    (not org-cycle-silently)
+	  (> (prefix-numeric-value arg) 0)))
+  (message "Silent visibility cycling %s"
+	   (if org-cycle-silently "enabled" "disabled")))
+
 (defun org-cycle-internal-global ()
   "Do the global cycling action."
   ;; Hack to avoid display of messages for .org  attachments in Gnus
@@ -6672,9 +6690,11 @@ in special contexts.
       ;; We just created the overview - now do table of contents
       ;; This can be slow in very large buffers, so indicate action
       (run-hook-with-args 'org-pre-cycle-hook 'contents)
-      (unless ga (message "CONTENTS..."))
+      (unless (or ga org-cycle-silently)
+	(message "CONTENTS..."))
       (org-content)
-      (unless ga (message "CONTENTS...done"))
+      (unless (or ga org-cycle-silently)
+	(message "CONTENTS...done"))
       (setq org-cycle-global-status 'contents)
       (run-hook-with-args 'org-cycle-hook 'contents))
 
@@ -6683,7 +6703,8 @@ in special contexts.
       ;; We just showed the table of contents - now show everything
       (run-hook-with-args 'org-pre-cycle-hook 'all)
       (show-all)
-      (unless ga (message "SHOW ALL"))
+      (unless (or ga org-cycle-silently)
+	(message "SHOW ALL"))
       (setq org-cycle-global-status 'all)
       (run-hook-with-args 'org-cycle-hook 'all))
 
@@ -6691,7 +6712,8 @@ in special contexts.
       ;; Default action: go to overview
       (run-hook-with-args 'org-pre-cycle-hook 'overview)
       (org-overview)
-      (unless ga (message "OVERVIEW"))
+      (unless (or ga org-cycle-silently)
+	(message "OVERVIEW"))
       (setq org-cycle-global-status 'overview)
       (run-hook-with-args 'org-cycle-hook 'overview)))))
 
-- 
1.8.2.3


[-- Attachment #3: Type: text/plain, Size: 22 bytes --]


-- 
cheers,
Thorsten

^ permalink raw reply related	[flat|nested] 15+ messages in thread

* Re: [PATCH] Enable silent visibility cycling
  2013-07-19 11:57           ` [PATCH] Enable silent visibility cycling (was: How to turn off visibility-state messages from 'org-cycle?) Thorsten Jolitz
@ 2013-07-19 12:23             ` Jambunathan K
  2013-07-22  7:50               ` Thorsten Jolitz
  2013-07-19 17:54             ` Eric S Fraga
  1 sibling, 1 reply; 15+ messages in thread
From: Jambunathan K @ 2013-07-19 12:23 UTC (permalink / raw)
  To: Thorsten Jolitz; +Cc: emacs-orgmode


[I have no specific opinions on this patch.]

The customary way is to put each message at different level.  The
threshold level that the user wishes to see is configurable.  Any
logging message that falls below or above that threshold gets filtered.

This way you don't introduce switches on a case-by-case basis.

No different from verbosity switches of some command lines or the log
levels defined by `lwarn' etc.

In the present case, you can make cycling messages at "newbie level".
An "intermediate" or an "expert user" will not see those.  What
constitutes a level could ofcourse be defined differently ...

^ permalink raw reply	[flat|nested] 15+ messages in thread

* Re: [PATCH] Enable silent visibility cycling
  2013-07-19 11:57           ` [PATCH] Enable silent visibility cycling (was: How to turn off visibility-state messages from 'org-cycle?) Thorsten Jolitz
  2013-07-19 12:23             ` [PATCH] Enable silent visibility cycling Jambunathan K
@ 2013-07-19 17:54             ` Eric S Fraga
  2013-09-02  6:50               ` Carsten Dominik
  1 sibling, 1 reply; 15+ messages in thread
From: Eric S Fraga @ 2013-07-19 17:54 UTC (permalink / raw)
  To: Thorsten Jolitz; +Cc: emacs-orgmode

Thorsten Jolitz <tjolitz@gmail.com> writes:

> Eric S Fraga <e.fraga@ucl.ac.uk> writes:
>
>> Would you wrap it all up in a patch and submit it?  It would be great to
>> have incorporated.
>
> ok, done. 

Brilliant!  Thanks.
-- 
: Eric S Fraga (0xFFFCF67D), Emacs 24.3.50.1, Org release_8.0.6-341-g338603

^ permalink raw reply	[flat|nested] 15+ messages in thread

* Re: [PATCH] Enable silent visibility cycling
  2013-07-19 12:23             ` [PATCH] Enable silent visibility cycling Jambunathan K
@ 2013-07-22  7:50               ` Thorsten Jolitz
  2013-07-22  7:58                 ` Jambunathan K
  0 siblings, 1 reply; 15+ messages in thread
From: Thorsten Jolitz @ 2013-07-22  7:50 UTC (permalink / raw)
  To: emacs-orgmode

Jambunathan K <kjambunathan@gmail.com> writes:

> [I have no specific opinions on this patch.]
>
> The customary way is to put each message at different level.  The
> threshold level that the user wishes to see is configurable.  Any
> logging message that falls below or above that threshold gets filtered.
>
> This way you don't introduce switches on a case-by-case basis.
>
> No different from verbosity switches of some command lines or the log
> levels defined by `lwarn' etc.
>
> In the present case, you can make cycling messages at "newbie level".
> An "intermediate" or an "expert user" will not see those.  What
> constitutes a level could ofcourse be defined differently ...

Yes, it would of cource be nice to have different levels for (logging)
messages, but that seems to be a bigger project - for all of Org-mode or
even all of Emacs. So I rather propose this special-case patch where
default messaging was a bit too verbose sometimes. 

-- 
cheers,
Thorsten

^ permalink raw reply	[flat|nested] 15+ messages in thread

* Re: [PATCH] Enable silent visibility cycling
  2013-07-22  7:50               ` Thorsten Jolitz
@ 2013-07-22  7:58                 ` Jambunathan K
  2013-07-25 10:18                   ` Thorsten Jolitz
  0 siblings, 1 reply; 15+ messages in thread
From: Jambunathan K @ 2013-07-22  7:58 UTC (permalink / raw)
  To: Thorsten Jolitz; +Cc: emacs-orgmode

Thorsten Jolitz <tjolitz@gmail.com> writes:

> seems to be a bigger project

No, it is not.  Unless you consider adding these a bigger project.  

    (defvar org-message-level)

    (defun org-message (level other args)


     )

    s/message/org-message/ at some places.

Just to remind to you, I am not the gatekeeper for this project, so what
I say is not binding.

^ permalink raw reply	[flat|nested] 15+ messages in thread

* Re: [PATCH] Enable silent visibility cycling
  2013-07-22  7:58                 ` Jambunathan K
@ 2013-07-25 10:18                   ` Thorsten Jolitz
  0 siblings, 0 replies; 15+ messages in thread
From: Thorsten Jolitz @ 2013-07-25 10:18 UTC (permalink / raw)
  To: emacs-orgmode

Jambunathan K <kjambunathan@gmail.com> writes:

> Thorsten Jolitz <tjolitz@gmail.com> writes:
>
>> seems to be a bigger project
>
> No, it is not.  Unless you consider adding these a bigger project.  
>
>     (defvar org-message-level)
>
>     (defun org-message (level other args)
>
>
>      )
>
>     s/message/org-message/ at some places.
>
> Just to remind to you, I am not the gatekeeper for this project, so what
> I say is not binding.

Looks good, better than doing isolated local patches. 

-- 
cheers,
Thorsten

^ permalink raw reply	[flat|nested] 15+ messages in thread

* Re: [PATCH] Enable silent visibility cycling
  2013-07-19 17:54             ` Eric S Fraga
@ 2013-09-02  6:50               ` Carsten Dominik
  0 siblings, 0 replies; 15+ messages in thread
From: Carsten Dominik @ 2013-09-02  6:50 UTC (permalink / raw)
  To: Eric S Fraga; +Cc: emacs-orgmode, Thorsten Jolitz


On 19.7.2013, at 19:54, Eric S Fraga <e.fraga@ucl.ac.uk> wrote:

> Thorsten Jolitz <tjolitz@gmail.com> writes:
> 
>> Eric S Fraga <e.fraga@ucl.ac.uk> writes:
>> 
>>> Would you wrap it all up in a patch and submit it?  It would be great to
>>> have incorporated.
>> 
>> ok, done. 
> 
> Brilliant!  Thanks.

This works now.

Kind regards

- Carsten

> -- 
> : Eric S Fraga (0xFFFCF67D), Emacs 24.3.50.1, Org release_8.0.6-341-g338603
> 
> 

^ permalink raw reply	[flat|nested] 15+ messages in thread

end of thread, other threads:[~2013-09-02  6:50 UTC | newest]

Thread overview: 15+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2013-07-17 14:13 How to turn off visibility-state messages from 'org-cycle? Thorsten Jolitz
2013-07-18  8:35 ` Eric S Fraga
2013-07-18  9:32   ` Thorsten Jolitz
2013-07-18  9:52     ` Thorsten Jolitz
2013-07-18  9:57       ` Thorsten Jolitz
2013-07-19  9:04         ` Eric S Fraga
2013-07-19 11:57           ` [PATCH] Enable silent visibility cycling (was: How to turn off visibility-state messages from 'org-cycle?) Thorsten Jolitz
2013-07-19 12:23             ` [PATCH] Enable silent visibility cycling Jambunathan K
2013-07-22  7:50               ` Thorsten Jolitz
2013-07-22  7:58                 ` Jambunathan K
2013-07-25 10:18                   ` Thorsten Jolitz
2013-07-19 17:54             ` Eric S Fraga
2013-09-02  6:50               ` Carsten Dominik
2013-07-18 11:40 ` How to turn off visibility-state messages from 'org-cycle? Jambunathan K
2013-07-19  6:18   ` Thorsten Jolitz

Code repositories for project(s) associated with this public inbox

	https://git.savannah.gnu.org/cgit/emacs/org-mode.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).