Easily re-indent the #+OPTIONS lines

Easily re-indent the #+OPTIONS lines

[Bastien]

Hi folks,

I often fiddle around #+AUTHOR, #+TITLE, and other such lines.  But
having to re-align them so that it looks better is time-consuming.

This function does it automatically:

(defun bzg-org-indent-options ()
  "Indent option lines correctly."
  (interactive)
  (save-excursion
    (goto-char (point-min))
    (let ((max-length 0))
      (while (re-search-forward "^#\\+\\([A-Z_]+\\)" nil t)
	(if (> (length (match-string 1)) max-length)
	    (setq max-length (length (match-string 1)))))
      (goto-char (point-min))
      (while (re-search-forward "^#\\+\\([A-Z_]+\\):[ \t]*\\(.+\\)$" nil t)
	(replace-match 
	 (concat "#+" (match-string 1) ":"
		 (make-string (1+ (- max-length (length (match-string 1)))) 32)
		 (match-string 2)) t t)))))

For example, it converts this:

#+TITLE: Test file 
#+STARTUP: hidestars
#+AUTHOR: Bastien Guerry
#+EMAIL: bzg AT altern DOT org
#+OPTIONS:   H:3 num:nil toc:t \n:nil @:t ::t |:t ^:t -:t f:t 
#+SEQ_TODO:  TODO NEXT FEEDBACK VERIFY DONE
#+COLUMNS: %66ITEM %8TODO %10SCHEDULED %3PRIORITY %1TAGS

into this:

#+TITLE:      Test file 
#+STARTUP:    hidestars
#+AUTHOR:     Bastien Guerry
#+EMAIL:      bzg AT altern DOT org
#+OPTIONS:    H:3 num:nil toc:t \n:nil @:t ::t |:t ^:t -:t f:t 
#+SEQ_TODO:   TODO NEXT FEEDBACK VERIFY DONE
#+COLUMNS:    %66ITEM %8TODO %10SCHEDULED %3PRIORITY %1TAGS

-- 
Bastien

Re: Easily re-indent the #+OPTIONS lines

[Phil Jackson]

Hey Bastien,

Bastien <bzg@altern.org> writes:

> I often fiddle around #+AUTHOR, #+TITLE, and other such lines.  But
> having to re-align them so that it looks better is time-consuming.
>
> This function does it automatically:
>
> (defun bzg-org-indent-options ()
>   "Indent option lines correctly."
>   (interactive)
>   (save-excursion
>     (goto-char (point-min))
>     (let ((max-length 0))
>       (while (re-search-forward "^#\\+\\([A-Z_]+\\)" nil t)
> 	(if (> (length (match-string 1)) max-length)
> 	    (setq max-length (length (match-string 1)))))
>       (goto-char (point-min))
>       (while (re-search-forward "^#\\+\\([A-Z_]+\\):[ \t]*\\(.+\\)$" nil t)
> 	(replace-match 
> 	 (concat "#+" (match-string 1) ":"
> 		 (make-string (1+ (- max-length (length (match-string 1)))) 32)
> 		 (match-string 2)) t t)))))

Thanks, really handy. BTW did you know about align-regexp?

 ,----
 | (align-regexp (point-min) (point-max) "^#\\+[A-Z_]+:\\( +\\)" 1 5)
 `----

Dare I say will have a similar affect.

Cheers,
Phil
-- 
 Phil Jackson
 http://www.shellarchive.co.uk

Re: Easily re-indent the #+OPTIONS lines

[Adam Spiers]

On Thu, Jan 17, 2008 at 09:09:07AM +0000, Phil Jackson wrote:
> Bastien <bzg@altern.org> writes:
> > I often fiddle around #+AUTHOR, #+TITLE, and other such lines.  But
> > having to re-align them so that it looks better is time-consuming.
> 
>  ,----
>  | (align-regexp (point-min) (point-max) "^#\\+[A-Z_]+:\\( +\\)" 1 5)
>  `----

`align-regexp' comes from align.el which also provides
`align-rules-list', a customizable variable which defines how the
DWIM `align' function behaves.  Therefore it would be even nicer if
org-mode automatically ensured that `align-rules-list' contained the
right settings for attaining this!  The following works for me when
included in `align-rules-list':

 '(org-in-buffer-settings
   (regexp . "^#\\+[A-Z_]+:\\(\\s-*\\)\\S-+")
   (modes '(org-mode)))

When I select the region and do M-x align, it does the right thing.

So the code could check whether there is an entry with this title
`org-in-buffer-settings' in the list, and if not, add it - thereby
allowing personal customization to override the automatically provided
default.