From: Thierry Banel <tbanelwebmin@free.fr>
To: emacs-orgmode@gnu.org
Subject: Re: make orgtbl-ascii-plot easier to install
Date: Wed, 27 Aug 2014 23:35:05 +0200 [thread overview]
Message-ID: <53FE4F09.5080408@free.fr> (raw)
In-Reply-To: <87r402oqce.fsf@nicolasgoaziou.fr>
[-- Attachment #1: Type: text/plain, Size: 362 bytes --]
Hereafter is an enhanced version of orgtbl-ascii-plot.
Thanks, Nicolas, for your feedback. Enhancements you suggested include:
- let-binding (instead of setq)
- better support for table headers (correct parsing of 'hline)
- no dependency on cl-lib (hopefully achieving Emacs 23 support)
- use dolist (instead of mapc)
- clean up doc-strings
Have fun
Thierry
[-- Attachment #2: 0001-Add-ascii-plotting-in-tables.patch --]
[-- Type: text/x-diff, Size: 6943 bytes --]
From 002e3b5baec9ba513c70914b9bfe17966aa9ca24 Mon Sep 17 00:00:00 2001
From: Thierry Banel <tbanelwebmin@free.fr>
Date: Wed, 27 Aug 2014 23:11:11 +0200
Subject: [PATCH] Add ascii plotting in tables
* org-table.el (orgtbl-ascii-plot): top-level function.
(orgtbl-ascii-draw), (orgtbl-uc-draw-grid), (orgtbl-uc-draw-cont):
functions which go in table formulas for drawing bars.
* org.el: key binding and menu binding
Thanks to Michael Brand and Nicolas Goaziou for feedback and
enhancements.
---
lisp/org-table.el | 105 +++++++++++++++++++++++++++++++++++++++++++++++++++++-
lisp/org.el | 4 ++-
2 files changed, 107 insertions(+), 2 deletions(-)
diff --git a/lisp/org-table.el b/lisp/org-table.el
index 06a1008..88ae094 100644
--- a/lisp/org-table.el
+++ b/lisp/org-table.el
@@ -4326,7 +4326,8 @@ to execute outside of tables."
["Move Column Left" org-metaleft :active (org-at-table-p) :keys "M-<left>"]
["Move Column Right" org-metaright :active (org-at-table-p) :keys "M-<right>"]
["Delete Column" org-shiftmetaleft :active (org-at-table-p) :keys "M-S-<left>"]
- ["Insert Column" org-shiftmetaright :active (org-at-table-p) :keys "M-S-<right>"])
+ ["Insert Column" org-shiftmetaright :active (org-at-table-p) :keys "M-S-<right>"]
+ ["Ascii plot" orgtbl-ascii-plot :active (org-at-table-p) :keys "C-c p"])
("Row"
["Move Row Up" org-metaup :active (org-at-table-p) :keys "M-<up>"]
["Move Row Down" org-metadown :active (org-at-table-p) :keys "M-<down>"]
@@ -5008,6 +5009,108 @@ it here: http://gnuvola.org/software/j/aa2u/ascii-art-to-unicode.el."
(user-error "Please download ascii-art-to-unicode.el (use C-c C-l to insert the link to it)"))
(buffer-string)))
+;; Put the cursor in a column containing numerical values
+;; of an Org-Mode table,
+;; type C-c p
+;; A new column is added with a bar plot.
+;; When the table is refreshed (C-u C-c *),
+;; the plot is updated to reflect the new values.
+
+(defun orgtbl-ascii-draw (value min max &optional width characters)
+ "Draws an ascii bar in a table.
+VALUE is a the value to plot, the width of the bar to draw. A
+value equal to MIN will be displayed as empty (zero width bar).
+A value equal to MAX will draw a bar filling all the WIDTH.
+WIDTH is the expected width in characters of the column.
+CHARACTERS is a string that will compose the bar, with shades of
+grey from pure white to pure black. It defaults to a 10
+characters string of regular ascii characters."
+ (let* ((characters (or characters " .:;c!lhVHW"))
+ (width (or width 12))
+ (value (if (numberp value) value (string-to-number value)))
+ (value (* (/ (- (+ value 0.0) min) (- max min)) width)))
+ (cond
+ ((< value 0) "too small")
+ ((> value width) "too large")
+ (t
+ (let ((len (1- (length characters))))
+ (concat
+ (make-string (floor value) (elt characters len))
+ (string (elt characters
+ (floor (* (- value (floor value)) len))))))))))
+
+;;;###autoload
+(defun orgtbl-ascii-plot (&optional ask)
+ "Draws an ascii bars plot in a column.
+With cursor in a column containing numerical values, this
+function will draw a plot in a new column. ASK, if given, is a
+numeric prefix to override the default 12 characters width of the
+plot. ASK may also be the C-u prefix, which will prompt for the
+width."
+ (interactive "P")
+ (let ((col (org-table-current-column))
+ (min 1e999) ;; 1e999 will be converted to infinity
+ (max -1e999) ;; which is the desired result
+ (table (org-table-to-lisp))
+ (length
+ (cond ((consp ask)
+ (read-number "Length of column " 12))
+ ((numberp ask) ask)
+ (t 12))))
+ (dolist (x
+ (let ((t1 ;; skip table header
+ (if (eq (car table) 'hline)
+ (cdr table)
+ table)))
+ (or (cdr (memq 'hline t1)) t1)))
+ (when (consp x)
+ (setq x (nth (1- col) x))
+ (when (string-match
+ "^[-+]?\\([0-9]*[.]\\)?[0-9]*\\([eE][+-]?[0-9]+\\)?$"
+ x)
+ (setq x (string-to-number x))
+ (when (> min x) (setq min x))
+ (when (< max x) (setq max x)))))
+ (org-table-insert-column)
+ (org-table-move-column-right)
+ (org-table-store-formulas
+ (cons
+ (cons
+ (number-to-string (1+ col))
+ (format "'(%s $%s %s %s %s)"
+ "orgtbl-ascii-draw" col min max length))
+ (org-table-get-stored-formulas)))
+ (org-table-recalculate t)))
+
+;; Example of extension: unicode characters
+;; Here are two examples of different styles.
+
+;; Unicode block characters are used to give a smooth effect.
+;; See http://en.wikipedia.org/wiki/Block_Elements
+;; Use one of those drawing functions
+;; - orgtbl-ascii-draw (the default ascii)
+;; - orgtbl-uc-draw-grid (unicode with a grid effect)
+;; - orgtbl-uc-draw-cont (smooth unicode)
+
+;; This is best viewed with the "DejaVu Sans Mono" font
+;; (use M-x set-default-font).
+
+(defun orgtbl-uc-draw-grid (value min max &optional width)
+ "Draws an ascii bar in a table. It is a variant of
+orgtbl-ascii-draw with Unicode block characters, for a smooth
+display. Bars appear as grids (to the extent the font allows)."
+ ;; http://en.wikipedia.org/wiki/Block_Elements
+ ;; best viewed with the "DejaVu Sans Mono" font
+ (orgtbl-ascii-draw value min max width
+ " \u258F\u258E\u258D\u258C\u258B\u258A\u2589"))
+
+(defun orgtbl-uc-draw-cont (value min max &optional width)
+ "Draws an ascii bar in a table. It is a variant of
+orgtbl-ascii-draw with Unicode block characters, for a smooth
+display. Bars are solid (to the extent the font allows)."
+ (orgtbl-ascii-draw value min max width
+ " \u258F\u258E\u258D\u258C\u258B\u258A\u2589\u2588"))
+
(defun org-table-get-remote-range (name-or-id form)
"Get a field value or a list of values in a range from table at ID.
diff --git a/lisp/org.el b/lisp/org.el
index 9fada32..e05a416 100755
--- a/lisp/org.el
+++ b/lisp/org.el
@@ -19470,6 +19470,7 @@ boundaries."
(org-defkey org-mode-map "\C-c=" 'org-table-eval-formula)
(org-defkey org-mode-map "\C-c'" 'org-edit-special)
(org-defkey org-mode-map "\C-c`" 'org-table-edit-field)
+(org-defkey org-mode-map "\C-cp" 'orgtbl-ascii-plot)
(org-defkey org-mode-map "\C-c|" 'org-table-create-or-convert-from-region)
(org-defkey org-mode-map [(control ?#)] 'org-table-rotate-recalc-marks)
(org-defkey org-mode-map "\C-c~" 'org-table-create-with-table.el)
@@ -21142,7 +21143,8 @@ on context. See the individual commands for more information."
["Move Column Left" org-metaleft (org-at-table-p)]
["Move Column Right" org-metaright (org-at-table-p)]
["Delete Column" org-shiftmetaleft (org-at-table-p)]
- ["Insert Column" org-shiftmetaright (org-at-table-p)])
+ ["Insert Column" org-shiftmetaright (org-at-table-p)]
+ ["Ascii plot" orgtbl-ascii-plot (org-at-table-p)])
("Row"
["Move Row Up" org-metaup (org-at-table-p)]
["Move Row Down" org-metadown (org-at-table-p)]
--
1.9.1
next prev parent reply other threads:[~2014-08-27 21:35 UTC|newest]
Thread overview: 31+ messages / expand[flat|nested] mbox.gz Atom feed top
2014-07-13 16:02 make orgtbl-ascii-plot easier to install Thierry Banel
2014-07-28 14:40 ` Bastien
2014-08-10 22:22 ` Thierry Banel
2014-08-26 8:29 ` Nicolas Goaziou
2014-08-26 19:52 ` Thierry Banel
2014-08-26 20:27 ` Nicolas Goaziou
2014-08-26 21:42 ` Thierry Banel
2014-08-26 22:09 ` Nicolas Goaziou
2014-08-26 22:21 ` Thierry Banel
2014-08-27 21:35 ` Thierry Banel [this message]
2014-08-27 23:28 ` Nicolas Goaziou
2014-08-28 20:46 ` Thierry Banel
2014-08-29 9:54 ` Nicolas Goaziou
2014-08-29 17:20 ` Thierry Banel
2014-09-02 21:53 ` [PATCH] " Thierry Banel
2014-09-03 18:22 ` Nicolas Goaziou
2014-09-03 20:10 ` A key-binding for plotting Thierry Banel
2014-09-06 14:35 ` [PATCH] remap orgtbl-ascii-plot to C-c # Thierry Banel
2014-09-08 16:30 ` Nicolas Goaziou
2014-09-13 17:06 ` key-binding for all plotting styles Thierry Banel
2014-10-07 14:15 ` Nicolas Goaziou
2014-10-07 21:40 ` Thierry Banel
2014-10-11 17:46 ` [PATCH] " Thierry Banel
2014-10-12 9:28 ` Nicolas Goaziou
2014-10-12 10:00 ` Thierry Banel
2014-10-12 14:05 ` Thierry Banel
2014-10-13 16:24 ` Nicolas Goaziou
2014-10-13 21:16 ` Thierry Banel
2014-10-14 20:48 ` Thierry Banel
2014-10-14 21:08 ` Nicolas Goaziou
2014-10-14 21:26 ` Thierry Banel
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
List information: https://www.orgmode.org/
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=53FE4F09.5080408@free.fr \
--to=tbanelwebmin@free.fr \
--cc=emacs-orgmode@gnu.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.savannah.gnu.org/cgit/emacs/org-mode.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).