emacs-orgmode@gnu.org archives
 help / color / mirror / code / Atom feed
blob 53669896ee31e91024ee61b885e249831598a86b 5655 bytes (raw)
name: lisp/ob-lob.el 	 # note: path name is non-authoritative(*)

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
 
;;; ob-lob.el --- functions supporting the Library of Babel

;; Copyright (C) 2009-2013 Free Software Foundation, Inc.

;; Authors: Eric Schulte
;;	 Dan Davison
;; Keywords: literate programming, reproducible research
;; Homepage: http://orgmode.org

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Code:
(eval-when-compile
  (require 'cl))
(require 'ob-core)
(require 'ob-table)

(declare-function org-babel-in-example-or-verbatim "ob-exp" nil)

(defvar org-babel-library-of-babel nil
  "Library of source-code blocks.
This is an association list.  Populate the library by adding
files to `org-babel-lob-files'.")

(defcustom org-babel-lob-files '()
  "Files used to populate the `org-babel-library-of-babel'.
To add files to this list use the `org-babel-lob-ingest' command."
  :group 'org-babel
  :version "24.1"
  :type 'list)

(defvar org-babel-default-lob-header-args '((:exports . "results"))
  "Default header arguments to use when exporting #+lob/call lines.")

(defun org-babel-lob-ingest (&optional file)
  "Add all named source-blocks defined in FILE to
`org-babel-library-of-babel'."
  (interactive "fFile: ")
  (let ((lob-ingest-count 0))
    (org-babel-map-src-blocks file
      (let* ((info (org-babel-get-src-block-info 'light))
	     (source-name (nth 4 info)))
	(when source-name
	  (setq source-name (intern source-name)
		org-babel-library-of-babel
		(cons (cons source-name info)
		      (assq-delete-all source-name org-babel-library-of-babel))
		lob-ingest-count (1+ lob-ingest-count)))))
    (message "%d src block%s added to Library of Babel"
	     lob-ingest-count (if (> lob-ingest-count 1) "s" ""))
    lob-ingest-count))

(defconst org-babel-block-lob-one-liner-regexp
  (concat
   "^\\([ \t]*?\\)#\\+call:[ \t]+\\([^\(\)\n]+?\\)\\(\\[\\(.*\\)\\]\\|\\(\\)\\)"
   "\(\\([^\n]*?\\)\)\\(\\[.+\\]\\|\\)[ \t]*\\(\\([^\n]*\\)\\)?")
  "Regexp to match non-inline calls to predefined source block functions.")

(defconst org-babel-inline-lob-one-liner-regexp
  (concat
   "\\([^\n]*?\\)call_\\([^\(\)\n]+?\\)\\(\\[\\(.*?\\)\\]\\|\\(\\)\\)"
   "\(\\([^\n]*?\\)\)\\(\\[\\(.*?\\)\\]\\)?")
  "Regexp to match inline calls to predefined source block functions.")

(defconst org-babel-lob-one-liner-regexp
  (concat "\\(" org-babel-block-lob-one-liner-regexp
	  "\\|" org-babel-inline-lob-one-liner-regexp "\\)")
  "Regexp to match calls to predefined source block functions.")

;; functions for executing lob one-liners

;;;###autoload
(defun org-babel-lob-execute-maybe ()
  "Execute a Library of Babel source block, if appropriate.
Detect if this is context for a Library Of Babel source block and
if so then run the appropriate source block from the Library."
  (interactive)
  (let ((info (org-babel-lob-get-info)))
    (if (and (nth 0 info) (not (org-babel-in-example-or-verbatim)))
	(progn (org-babel-lob-execute info) t)
      nil)))

;;;###autoload
(defun org-babel-lob-get-info ()
  "Return a Library of Babel function call as a string."
  (let ((case-fold-search t)
	(nonempty (lambda (a b)
		    (let ((it (match-string a)))
		      (if (= (length it) 0) (match-string b) it)))))
    (save-excursion
      (beginning-of-line 1)
      (when (looking-at org-babel-lob-one-liner-regexp)
	(append
	 (mapcar #'org-no-properties
		 (list
		  (format "%s%s(%s)%s"
			  (funcall nonempty 3 12)
			  (if (not (= 0 (length (funcall nonempty 5 14))))
			      (concat "[" (funcall nonempty 5 14) "]") "")
			  (or (funcall nonempty 7 16) "")
			  (or (funcall nonempty 8 19) ""))
		  (funcall nonempty 9 18)))
	 (list (length (if (= (length (match-string 12)) 0)
			   (match-string 2) (match-string 11)))))))))

(defvar org-babel-default-header-args:emacs-lisp) ; dynamic binding from ob-emacs-lisp
(defun org-babel-lob-execute (info)
  "Execute the lob call specified by INFO."
  (let* ((mkinfo (lambda (p) (list "emacs-lisp" "results" p nil nil (nth 2 info))))
	 (pre-params (org-babel-merge-params
		      org-babel-default-header-args
		      org-babel-default-header-args:emacs-lisp
		      (org-babel-params-from-properties)
		      (org-babel-parse-header-arguments
		       (org-no-properties
			(concat ":var results="
				(mapconcat #'identity (butlast info) " "))))))
	 (pre-info (funcall mkinfo pre-params))
	 (cache-p (and (cdr (assoc :cache pre-params))
		       (string= "yes" (cdr (assoc :cache pre-params)))))
	 (new-hash (when cache-p (org-babel-sha1-hash pre-info)))
	 (old-hash (when cache-p (org-babel-current-result-hash))))
    (if (and cache-p (equal new-hash old-hash))
	(save-excursion (goto-char (org-babel-where-is-src-block-result))
			(forward-line 1)
			(message "%S" (org-babel-read-result)))
      (prog1 (let* ((proc-params (org-babel-process-params pre-params))
		     org-confirm-babel-evaluate)
	       (org-babel-execute-src-block
		nil (funcall mkinfo proc-params)))
	;; update the hash
	(when new-hash (org-babel-set-current-result-hash new-hash))))))

(provide 'ob-lob)

;; Local variables:
;; generated-autoload-file: "org-loaddefs.el"
;; End:

;;; ob-lob.el ends here

debug log:

solving 5366989 ...
found 5366989 in https://list.orgmode.org/orgmode/87k3oaw7jz.fsf@Rainer.invalid/
found 4c89485 in https://git.savannah.gnu.org/cgit/emacs/org-mode.git
preparing index
index prepared:
100644 4c894852a8de846e0979b708682ba9c5b8e8b605	lisp/ob-lob.el

applying [1/1] https://list.orgmode.org/orgmode/87k3oaw7jz.fsf@Rainer.invalid/
diff --git a/lisp/ob-lob.el b/lisp/ob-lob.el
index 4c89485..5366989 100644

Checking patch lisp/ob-lob.el...
Applied patch lisp/ob-lob.el cleanly.

index at:
100644 53669896ee31e91024ee61b885e249831598a86b	lisp/ob-lob.el

(*) Git path names are given by the tree(s) the blob belongs to.
    Blobs themselves have no identifier aside from the hash of its contents.^

Code repositories for project(s) associated with this public inbox

	https://git.savannah.gnu.org/cgit/emacs/org-mode.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).