Breadcrumbs?

Breadcrumbs?

[Ken Williams]

[-- Attachment #1: Type: text/plain, Size: 946 bytes --]

Has anyone ever tried implementing a "breadcrumbs"-type feature in org-mode?  By that I mean something that would quickly tell you the headings up the whole path to the root, to quickly orient yourself when you're deep within a document.  I was originally thinking of something always-present shown at the top of the frame, but maybe it would be better as something shown on demand in the minibuffer, possibly making it taller while shown.

--
Ken Williams, Senior Research Scientist
WindLogics
http://windlogics.com


________________________________
CONFIDENTIALITY NOTICE: This e-mail message is for the sole use of the intended recipient(s) and may contain confidential and privileged information. Any unauthorized review, use, disclosure or distribution of any kind is strictly prohibited. If you are not the intended recipient, please contact the sender via reply e-mail and destroy all copies of the original message. Thank you.

[-- Attachment #2: Type: text/html, Size: 2998 bytes --]

Re: Breadcrumbs?

[Anthony Lander]

[-- Attachment #1: Type: text/plain, Size: 1581 bytes --]

Hi Ken,

On 12-Sep-24, at 5:36 PM, Ken Williams wrote:

> Has anyone ever tried implementing a “breadcrumbs”-type feature in org-mode?  By that I mean something that would quickly tell you the headings up the whole path to the root, to quickly orient yourself when you’re deep within a document.  I was originally thinking of something always-present shown at the top of the frame, but maybe it would be better as something shown on demand in the minibuffer, possibly making it taller while shown.

You can bind this to a speed command. It will show you the path to the current headline (less the first heading) in the echo area, and will also copy it to the kill ring. This is the functionality I need, but it would be easy to modify to do what you want.

(defun org-copy-outline-path-less-root-to-kill-ring (&optional a b)
  "Copy the current outline path, less the first node, to the
kill ring, and echo to the echo area."
  (interactive "P")
  (let* ((bfn (buffer-file-name (buffer-base-buffer)))
     (case-fold-search nil)
         (path (rest (org-get-outline-path))))
    (setq path (append path
                       (save-excursion
                         (org-back-to-heading t)
                         (if (looking-at org-complex-heading-regexp)
                             (list (match-string 4))))))
    (let ((formatted-path (org-format-outline-path
                           path
                           (1- (frame-width)))))
      (kill-new formatted-path)
      (message "%s" formatted-path))))

Hope this helps,

 -Anthony


[-- Attachment #2: Type: text/html, Size: 3400 bytes --]

Re: Breadcrumbs?

[Sebastien Vauban]

Hi,

Anthony Lander wrote:
> On 12-Sep-24, at 5:36 PM, Ken Williams wrote:
>
>> Has anyone ever tried implementing a “breadcrumbs”-type feature in org-mode?
>> By that I mean something that would quickly tell you the headings up the
>> whole path to the root, to quickly orient yourself when you’re deep within a
>> document. I was originally thinking of something always-present shown at the
>> top of the frame, but maybe it would be better as something shown on demand
>> in the minibuffer, possibly making it taller while shown.
>
> You can bind this to a speed command.

SPC in column 0 does already do that, doesn't it?

Best regards,
  Seb

-- 
Sebastien Vauban

Re: Breadcrumbs?

[Bastien]

"Sebastien Vauban"
<wxhgmqzgwmuf-geNee64TY+gS+FvcfC7Uqw@public.gmane.org> writes:

>> You can bind this to a speed command.
>
> SPC in column 0 does already do that, doesn't it?

Yes.

-- 
 Bastien

Re: Breadcrumbs?

[Sebastien Vauban]

Bastien,

Bastien wrote:
> "Sebastien Vauban" writes:
>>> You can bind this to a speed command.
>>
>> SPC in column 0 does already do that, doesn't it?
>
> Yes.

And here a small extension to your function, in order to add a more visible
color to the displayed path:

#+begin_src emacs-lisp
(add-hook 'org-mode-hook
          (lambda() (add-to-list 'mode-line-format
                                 '(:eval (org-propertize
                                          (org-display-outline-path nil t t)
                                         'face 'mode-line-emphasis
                                         'help-echo "Outline path")) t)))
#+end_src

Could we imagine the displayed outline path to be separated by " / " instead
of by "/", that is:

    "Tasks / Add color to modeline / Check function org-propertize"

instead of:

    "Tasks/Add color to modeline/Check function org-propertize"?

That way, it would as well be equivalent to what's displayed by helm-imenu.

Best regards,
  Seb

-- 
Sebastien Vauban

Re: Breadcrumbs?

[Bastien]

"Sebastien Vauban"
<wxhgmqzgwmuf-geNee64TY+gS+FvcfC7Uqw@public.gmane.org> writes:

> Could we imagine the displayed outline path to be separated by " / " instead
> of by "/", that is:

From current master, try this out:

(org-display-outline-path nil t " - ")

HTH,

-- 
 Bastien

Re: Breadcrumbs?

[Carsten Dominik]

On 25.9.2012, at 14:48, Bastien wrote:

> 
> 
> "Sebastien Vauban"
> <wxhgmqzgwmuf-geNee64TY+gS+FvcfC7Uqw@public.gmane.org> writes:
> 
>> Could we imagine the displayed outline path to be separated by " / " instead
>> of by "/", that is:
> 
> From current master, try this out:
> 
> (org-display-outline-path nil t " - ")

Hi everyone,

I just changed the definitions of org-display-outline-path
and org-format-outline-path, so the call above would have to
be modified to

         (org-display-outline-path nil t " / " t)

Cheers

- Carsten

> 
> HTH,
> 
> -- 
> Bastien
> 
> 

Re: Breadcrumbs?

[Bastien]

Carsten Dominik <carsten.dominik@gmail.com> writes:

> I just changed the definitions of org-display-outline-path
> and org-format-outline-path, so the call above would have to
> be modified to
>
>          (org-display-outline-path nil t " / " t)

Great, thanks!

-- 
 Bastien

Re: **: Re: Breadcrumbs?

[Bastien]

Hi Sébastien,

"Sebastien Vauban" <wxhgmqzgwmuf@spammotel.com> writes:

> Now, it does not work anymore as it did. I now have things such as:
>
>  "/ Headline 1/Longer headline 2/Very long headline 3"
>
> in my mode line, instead of:
>
>  "Headline 1 / Longer headline 2 / Very long headline 3"

Fixed, thanks.

-- 
 Bastien

Re: Breadcrumbs?

[Bastien]

Hi Nick,

Nick Dokos <nicholas.dokos@hp.com> writes:

> I must have missed some context: where does SPC in column 0 run
> org-display-outline-path?

If you have (setq org-use-speed-commands t)

HTH,

-- 
 Bastien

Re: Breadcrumbs?

[Nick Dokos]

Sebastien Vauban <wxhgmqzgwmuf@spammotel.com> wrote:

> Hi,
> 
> Anthony Lander wrote:
> > On 12-Sep-24, at 5:36 PM, Ken Williams wrote:
> >
> >> Has anyone ever tried implementing a “breadcrumbs”-type feature in org-mode?
> >> By that I mean something that would quickly tell you the headings up the
> >> whole path to the root, to quickly orient yourself when you’re deep within a
> >> document. I was originally thinking of something always-present shown at the
> >> top of the frame, but maybe it would be better as something shown on demand
> >> in the minibuffer, possibly making it taller while shown.
> >
> > You can bind this to a speed command.
> 
> SPC in column 0 does already do that, doesn't it?
> 

Not here, I'm afraid: SPC in column 0 (both on headlines and not on headlines)
is bound to org-self-insert-command and just inserts a space.

Nick

Re: Breadcrumbs?

[François Pinard]

"Sebastien Vauban"
<wxhgmqzgwmuf-geNee64TY+gS+FvcfC7Uqw@public.gmane.org> writes:

> SPC in column 0 does already do that, doesn't it?

Wow!  I did not know that!  Thanks! :-)

François

Re: Breadcrumbs?

[Ken Williams]

[-- Attachment #1: Type: text/plain, Size: 1810 bytes --]

Very nice, thanks.  I like to see the top-level heading too, so I removed the (rest ...) call near the beginning.

  -Ken

From: Anthony Lander [mailto:anthony@landerfamily.ca]
Sent: Monday, September 24, 2012 7:45 PM
To: Ken Williams
Cc: emacs-orgmode@gnu.org
Subject: Re: [O] Breadcrumbs?

Hi Ken,

You can bind this to a speed command. It will show you the path to the current headline (less the first heading) in the echo area, and will also copy it to the kill ring. This is the functionality I need, but it would be easy to modify to do what you want.

(defun org-copy-outline-path-less-root-to-kill-ring (&optional a b)
  "Copy the current outline path, less the first node, to the
kill ring, and echo to the echo area."
  (interactive "P")
  (let* ((bfn (buffer-file-name (buffer-base-buffer)))
     (case-fold-search nil)
         (path (rest (org-get-outline-path))))
    (setq path (append path
                       (save-excursion
                         (org-back-to-heading t)
                         (if (looking-at org-complex-heading-regexp)
                             (list (match-string 4))))))
    (let ((formatted-path (org-format-outline-path
                           path
                           (1- (frame-width)))))
      (kill-new formatted-path)
      (message "%s" formatted-path))))

Hope this helps,

 -Anthony


________________________________
CONFIDENTIALITY NOTICE: This e-mail message is for the sole use of the intended recipient(s) and may contain confidential and privileged information. Any unauthorized review, use, disclosure or distribution of any kind is strictly prohibited. If you are not the intended recipient, please contact the sender via reply e-mail and destroy all copies of the original message. Thank you.

[-- Attachment #2: Type: text/html, Size: 6593 bytes --]

Re: Breadcrumbs?

[Bastien]

Hi Ken,

Ken Williams <Ken.Williams@windlogics.com> writes:

> Has anyone ever tried implementing a “breadcrumbs”-type feature in
> org-mode?  

What about this?

(defun org-show-olpath ()
  "Show the outline path."
  (interactive)
  (let (p h)
    (save-excursion
      (while (and (setq h (ignore-errors (org-get-heading t t)))
		  (org-up-heading-safe))
	(setq p (concat h "/" p)))
      (setq p (concat (org-get-heading t t) "/" p)))
    p))

(add-hook 'org-mode-hook
          (lambda() (add-to-list 'mode-line-format
                                 '(:eval (org-show-olpath)) t)))

-- 
 Bastien

Re: Breadcrumbs?

[Bastien]

Bastien <bzg@altern.org> writes:

> What about this?

Or, inspired by Anthony's use of `org-get-outline-path':

(defun org-show-olpath ()
  "Show the outline path."
  (org-no-properties
   (mapconcat 'identity
	      (append (ignore-errors (org-get-outline-path))
		      (ignore-errors (list (org-get-heading t t))))
	      "/")))

(add-hook 'org-mode-hook
          (lambda() (add-to-list 'mode-line-format
                                 '(:eval (org-show-olpath)) t)))

-- 
 Bastien

Re: Breadcrumbs?

[Eric Abrahamsen]

On Tue, Sep 25 2012, Ken Williams wrote:

> Has anyone ever tried implementing a “breadcrumbs”-type feature in
> org-mode?  By that I mean something that would quickly tell you the
> headings up the whole path to the root, to quickly orient yourself
> when you’re deep within a document.  I was originally thinking of
> something always-present shown at the top of the frame, but maybe it
> would be better as something shown on demand in the minibuffer,
> possibly making it taller while shown.

The command `org-display-outline-path' will do this -- you could just
bind it to a key in org-mode-map.

Yours,
Eric

-- 
GNU Emacs 24.2.50.1 (i686-pc-linux-gnu, GTK+ Version 3.4.4)
 of 2012-09-16 on pellet
7.9.1

Re: Breadcrumbs?

[Bastien]

Eric Abrahamsen <eric@ericabrahamsen.net> writes:

> The command `org-display-outline-path' will do this -- you could just
> bind it to a key in org-mode-map.

Indeed!  I've updated `org-display-outline-path' so that it can return a
string:

  (org-display-outline-path nil t t)

So you can now hook it like this:

(add-hook 'org-mode-hook
          (lambda() (add-to-list 'mode-line-format
                                 '(:eval (org-display-outline-path nil t t)) t)))

-- 
 Bastien

Re: Breadcrumbs?

[Memnon Anon]

Bastien <bzg@altern.org> writes:

> Indeed!  I've updated `org-display-outline-path' so that it can return a
> string:
>
>   (org-display-outline-path nil t t)
>
> So you can now hook it like this:
>
> (add-hook 'org-mode-hook
>           (lambda() (add-to-list 'mode-line-format
>                                  '(:eval (org-display-outline-path nil t t)) t)))

Interesting.

But my modeline is already fairly crowded and headlines can be rather long.

I am currently trying this:

--8<---------------cut here---------------start------------->8---

(add-hook 'org-mode-hook
          (lambda() (setq header-line-format
                                 '(:eval (org-display-outline-path nil t t)))))

--8<---------------cut here---------------end--------------->8---

Memnon