;;; org-plot.el --- Support for Plotting from Org -*- lexical-binding: t; -*-

;; Copyright (C) 2008-2020 Free Software Foundation, Inc.
;;
;; Author: Eric Schulte <schulte dot eric at gmail dot com>
;; Keywords: tables, plotting
;; Homepage: https://orgmode.org
;;
;; This file is part of GNU Emacs.
;;
;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:

;; Borrows ideas and a couple of lines of code from org-exp.el.

;; Thanks to the Org mailing list for testing and implementation and
;; feature suggestions

;;; Code:

(require 'cl-lib)
(require 'org)
(require 'org-table)

(declare-function gnuplot-delchar-or-maybe-eof "ext:gnuplot" (arg))
(declare-function gnuplot-mode "ext:gnuplot" ())
(declare-function gnuplot-send-buffer-to-gnuplot "ext:gnuplot" ())

(defvar org-plot/gnuplot-default-options
  '((:plot-type . 2d)
    (:with . lines)
    (:ind . 0))
  "Default options to gnuplot used by `org-plot/gnuplot'.")

(defvar org-plot-timestamp-fmt nil)

(defun org-plot/add-options-to-plist (p options)
  "Parse an OPTIONS line and set values in the property list P.
Returns the resulting property list."
  (when options
    (let ((op '(("type"      . :plot-type)
		("script"    . :script)
		("line"      . :line)
		("set"       . :set)
		("title"     . :title)
		("ind"       . :ind)
		("deps"      . :deps)
		("with"      . :with)
		("file"      . :file)
		("labels"    . :labels)
		("map"       . :map)
		("timeind"   . :timeind)
		("timefmt"   . :timefmt)
		("min"       . :ymin)
		("max"       . :ymax)
		("ymin"      . :ymin)
		("xmax"      . :xmax)
		("ticks"     . :ticks)
		("trans"     . :transpose)
		("transpose" . :transpose)))
	  (multiples '("set" "line"))
	  (regexp ":\\([\"][^\"]+?[\"]\\|[(][^)]+?[)]\\|[^ \t\n\r;,.]*\\)")
	  (start 0))
      (dolist (o op)
	(if (member (car o) multiples) ;; keys with multiple values
	    (while (string-match
		    (concat (regexp-quote (car o)) regexp)
		    options start)
	      (setq start (match-end 0))
	      (setq p (plist-put p (cdr o)
				 (cons (car (read-from-string
					     (match-string 1 options)))
				       (plist-get p (cdr o)))))
	      p)
	  (if (string-match (concat (regexp-quote (car o)) regexp)
			    options)
	      (setq p (plist-put p (cdr o)
				 (car (read-from-string
				       (match-string 1 options))))))))))
  p)

(defun org-plot/goto-nearest-table ()
  "Move the point forward to the beginning of nearest table.
Return value is the point at the beginning of the table."
  (interactive) (move-beginning-of-line 1)
  (while (not (or (org-at-table-p) (< 0 (forward-line 1)))))
  (goto-char (org-table-begin)))

(defun org-plot/collect-options (&optional params)
  "Collect options from an org-plot `#+Plot:' line.
Accepts an optional property list PARAMS, to which the options
will be added.  Returns the resulting property list."
  (interactive)
  (let ((line (thing-at-point 'line)))
    (if (string-match "#\\+PLOT: +\\(.*\\)$" line)
	(org-plot/add-options-to-plist params (match-string 1 line))
      params)))

(defun org-plot-quote-timestamp-field (s)
  "Convert field S from timestamp to Unix time and export to gnuplot."
  (format-time-string org-plot-timestamp-fmt (org-time-string-to-time s)))

(defun org-plot-quote-tsv-field (s)
  "Quote field S for export to gnuplot."
  (if (string-match org-table-number-regexp s) s
    (if (string-match org-ts-regexp3 s)
	(org-plot-quote-timestamp-field s)
      (concat "\"" (mapconcat 'identity (split-string s "\"") "\"\"") "\""))))

(defun org-plot/gnuplot-to-data (table data-file params)
  "Export TABLE to DATA-FILE in a format readable by gnuplot.
Pass PARAMS through to `orgtbl-to-generic' when exporting TABLE."
  (with-temp-file
      data-file
    (setq-local org-plot-timestamp-fmt (or
					(plist-get params :timefmt)
					"%Y-%m-%d-%H:%M:%S"))
    (insert (orgtbl-to-generic
	     table
	     (org-combine-plists
	      '(:sep "\t" :fmt org-plot-quote-tsv-field)
	      params))))
  nil)

(defun org-plot/gnuplot-to-grid-data (table data-file params)
  "Export the data in TABLE to DATA-FILE for gnuplot.
This means in a format appropriate for grid plotting by gnuplot.
PARAMS specifies which columns of TABLE should be plotted as independent
and dependent variables."
  (interactive)
  (let* ((ind (- (plist-get params :ind) 1))
	 (deps (if (plist-member params :deps)
		   (mapcar (lambda (val) (- val 1)) (plist-get params :deps))
		 (let (collector)
		   (dotimes (col (length (nth 0 table)))
		     (setf collector (cons col collector)))
		   collector)))
	 (counter 0)
	 row-vals)
    (when (>= ind 0) ;; collect values of ind col
      (setf row-vals (mapcar (lambda (row) (setf counter (+ 1 counter))
			       (cons counter (nth ind row)))
			     table)))
    (when (or deps (>= ind 0)) ;; remove non-plotting columns
      (setf deps (delq ind deps))
      (setf table (mapcar (lambda (row)
			    (dotimes (col (length row))
			      (unless (memq col deps)
				(setf (nth col row) nil)))
			    (delq nil row))
			  table)))
    ;; write table to gnuplot grid datafile format
    (with-temp-file data-file
      (let ((num-rows (length table)) (num-cols (length (nth 0 table)))
	    (gnuplot-row (lambda (col row value)
			   (setf col (+ 1 col)) (setf row (+ 1 row))
			   (format "%f  %f  %f\n%f  %f  %f\n"
				   col (- row 0.5) value ;; lower edge
				   col (+ row 0.5) value))) ;; upper edge
	    front-edge back-edge)
	(dotimes (col num-cols)
	  (dotimes (row num-rows)
	    (setf back-edge
		  (concat back-edge
			  (funcall gnuplot-row (- col 1) row
				   (string-to-number (nth col (nth row table))))))
	    (setf front-edge
		  (concat front-edge
			  (funcall gnuplot-row col row
				   (string-to-number (nth col (nth row table)))))))
	  ;; only insert once per row
	  (insert back-edge) (insert "\n") ;; back edge
	  (insert front-edge) (insert "\n") ;; front edge
	  (setf back-edge "") (setf front-edge ""))))
    row-vals))

(defun org--plot/values-stats (nums &optional hard-min hard-max)
  "From a list of NUMS return a plist containing some rudamentry statistics on the
values, namely regarding the range."
  (let* ((minimum (or hard-min (apply #'min nums)))
	 (maximum (or hard-max (apply #'max nums)))
	 (range (- maximum minimum))
	 (rangeOrder (ceiling (- 1 (log10 range))))
	 (range-factor (expt 10 rangeOrder))
	 (nice-min (/ (float (floor (* minimum range-factor))) range-factor))
	 (nice-max (/ (float (ceiling (* maximum range-factor))) range-factor)))
    `(:min ,minimum :max ,maximum :range ,range
      :range-factor ,range-factor
      :nice-min ,nice-min :nice-max ,nice-max :nice-range ,(- nice-max nice-min))))

(defun org--plot/sensible-tick-num (table &optional hard-min hard-max)
  "From a the values in a TABLE of data, attempt to guess an appropriate number of ticks."
  (let* ((row-data
	  (mapcar (lambda (row) (org--plot/values-stats
			    (mapcar #'string-to-number (cdr row))
			    hard-min
			    hard-max)) table))
	 (row-normalised-ranges (mapcar (lambda (r-data)
					  (let ((val (round (*
							     (plist-get r-data :range-factor)
							     (plist-get r-data :nice-range)))))
					    (if (= (% val 10) 0) (/ val 10) val)))
					row-data))
	 (range-prime-decomposition (mapcar #'org--plot/prime-factors row-normalised-ranges))
	 (weighted-factors (sort (apply #'org--plot/merge-alists #'+ 0
					(mapcar (lambda (factors) (org--plot/item-frequencies factors t))
						range-prime-decomposition))
				 (lambda (a b) (> (cdr a) (cdr b))))))
    (apply #'* (org--plot/nice-frequency-pick weighted-factors))))

(defun org--plot/nice-frequency-pick (frequencies)
  "From a list of frequences, try to sensibly pick a sample of the most frequent."
  ;; TODO this mosly works decently, but counld do with some tweaking to work more consistently.
  (case (length frequencies)
    (1 (list (car (nth 0 frequencies))))
    (2 (if (<= 3 (/ (cdr (nth 0 frequencies))
		    (cdr (nth 1 frequencies))))
	   (make-list 2
		      (car (nth 0 frequencies)))
	 (list (car (nth 0 frequencies))
	       (car (nth 1 frequencies)))))
    (t
     (let* ((total-count (apply #'+ (mapcar #'cdr frequencies)))
	    (n-freq (mapcar (lambda (freq) `(,(car freq) . ,(/ (float (cdr freq)) total-count))) frequencies))
	    (f-pick (list (car (car n-freq))))
	    (1-2-ratio (/ (cdr (nth 0 n-freq))
			  (cdr (nth 1 n-freq))))
	    (2-3-ratio (/ (cdr (nth 1 n-freq))
			  (cdr (nth 2 n-freq))))
	    (1-3-ratio (* 1-2-ratio 2-3-ratio))
	    (1-val (car (nth 0 n-freq)))
	    (2-val (car (nth 1 n-freq)))
	    (3-val (car (nth 2 n-freq))))
       (when (> 1-2-ratio 4) (push 1-val f-pick))
       (when (and (< 1-2-ratio 2-val)
		  (< (* (apply #'* f-pick) 2-val) 30))
	 (push 2-val f-pick))
       (when (and (< 1-3-ratio 3-val)
		  (< (* (apply #'* f-pick) 3-val) 30))
	 (push 3-val f-pick))
       f-pick))))

(defun org--plot/merge-alists (function default alist1 alist2 &rest alists)
  "Using FUNCTION, combine the elements of all given ALISTS. When an element is
only present in one alist, DEFAULT is used as the second argument for the FUNCTION."
  (when (> (length alists) 0)
    (setq alist2 (apply #'org--plot/merge-alists function default alist2 alists)))
  (flet ((keys (alist) (mapcar #'car alist))
	 (lookup (key alist) (or (cdr (assoc key alist)) default)))
    (loop with keys = (union (keys alist1) (keys alist2) :test 'equal)
	  for k in keys collect
	  (cons k (funcall function (lookup k alist1) (lookup k alist2))))))

(defun org--plot/item-frequencies (values &optional normalise)
  "Return an alist indicating the frequency of values in VALUES list."
  (let ((normaliser (if normalise (float (length values)) 1)))
    (cl-loop for (n . m) in (seq-group-by #'identity values)
	     collect (cons n (/ (length m) normaliser)))))

(defun org--plot/prime-factors (value)
  "Return the prime decomposition of VALUE, e.g. for 12, '(3 2 2)"
  (let ((factors '(1)) (i 1))
    (while (/= 1 value)
      (setq i (1+ i))
      (when (eq 0 (% value i))
	(push i factors)
	(setq value (/ value i))
	(setq i (1- i))
	))
    (subseq factors 0 -1)))

(defcustom org-plot/gnuplot-script-preamble ""
  "String or function which provides content to be inserted into the GNUPlot
script before the plot command. Not that this is in addition to, not instead of
other content generated in `org-plot/gnuplot-script'."
  :group 'org-plot
  :type '(choice string function))

(defcustom org-plot/preset-plot-types
  '((2d (lambda (data-file num-cols params plot-str)
	  (let* ((type (plist-get params :plot-type))
		 (with (if (eq type 'grid) 'pm3d (plist-get params :with)))
		 (ind (plist-get params :ind))
		 (deps (if (plist-member params :deps) (plist-get params :deps)))
		 (text-ind (plist-get params :textind))
		 (col-labels (plist-get params :labels))
		 res)
	    (dotimes (col num-cols res)
	      (unless (and (eq type '2d)
			   (or (and ind (equal (1+ col) ind))
			       (and deps (not (member (1+ col) deps)))))
		(setf res
		      (cons
		       (format plot-str data-file
			       (or (and ind (> ind 0)
					(not text-ind)
					(format "%d:" ind)) "")
			       (1+ col)
			       (if text-ind (format ":xticlabel(%d)" ind) "")
			       with
			       (or (nth col col-labels)
				   (format "%d" (1+ col))))
		       res)))))))
    (3d (lambda (data-file num-cols params plot-str)
	  (let* ((type (plist-get params :plot-type))
		 (with (if (eq type 'grid) 'pm3d (plist-get params :with))))
	    (list (format "'%s' matrix with %s title ''"
			  data-file with)))))
    (grid (lambda (data-file num-cols params plot-str)
	    (let* ((type (plist-get params :plot-type))
		   (with (if (eq type 'grid) 'pm3d (plist-get params :with))))
	    (list (format "'%s' with %s title ''"
			  data-file with))))))
  "List of plot presets with the type name as the car, and a function
which yeilds plot-lines (a list of strings) as the cdr.
The parameters of `org-plot/gnuplot-script' and PLOT-STR are passed to
that function. i.e. it is called with the following arguments:
  DATA-FILE NUM-COLS PARAMS PLOT-STR"
  :group 'org-plot
  :type '(alist :value-type (symbol group)))

(defun org-plot/gnuplot-script (data-file num-cols params &optional preface)
  "Write a gnuplot script to DATA-FILE respecting the options set in PARAMS.
NUM-COLS controls the number of columns plotted in a 2-d plot.
Optional argument PREFACE returns only option parameters in a
manner suitable for prepending to a user-specified script."
  (let* ((type (plist-get params :plot-type))
	 (with (if (eq type 'grid) 'pm3d (plist-get params :with)))
	 (sets (plist-get params :set))
	 (lines (plist-get params :line))
	 (map (plist-get params :map))
	 (title (plist-get params :title))
	 (file (plist-get params :file))
	 (ind (plist-get params :ind))
	 (time-ind (plist-get params :timeind))
	 (timefmt (plist-get params :timefmt))
	 (text-ind (plist-get params :textind))
	 (deps (if (plist-member params :deps) (plist-get params :deps)))
	 (col-labels (plist-get params :labels))
	 (x-labels (plist-get params :xlabels))
	 (y-labels (plist-get params :ylabels))
	 (plot-str "'%s' using %s%d%s with %s title '%s'")
	 (plot-cmd (pcase type
		     (`2d "plot")
		     (`3d "splot")
		     (`grid "splot")))
	 (script "reset")
	 ;; ats = add-to-script
	 (ats (lambda (line) (setf script (concat script "\n" line))))
	 plot-lines)
    (when file				; output file
      (funcall ats (format "set term %s" (file-name-extension file)))
      (funcall ats (format "set output '%s'" file)))

    (funcall ats
	     (if (stringp org-plot/gnuplot-script-preamble)
		 org-plot/gnuplot-script-preamble
	       (org-plot/gnuplot-script-preamble)))

    (pcase type				; type
      (`2d ())
      (`3d (when map (funcall ats "set map")))
      (`grid (funcall ats (if map "set pm3d map" "set pm3d"))))
    (when title (funcall ats (format "set title '%s'" title))) ; title
    (mapc ats lines)					       ; line
    (dolist (el sets) (funcall ats (format "set %s" el)))      ; set
    ;; Unless specified otherwise, values are TAB separated.
    (unless (string-match-p "^set datafile separator" script)
      (funcall ats "set datafile separator \"\\t\""))
    (when x-labels			; x labels (xtics)
      (funcall ats
	       (format "set xtics (%s)"
		       (mapconcat (lambda (pair)
				    (format "\"%s\" %d" (cdr pair) (car pair)))
				  x-labels ", "))))
    (when y-labels			; y labels (ytics)
      (funcall ats
	       (format "set ytics (%s)"
		       (mapconcat (lambda (pair)
				    (format "\"%s\" %d" (cdr pair) (car pair)))
				  y-labels ", "))))
    (when time-ind			; timestamp index
      (funcall ats "set xdata time")
      (funcall ats (concat "set timefmt \""
			   (or timefmt	; timefmt passed to gnuplot
			       "%Y-%m-%d-%H:%M:%S") "\"")))
    (unless preface
      (let ((type-func (cadr (assoc type org-plot/preset-plot-types))))
	(when type-func
	  (setq plot-lines
		(funcall type-func data-file num-cols params plot-str))))

      (funcall ats
	       (concat plot-cmd " " (mapconcat #'identity
					       (reverse plot-lines)
					       ",\\\n    "))))
    script))

;;-----------------------------------------------------------------------------
;; facade functions
;;;###autoload
(defun org-plot/gnuplot (&optional params)
  "Plot table using gnuplot.  Gnuplot options can be specified with PARAMS.
If not given options will be taken from the +PLOT
line directly before or after the table."
  (interactive)
  (require 'gnuplot)
  (save-window-excursion
    (delete-other-windows)
    (when (get-buffer "*gnuplot*") ; reset *gnuplot* if it already running
      (with-current-buffer "*gnuplot*"
	(goto-char (point-max))))
    (org-plot/goto-nearest-table)
    ;; Set default options.
    (dolist (pair org-plot/gnuplot-default-options)
      (unless (plist-member params (car pair))
	(setf params (plist-put params (car pair) (cdr pair)))))
    ;; collect table and table information
    (let* ((data-file (make-temp-file "org-plot"))
	   (table (let ((tbl (org-table-to-lisp)))
		    (when (pcase (plist-get params :transpose)
			    ('y   t)
			    ('yes t)
			    ('t   t))
		      (if (memq 'hline tbl)
			  (setq tbl (apply #'cl-mapcar #'list tbl))
			;; When present, remove hlines as they can't (currentily) be easily transposed.
			(setq tbl (apply #'cl-mapcar #'list
					 (remove 'hline tbl)))
			(push 'hline (cdr tbl))))
		    tbl))
	   (num-cols (length (if (eq (nth 0 table) 'hline) (nth 1 table)
			       (nth 0 table)))))
      (run-with-idle-timer 0.1 nil #'delete-file data-file)
      (while (eq 'hline (car table)) (setf table (cdr table)))
      (when (eq (cadr table) 'hline)
	(setf params
	      (plist-put params :labels (nth 0 table))) ; headers to labels
	(setf table (delq 'hline (cdr table)))) ; clean non-data from table
      ;; Collect options.
      (save-excursion (while (and (equal 0 (forward-line -1))
				  (looking-at "[[:space:]]*#\\+"))
			(setf params (org-plot/collect-options params))))
      ;; Dump table to datafile (very different for grid).
      (pcase (plist-get params :plot-type)
	(`2d   (org-plot/gnuplot-to-data table data-file params))
	(`3d   (org-plot/gnuplot-to-data table data-file params))
	(`grid (let ((y-labels (org-plot/gnuplot-to-grid-data
				table data-file params)))
		 (when y-labels (plist-put params :ylabels y-labels)))))
      ;; Check for timestamp ind column.
      (let ((ind (1- (plist-get params :ind))))
	(when (and (>= ind 0) (eq '2d (plist-get params :plot-type)))
	  (if (= (length
		  (delq 0 (mapcar
			   (lambda (el)
			     (if (string-match org-ts-regexp3 el) 0 1))
			   (mapcar (lambda (row) (nth ind row)) table))))
		 0)
	      (plist-put params :timeind t)
	    ;; Check for text ind column.
	    (if (or (string= (plist-get params :with) "hist")
		    (> (length
			(delq 0 (mapcar
				 (lambda (el)
				   (if (string-match org-table-number-regexp el)
				       0 1))
				 (mapcar (lambda (row) (nth ind row)) table))))
		       0))
		(plist-put params :textind t)))))
      ;; Write script.
      (with-temp-buffer
	(if (plist-get params :script)	; user script
	    (progn (insert
		    (org-plot/gnuplot-script data-file num-cols params t))
		   (insert "\n")
		   (insert-file-contents (plist-get params :script))
		   (goto-char (point-min))
		   (while (re-search-forward "\\$datafile" nil t)
		     (replace-match data-file nil nil)))
	  (insert (org-plot/gnuplot-script data-file num-cols params)))
	;; Graph table.
	(gnuplot-mode)
	(gnuplot-send-buffer-to-gnuplot))
      ;; Cleanup.
      (bury-buffer (get-buffer "*gnuplot*")))))

(provide 'org-plot)

;; Local variables:
;; generated-autoload-file: "org-loaddefs.el"
;; End:

;;; org-plot.el ends here