emacs-orgmode@gnu.org archives
 help / color / mirror / code / Atom feed
From: "Rudolf Adamkovič" <salutis@me.com>
To: Ihor Radchenko <yantar92@gmail.com>
Cc: Nicolas Goaziou <mail@nicolasgoaziou.fr>, emacs-orgmode@gnu.org
Subject: Re: [PATCH] Re: No mathematics in Texinfo exports
Date: Wed, 15 Jun 2022 22:26:39 +0200	[thread overview]
Message-ID: <m2mtedisg0.fsf@me.com> (raw)
In-Reply-To: <87bkv75mgo.fsf@localhost>

[-- Attachment #1: Type: text/plain, Size: 1060 bytes --]

Ihor Radchenko <yantar92@gmail.com> writes:

> Sounds reasonable in general.

Ihor, thank you for guiding me through the process!

> `org-export-with-latex' is a global setting. I do not think that
> texinfo equivalent should be global. It should only be declared inside
> ox-texinfo.

That makes perfect sense.  Please see the new patch attached to this
message.  What do you think?

> As for the default value, it would be better if the option were set
> depending on the installed Texinfo version. If the installed Texinfo
> supports math, set it to t. Otherwise, nil. Of course, users will be
> able to override the default as they wish.

I looked at both ox-texinfo.el and texinfo.el, and I found no function
or variable that would give the installed Texinfo version.

Do we pull the version from "makeinfo --version" and then parse it?  If
so, does that functionality belong to Org (ox-texinfo.el) or Emacs
(texinfo.el) instead?  I also wonder how we could test it so that it
will not break.  I would appreciate any ideas and/or pointers from you.

Rudy

[-- Attachment #2: 0001-ox-texinfo-Include-LaTeX-in-Texinfo-exports.patch --]
[-- Type: text/x-patch, Size: 11934 bytes --]

From 776b85955181709f440e55be56f8ad9d4211f931 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Rudolf=20Adamkovi=C4=8D?= <salutis@me.com>
Date: Sat, 26 Mar 2022 16:46:47 +0100
Subject: [PATCH] ox-texinfo: Include LaTeX in Texinfo exports

* lisp/ox-texinfo.el (org-texinfo-latex-environment): New function.
* lisp/ox-texinfo.el (org-texinfo-latex-fragment): New function.
* lisp/ox-texinfo.el (texinfo): Set latex-environment.
* lisp/ox-texinfo.el (texinfo): Set latex-fragment.
* testing/lisp/test-ox-texinfo.el: Add basic tests.

Include (La)TeX mathematics, both inline and display style, in Texinfo
exports.
---
 lisp/ox-texinfo.el              |  57 +++++++-
 testing/lisp/test-ox-texinfo.el | 221 ++++++++++++++++++++++++++++++++
 2 files changed, 277 insertions(+), 1 deletion(-)
 create mode 100644 testing/lisp/test-ox-texinfo.el

diff --git a/lisp/ox-texinfo.el b/lisp/ox-texinfo.el
index a01bb268c..d5bb75ce8 100644
--- a/lisp/ox-texinfo.el
+++ b/lisp/ox-texinfo.el
@@ -55,6 +55,8 @@
     (italic . org-texinfo-italic)
     (item . org-texinfo-item)
     (keyword . org-texinfo-keyword)
+    (latex-environment . org-texinfo-latex-environment)
+    (latex-fragment . org-texinfo-latex-fragment)
     (line-break . org-texinfo-line-break)
     (link . org-texinfo-link)
     (node-property . org-texinfo-node-property)
@@ -120,7 +122,9 @@
     (:texinfo-text-markup-alist nil nil org-texinfo-text-markup-alist)
     (:texinfo-format-drawer-function nil nil org-texinfo-format-drawer-function)
     (:texinfo-format-inlinetask-function nil nil org-texinfo-format-inlinetask-function)
-    (:texinfo-compact-itemx nil "compact-itemx" org-texinfo-compact-itemx)))
+    (:texinfo-compact-itemx nil "compact-itemx" org-texinfo-compact-itemx)
+    ;; Redefine regular options.
+    (:with-latex nil "tex" org-texinfo-with-latex)))
 
 \f
 ;;; User Configurable Variables
@@ -355,6 +359,17 @@ The function should return the string to be exported."
   :group 'org-export-texinfo
   :type 'function)
 
+;;;; LaTeX
+
+(defcustom org-texinfo-with-latex org-export-with-latex
+  "Non-nil means process LaTeX math snippets.
+
+When set, the exporter will process LaTeX environments and
+fragments, using Texinfo \"@displaymath\" and \"@math\" commands,
+respectively."
+  :group 'org-export-texinfo
+  :type 'boolean)
+
 ;;;; Itemx
 
 (defcustom org-texinfo-compact-itemx nil
@@ -1212,6 +1227,46 @@ CONTENTS is nil.  INFO is a plist holding contextual information."
 	      (concat "@listoffloats "
 		      (org-export-translate "Listing" :utf-8 info))))))))
 
+;;;; LaTeX Environment
+
+(defun org-texinfo-latex-environment (environment _contents info)
+  "Transcode a LaTeX ENVIRONMENT from Org to Texinfo.  CONTENTS is
+nil.  INFO is a plist holding contextual information."
+  (when (plist-get info :with-latex)
+    (let ((value (org-element-property :value environment)))
+      (string-join (list "@displaymath"
+                         (string-trim (org-remove-indentation value))
+                         "@end displaymath")
+                   "\n"))))
+
+;;;; LaTeX Fragment
+
+(defun org-texinfo-latex-fragment (fragment _contents info)
+  "Transcode a LaTeX FRAGMENT from Org to Texinfo.  CONTENTS is
+nil.  INFO is a plist holding contextual information."
+  (when (plist-get info :with-latex)
+    (let ((value (org-remove-indentation
+                  (org-element-property :value fragment))))
+      (cond
+       ((or (string-match-p "^\\\\\\[" value)
+            (string-match-p "^\\$\\$" value))
+        (concat "\n"
+                "@displaymath"
+                "\n"
+                (string-trim (substring value 2 -2))
+                "\n"
+                "@end displaymath"
+                "\n"))
+       ((string-match-p "^\\$" value)
+        (concat "@math{"
+                (string-trim (substring value 1 -1))
+                "}"))
+       ((string-match-p "^\\\\(" value)
+        (concat "@math{"
+                (string-trim (substring value 2 -2))
+                "}"))
+       (t value)))))
+
 ;;;; Line Break
 
 (defun org-texinfo-line-break (_line-break _contents _info)
diff --git a/testing/lisp/test-ox-texinfo.el b/testing/lisp/test-ox-texinfo.el
new file mode 100644
index 000000000..316b7cb1d
--- /dev/null
+++ b/testing/lisp/test-ox-texinfo.el
@@ -0,0 +1,221 @@
+;;; test-ox-texinfo.el --- Tests for ox-texinfo.el
+
+;; Copyright (C) 2022  Rudolf Adamkovič
+
+;; Author: Rudolf Adamkovič <salutis@me.com>
+
+;; This file is not part of GNU Emacs.
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
+
+;;; Code:
+
+(require 'cl-lib)
+(require 'ox-texinfo)
+
+(unless (featurep 'ox-texinfo)
+  (signal 'missing-test-dependency "org-export-texinfo"))
+
+(ert-deftest test-org-export-texinfo/latex-fragment ()
+  "Test `org-texinfo-latex-fragment' output."
+
+  ;; inline TeX fragment
+  (should
+   (equal "@math{a^2 = b}"
+          (org-texinfo-latex-fragment
+           (org-element-create 'latex-fragment
+                               '(:value "$a^2 = b$"))
+           nil
+           '(:with-latex t))))
+
+  ;; inline TeX fragment, padded
+  (should
+   (equal "@math{a^2 = b}"
+          (org-texinfo-latex-fragment
+           (org-element-create 'latex-fragment
+                               '(:value "$ a^2 = b $"))
+           nil
+           '(:with-latex t))))
+
+  ;; inline LaTeX fragment
+  (should
+   (equal "@math{a^2 = b}"
+          (org-texinfo-latex-fragment
+           (org-element-create 'latex-fragment
+                               '(:value "\\(a^2 = b\\)"))
+           nil
+           '(:with-latex t))))
+
+  ;; inline LaTeX fragment, padded
+  (should
+   (equal "@math{a^2 = b}"
+          (org-texinfo-latex-fragment
+           (org-element-create 'latex-fragment
+                               '(:value "\\( a^2 = b \\)"))
+           nil
+           '(:with-latex t))))
+
+  ;; displayed TeX fragment, inline
+  (should
+   (equal (string-join
+           (list ""
+                 "@displaymath"
+                 "a ^ 2 = b"
+                 "@end displaymath"
+                 "")
+           "\n")
+          (org-texinfo-latex-fragment
+           (org-element-create 'latex-fragment
+                               (list :value "$$a ^ 2 = b$$"))
+           nil
+           '(:with-latex t))))
+
+  ;; displayed TeX fragment, inline, padded
+  (should
+   (equal (string-join
+           (list ""
+                 "@displaymath"
+                 "a ^ 2 = b"
+                 "@end displaymath"
+                 "")
+           "\n")
+          (org-texinfo-latex-fragment
+           (org-element-create 'latex-fragment
+                               (list :value "$$ a ^ 2 = b $$"))
+           nil
+           '(:with-latex t))))
+
+  ;; displayed TeX fragment, multi-line
+  (should
+   (equal (string-join
+           (list ""
+                 "@displaymath"
+                 "a ^ 2 = b"
+                 "b ^ 2 = c"
+                 "@end displaymath"
+                 "")
+           "\n")
+          (org-texinfo-latex-fragment
+           (org-element-create 'latex-fragment
+                               (list :value
+                                     (string-join
+                                      (list "$$"
+                                            "a ^ 2 = b"
+                                            "b ^ 2 = c"
+                                            "$$")
+                                      "\n")))
+           nil
+           '(:with-latex t))))
+
+  ;; displayed TeX fragment, multi-line, indented
+  (should
+   (equal (string-join
+           (list ""
+                 "@displaymath"
+                 "a ^ 2 = b"
+                 "b ^ 2 = c"
+                 "@end displaymath"
+                 "")
+           "\n")
+          (org-texinfo-latex-fragment
+           (org-element-create 'latex-fragment
+                               (list :value
+                                     (string-join
+                                      (list "  $$"
+                                            "  a ^ 2 = b"
+                                            "  b ^ 2 = c"
+                                            "  $$")
+                                      "\n")))
+           nil
+           '(:with-latex t))))
+
+  ;; displayed LaTeX fragment, inline
+  (should
+   (equal (string-join
+           (list ""
+                 "@displaymath"
+                 "a ^ 2 = b"
+                 "@end displaymath"
+                 "")
+           "\n")
+          (org-texinfo-latex-fragment
+           (org-element-create 'latex-fragment
+                               (list :value "\\[a ^ 2 = b\\]"))
+           nil
+           '(:with-latex t))))
+
+  ;; displayed LaTeX fragment, inline, padded
+  (should
+   (equal (string-join
+           (list ""
+                 "@displaymath"
+                 "a ^ 2 = b"
+                 "@end displaymath"
+                 "")
+           "\n")
+          (org-texinfo-latex-fragment
+           (org-element-create 'latex-fragment
+                               (list :value "\\[ a ^ 2 = b \\]"))
+           nil
+           '(:with-latex t)))))
+
+(ert-deftest test-org-export-texinfo/latex-environment ()
+  "Test `org-texinfo-latex-environment' output."
+
+  ;; LaTeX environment
+  (should
+   (equal (string-join
+           (list "@displaymath"
+                 "\\begin{equation}"
+                 "a ^ 2 = b"
+                 "b ^ 2 = c"
+                 "\\end{equation}"
+                 "@end displaymath")
+           "\n")
+          (org-texinfo-latex-environment
+           (org-element-create 'latex-environment
+                               (list :value
+                                     (string-join
+                                      (list "\\begin{equation}"
+                                            "a ^ 2 = b"
+                                            "b ^ 2 = c"
+                                            "\\end{equation}")
+                                      "\n")))
+           nil
+           '(:with-latex t))))
+
+  ;; LaTeX environment, indented
+  (should
+   (equal (string-join
+           (list "@displaymath"
+                 "\\begin{equation}"
+                 "a ^ 2 = b"
+                 "b ^ 2 = c"
+                 "\\end{equation}"
+                 "@end displaymath")
+           "\n")
+          (org-texinfo-latex-environment
+           (org-element-create 'latex-environment
+                               (list :value
+                                     (string-join
+                                      (list "  \\begin{equation}"
+                                            "  a ^ 2 = b"
+                                            "  b ^ 2 = c"
+                                            "  \\end{equation}")
+                                      "\n")))
+           nil
+           '(:with-latex t)))))
+
+(provide 'test-ox-texinfo)
+;;; test-ox-texinfo.el end here
-- 
2.36.1


[-- Attachment #3: Type: text/plain, Size: 300 bytes --]

-- 
"Mathematics takes us still further from what is human into the region
of absolute necessity, to which not only the actual world, but every
possible world, must conform."
-- Bertrand Russell, 1902

Rudolf Adamkovič <salutis@me.com> [he/him]
Studenohorská 25
84103 Bratislava
Slovakia

  reply	other threads:[~2022-06-15 20:27 UTC|newest]

Thread overview: 21+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2022-03-25  7:45 Rudolf Adamkovič
2022-03-26 16:07 ` [PATCH] " Rudolf Adamkovič
2022-04-20 20:14   ` Rudolf Adamkovič
2022-04-21  6:11     ` Ihor Radchenko
2022-04-21  7:31       ` Nicolas Goaziou
2022-04-21  9:59         ` Ihor Radchenko
2022-04-21 11:20           ` Nicolas Goaziou
2022-04-21 13:36             ` Ihor Radchenko
2022-05-15 19:37               ` Rudolf Adamkovič
2022-05-16  2:17                 ` Ihor Radchenko
2022-05-20 12:52                   ` Rudolf Adamkovič
2022-05-23 11:30                     ` Rudolf Adamkovič
2022-05-23 11:37                       ` Ihor Radchenko
2022-05-27  7:04                         ` Rudolf Adamkovič
2022-05-28  2:42                           ` Ihor Radchenko
2022-06-05  9:08                             ` Rudolf Adamkovič
2022-06-05 12:22                               ` Ihor Radchenko
2022-06-15 20:26                                 ` Rudolf Adamkovič [this message]
2022-06-19  8:23                                   ` Ihor Radchenko
2022-06-24 19:33                                     ` Rudolf Adamkovič
2022-06-25  5:51                                       ` Ihor Radchenko

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

  List information: https://www.orgmode.org/

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=m2mtedisg0.fsf@me.com \
    --to=salutis@me.com \
    --cc=emacs-orgmode@gnu.org \
    --cc=mail@nicolasgoaziou.fr \
    --cc=yantar92@gmail.com \
    --subject='Re: [PATCH] Re: No mathematics in Texinfo exports' \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link

Code repositories for project(s) associated with this inbox:

	https://git.savannah.gnu.org/cgit/emacs/org-mode.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).