emacs-orgmode@gnu.org archives
 help / color / mirror / code / Atom feed
blob e63fbc0ed3dc0647bcc9f9e7202eea7b00ef1e13 3184 bytes (raw)
name: lisp/ob-forth.el 	 # note: path name is non-authoritative(*)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
 
;;; ob-forth.el --- Babel Functions for Forth        -*- lexical-binding: t; -*-

;; Copyright (C) 2014-2023 Free Software Foundation, Inc.

;; Author: Eric Schulte
;; Keywords: literate programming, reproducible research, forth
;; URL: https://orgmode.org

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:

;; Requires the gforth forth compiler and `forth-mode' (see below).
;; https://www.gnu.org/software/gforth/

;;; Requirements:

;; Session evaluation requires the gforth forth compiler as well as
;; `forth-mode' which is distributed with gforth (in gforth.el).

;;; Code:

(require 'org-macs)
(unless (version< emacs-version "29")
  (org-assert-version))

(require 'ob)
(require 'org-macs)

(declare-function forth-proc "ext:gforth" ())

(defvar org-babel-default-header-args:forth '((:session . "yes"))
  "Default header arguments for forth code blocks.")

(defun org-babel-execute:forth (body params)
  "Execute a block of Forth code with org-babel.
This function is called by `org-babel-execute-src-block'."
  (if (string= "none" (cdr (assq :session params)))
      (error "Non-session evaluation not supported for Forth code blocks")
    (let ((all-results (org-babel-forth-session-execute body params)))
      (if (member "output" (cdr (assq :result-params params)))
	  (mapconcat #'identity all-results "\n")
	(car (last all-results))))))

(defun org-babel-forth-session-execute (body params)
  (require 'forth-mode)
  (let ((proc (forth-proc))
	(rx " \\(\n:\\|compiled\n\\|ok\n\\)")
	(result-start))
    (with-current-buffer (process-buffer (forth-proc))
      (mapcar (lambda (line)
		(setq result-start (progn (goto-char (process-mark proc))
					  (point)))
		(comint-send-string proc (concat line "\n"))
		;; wait for forth to say "ok"
		(while (not (progn (goto-char result-start)
				   (re-search-forward rx nil t)))
		  (accept-process-output proc 0.01))
		(let ((case (match-string 1)))
		  (cond
		   ((string= "ok\n" case)
		    ;; Collect intermediate output.
		    (buffer-substring (+ result-start 1 (length line))
				      (match-beginning 0)))
		   ((string= "compiled\n" case))
		   ;; Ignore partial compilation.
		   ((string= "\n:" case)
		    ;; Report errors.
		    (org-babel-eval-error-notify 1
		                                 (buffer-substring
		                                  (+ (match-beginning 0) 1) (point-max)))
		    nil))))
	      (split-string (org-trim
			     (org-babel-expand-body:generic body params))
			    "\n"
			    'omit-nulls)))))

(provide 'ob-forth)

;;; ob-forth.el ends here

debug log:

solving e63fbc0ed ...
found e63fbc0ed in https://list.orgmode.org/orgmode/87o7obn0dp.fsf@localhost/
found e5dcad6d0 in https://git.savannah.gnu.org/cgit/emacs/org-mode.git
preparing index
index prepared:
100644 e5dcad6d038b87e85ce20197bc18ac1471d29b60	lisp/ob-forth.el

applying [1/1] https://list.orgmode.org/orgmode/87o7obn0dp.fsf@localhost/
diff --git a/lisp/ob-forth.el b/lisp/ob-forth.el
index e5dcad6d0..e63fbc0ed 100644

Checking patch lisp/ob-forth.el...
Applied patch lisp/ob-forth.el cleanly.

index at:
100644 e63fbc0ed3dc0647bcc9f9e7202eea7b00ef1e13	lisp/ob-forth.el

(*) Git path names are given by the tree(s) the blob belongs to.
    Blobs themselves have no identifier aside from the hash of its contents.^

Code repositories for project(s) associated with this public inbox

	https://git.savannah.gnu.org/cgit/emacs/org-mode.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).