emacs-orgmode@gnu.org archives
 help / color / mirror / code / Atom feed
* Clean up org-faces.el
@ 2018-04-08 13:27 Rasmus
  2018-04-08 14:03 ` Nicolas Goaziou
                   ` (3 more replies)
  0 siblings, 4 replies; 14+ messages in thread
From: Rasmus @ 2018-04-08 13:27 UTC (permalink / raw)
  To: emacs-orgmode

[-- Attachment #1: Type: text/plain, Size: 975 bytes --]

Hi,

I have been wanting to clean up org-faces.el for a couple of years.

1. Font-lock keywords are copied over and the file is a mess to browse.

2. Some faces are basically hard-coded.  It would be better to just
   inherit stuff and let the theme font lock dictate colors.

3. Things that must be fixed-pitch are not marked as such, making Org
   break with variable-pitch-mode out of the box.

4. Some faces probably could stand out a bit more.  E.g. meta-lines may
   not need to use the same face as comments.

I have tried to clean up the file (attached).  It’s probably not something
that should be merged until after v9.2, though.

However, it would be useful to know what sort of ideas there are about
faces.  E.g. I know that faces are eventually to reflect the element type.
Is there anything I should keep in mind?

Also, is there showcase of /all/ faces that I can use to test against?

Thanks,
Rasmus

-- 
Even a three-legged dog has three good legs to lose

[-- Attachment #2: org-faces.el --]
[-- Type: text/plain, Size: 20450 bytes --]

;;; org-faces.el --- Face definitions -*- lexical-binding: t; -*-

;; Copyright (C) 2004-2018 Free Software Foundation, Inc.

;; Author: Carsten Dominik <carsten at orgmode dot org>
;; Keywords: outlines, hypermedia, calendar, wp
;; Homepage: https://orgmode.org
;;
;; This file is part of GNU Emacs.
;;
;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;;; Commentary:

;; This file contains the face definitions for Org.

;;; Code:

;;; Custom variables

(defconst org-level-faces '(org-level-1 org-level-2 org-level-3 org-level-4
		                                org-level-5 org-level-6 org-level-7 org-level-8))

(defcustom org-n-level-faces (length org-level-faces)
  "The number of different faces to be used for headlines.
Org mode defines 8 different headline faces, so this can be at most 8.
If it is less than 8, the level-1 face gets re-used for level N+1 etc."
  :type 'integer
  :group 'org-faces)

(defcustom org-cycle-level-faces t
  "Non-nil means level styles cycle after level `org-n-level-faces'.
Then so level org-n-level-faces+1 is styled like level 1.
If nil, then all levels >=org-n-level-faces are styled like
level org-n-level-faces"
  :group 'org-appearance
  :group 'org-faces
  :version "24.1"
  :type 'boolean)

(defcustom org-agenda-deadline-faces
  '((1.0 . org-warning)
    (0.5 . org-upcoming-deadline)
    (0.0 . org-upcoming-distant-deadline))
  "Faces for showing deadlines in the agenda.
This is a list of cons cells.  The cdr of each cell is a face to be used,
and it can also just be like \\='(:foreground \"yellow\").
Each car is a fraction of the head-warning time that must have passed for
this the face in the cdr to be used for display.  The numbers must be
given in descending order.  The head-warning time is normally taken
from `org-deadline-warning-days', but can also be specified in the deadline
timestamp itself, like this:

   DEADLINE: <2007-08-13 Mon -8d>

You may use d for days, w for weeks, m for months and y for years.  Months
and years will only be treated in an approximate fashion (30.4 days for a
month and 365.24 days for a year)."
  :group 'org-faces
  :group 'org-agenda-daily/weekly
  :type '(repeat
	  (cons
	   (number :tag "Fraction of head-warning time passed")
	   (sexp :tag "Face"))))

(defcustom org-faces-easy-properties
  '((todo . :foreground) (tag . :foreground) (priority . :foreground))
  "The property changes by easy faces.
This is an alist, the keys show the area of application, the values
can be `:foreground' or `:background'.  A color string for special
keywords will then be interpreted as either foreground or background
color."
  :group 'org-faces
  :group 'org-todo
  :version "24.1"
  :type '(repeat
	  (cons (choice (const todo) (const tag) (const priority))
		(choice (const :foreground) (const :background)))))

(defcustom org-todo-keyword-faces nil
  "Faces for specific TODO keywords.
This is a list of cons cells, with TODO keywords in the car
and faces in the cdr.  The face can be a symbol, a color
as a string (in which case the rest is inherited from the `org-todo' face),
or a property list of attributes, like
   (:foreground \"blue\" :weight bold :underline t).
If it is a color string, the variable `org-faces-easy-properties'
determines if it is a foreground or a background color."
  :group 'org-faces
  :group 'org-todo
  :type '(repeat
	  (cons
	   (string :tag "Keyword")
	   (choice :tag "Face   "
		   (string :tag "Color")
		   (sexp :tag "Face")))))

(defcustom org-priority-faces nil
  "Faces for specific Priorities.
This is a list of cons cells, with priority character in the car
and faces in the cdr.  The face can be a symbol, a color
as a string, or a property list of attributes, like
    (:foreground \"blue\" :weight bold :underline t).
If it is a color string, the variable `org-faces-easy-properties'
determines if it is a foreground or a background color."
  :group 'org-faces
  :group 'org-todo
  :type '(repeat
	  (cons
	   (character :tag "Priority")
	   (choice    :tag "Face    "
		      (string :tag "Color")
		      (sexp :tag "Face")))))

(defvar org-tags-special-faces-re nil)
(defun org-set-tag-faces (var value)
  (set var value)
  (if (not value)
      (setq org-tags-special-faces-re nil)
    (setq org-tags-special-faces-re
	  (concat ":\\(" (mapconcat #'car value "\\|") "\\):"))))

(defcustom org-tag-faces nil
  "Faces for specific tags.
This is a list of cons cells, with tags in the car and faces in the cdr.
The face can be a symbol, a foreground color (in which case the rest is
inherited from the `org-tag' face) or a property list of attributes,
like (:foreground \"blue\" :weight bold :underline t).
If you set this variable through customize, it will immediately be effective
in new buffers and in modified lines.
If you set it with Lisp, a restart of Emacs is required to activate the
changes."
  :group 'org-faces
  :group 'org-tags
  :set 'org-set-tag-faces
  :type '(repeat
	  (cons
	   (string :tag "Tag ")
	   (choice :tag "Face"
		   (string :tag "Foreground color")
		   (sexp :tag "Face")))))

(defcustom org-fontify-quote-and-verse-blocks nil
  "Non-nil means, add a special face to #+begin_quote and #+begin_verse block.
When nil, format these as normal Org.  This is the default, because the
content of these blocks will still be treated as Org syntax."
  :group 'org-faces
  :version "24.1"
  :type 'boolean)

\f
;; Basic faces

(defgroup org-faces nil
  "Faces in Org mode."
  :tag "Org Faces"
  :group 'org-appearance)

;; TODO: Maybe this inheirts too much?  Maybe it should only inherit
;; the face?
(defface org-default '((t (:inherit (default))))
  "Face used for org default text."
  :group 'org-faces)

(defface org-fixed '((t (:inherit (fixed-pitch))))
  "Face used for org default text."
  :group 'org-faces)

(defface org-dim '((t (:inherit (shadow))))
  "Face used for dimmed text."
  :group 'org-faces)

(defface org-headline-default nil
  "Common face used for headline elements."
  :group 'org-faces)

;; TODO: Rename
(defface org-bold '((t (:inherit (bold))))
  "Subtly emphasized text"
  :group 'org-faces)

(defface org-underline '((t (:inherit (underline))))
  "Emphasized text")

(defface org-text-highlight '((t :inherit (font-lock-variable-name-face)))
  "Sublte foreground highlight")

(defface org-title-highlight '((t (:inherit (font-lock-builtin-face))))
  "Foreground highlight for titles.")

;; TODO: Rename
(defface org-medium-highlight '((t (:inherit (font-lock-keyword-face))))
  "Medium foreground highlight.")

(defface org-aggresive-highlight '((t (:inherit (font-lock-keyword-face))))
  "Aggresive foreground Highlight.")

(defface org-success '((t (:inherit (font-lock-type-face))))
  "Org success face")

(defface org-subtle-background  '((t (:inherit (region))))
  "Face for subtle background" )

(defface org-aggressive-background '((t (:inherit (secondary-selection))))
  "Face for subtle background" )

;; TODO: remove this and use invisible text instead.
;; TODO: should it use default background instead?
(defface org-hide
  `((t (:foreground ,(face-attribute 'org-default :background nil t))))
  "Face used to hide leading stars in headlines.
The foreground color of this face should be equal to the background
color of the frame."
  :group 'org-faces)

\f
;;; Headlines

(defface org-level-1 '((t (:inherit (outline-1 org-headline-default))))
  "Face used for level 1 headlines."
  :group 'org-faces)

(defface org-level-2 '((t (:inherit (outline-2 org-headline-default))))
  "Face used for level 2 headlines."
  :group 'org-faces)

(defface org-level-3 '((t (:inherit (outline-3 org-headline-default))))
  "Face used for level 3 headlines."
  :group 'org-faces)

(defface org-level-4 '((t (:inherit (outline-4 org-headline-default))))
  "Face used for level 4 headlines."
  :group 'org-faces)

(defface org-level-5 '((t (:inherit (outline-5 org-headline-default))))
  "Face used for level 5 headlines."
  :group 'org-faces)

(defface org-level-6 '((t (:inherit (outline-6 org-headline-default))))
  "Face used for level 6 headlines."
  :group 'org-faces)

(defface org-level-7 '((t (:inherit (outline-7 org-headline-default))))
  "Face used for level 7 headlines."
  :group 'org-faces)

(defface org-level-8 '((t (:inherit (outline-8 org-headline-default))))
  "Face used for level 8 headlines."
  :group 'org-faces)

(defface org-archived '((t :inherit (org-dim)))
  "Face for headline with the ARCHIVE tag."
  :group 'org-faces)

;; TODO: Other variables depends on this, but it also uses
;; org-headline-default...
(defface org-warning '((t :inherit (font-lock-warning-face)))
  "Face for deadlines and TODO keywords."
  :group 'org-faces)

(defface org-tag-group '((t :inherit org-tag))
  "Face for group tags."
  :group 'org-faces
  :version "24.4"
  :package-version '(Org . "8.0"))

(defface org-todo '((t (:inherit (org-warning  org-headline-default))))
  "Face used by headline todo items in progress."
  :group 'org-faces)

(defface org-done '((t (:inherit (org-success org-headline-default))))
  "Face used for todo keywords that indicate DONE items."
  :group 'org-faces)

(defface org-headline-done '((t (:inherit (org-done))))
  "Face used to indicate that a headline is DONE.
This face is only used if `org-fontify-done-headline' is set.  If applies
to the part of the headline after the DONE keyword."
  :group 'org-faces)

(defface org-priority '((t (:inherit (org-medium-highlight org-headline-default))))
  "Face used for priority cookies."
  :group 'org-faces)

(defface org-checkbox-statistics-todo '((t (:inherit (org-todo))))
  "Face used for unfinished checkbox statistics."
  :group 'org-faces)

(defface org-checkbox-statistics-done '((t (:inherit (org-done))))
  "Face used for finished checkbox statistics."
  :group 'org-faces)

(defface org-tag '((t (:inherit (org-bold org-headline-default))))
  "Default face for tags.
Note that the variable `org-tag-faces' can be used to overrule this face for
specific tags."
  :group 'org-faces)

(defface org-ellipsis '((t (:inherit (org-text-highlight org-underline))))
  "Face for the ellipsis in folded text."
  :group 'org-faces)

(defface org-drawer '((t (:inherit (font-lock-constant-face))))
  "Face used for drawers."
  :group 'org-faces)

(defface org-property-value '((t (:inherit org-dim)))
  "Face used for the value of a property."
  :group 'org-faces)


;; Column faces

(defface org-column '((t (:inherit (org-subtle-background))))
  "Face for column display of entry properties.
This is actually only part of the face definition for the text in column view.
The following faces apply, with this priority.

1. The color of the reference face.  This is normally the level fact that
   is used in the outline.  In agenda-mode, it will be the face of the
   first character in the line.  The color is explicitly retained to
   make sure that the column line still looks a bit like the structure
   line it is masking.

2. The `org-column' face.

3. The remaining properties of the reference face.

Since column view works by putting overlays with a display property
over individual characters in the buffer, the face of the underlining
character (this might for example be the a TODO keyword) might still
shine through in some properties.  So when your column view looks
funny, with \"random\" colors, weight, strike-through, try to explicitly
set the properties in the `org-column' face.  For example, set
:underline to nil, or the :slant to `normal'."
  :group 'org-faces)

(defface org-column-title
  '((t (:inherit (org-subtle-background))))
  "Face for column display of entry properties."
  :group 'org-faces)

(defface org-agenda-column-dateline '((t :inherit org-column))
  "Face used in agenda column view for datelines with summaries."
  :group 'org-faces)

;;; Table faces

(defface org-table '((t (:inherit (font-lock-function-name-face org-fixed))))
  "Face used for tables."
  :group 'org-faces)

(defface org-formula '((t (:inherit (org-meta-line org-table ))))
  "Face for formulas."
  :group 'org-faces)

;; Org title keywords etc.

(defface org-title-value '((t (:inherit (org-title-highlight org-headline-default))))
  "Face for document information values"
  :group 'org-faces)

(defface org-document-title '((t (:inherit (org-title-highlight org-bold))))
  "Face for document title, i.e. that which follows the #+TITLE: keyword."
  :group 'org-faces)

(defface org-document-info '((t (:inherit (org-headline-default))))
  "Face for document date, author and email; i.e. that which
follows a #+DATE:, #+AUTHOR: or #+EMAIL: keyword."
  :group 'org-faces)

(defface org-document-info-keyword '((t (:inherit (org-dim org-headline-default))))
  "Face for #+TITLE:, #+AUTHOR:, #+EMAIL: and #+DATE: keywords."
  :group 'org-faces)

;;; Blocks

(defface org-meta-line '((t (:inherit (font-lock-doc-face org-fixed))))
  "Face for meta lines starting with \"#+\"."
  :group 'org-faces
  :version "22.1")

(defface org-block '((t (:inherit (org-dim org-fixed))))
  "Face text in #+begin ... #+end blocks."
  :group 'org-faces
  :version "26.1")

(defface org-quote '((t (:inherit (org-block))))
  "Face for #+BEGIN_QUOTE ... #+END_QUOTE blocks."
  :group 'org-faces)

(defface org-verse '((t (:inherit (org-block))))
  "Face for #+BEGIN_VERSE ... #+END_VERSE blocks."
  :group 'org-faces)

(defface org-block-begin-line '((t (:inherit (org-meta-line))))
  "Face used for the line delimiting the begin of source blocks."
  :group 'org-faces)

(defface org-block-end-line '((t (:inherit (org-meta-line))))
  "Face used for the line delimiting the end of source blocks."
  :group 'org-faces)

;; Org faces for text elements

(defface org-link '((t :inherit (link)))
  "Face for links."
  :group 'org-faces)

(defface org-footnote '((t (:inherit (link-visited))))
  "Face for footnotes."
  :group 'org-faces)

(defface org-target '((t (:inherit (org-underline))))
  "Face for link targets."
  :group 'org-faces)

(defface org-checkbox '((t (:inherit (org-bold))))
  "Face for checkboxes."
  :group 'org-faces)

(defface org-list-dt '((t (:inherit org-bold)))
  "Default face for definition terms in lists."
  :group 'org-faces)

(defface org-code '((t (:inherit (org-dim org-fixed))))
  "Face for fixed-width text like code snippets."
  :group 'org-faces
  :version "22.1")

(defface org-verbatim '((t (:inherit (org-dim org-fixed))))
  "Face for fixed-with text like code snippets."
  :group 'org-faces
  :version "22.1")

(defface org-macro '((t :inherit (org-text-highlight)))
  "Face for macros."
  :group 'org-faces
  :version "24.4"
  :package-version '(Org . "8.0"))

(defface org-latex-and-related '((t :inherit (org-text-highlight)))
  "Face used to highlight LaTeX data, entities and sub/superscript."
  :group 'org-faces
  :version "24.4"
  :package-version '(Org . "8.0"))

;;; Clock and schedule faces

(defface org-scheduled '((t (:inherit (org-agenda-highlight org-success))))
  "Face for items scheduled for a certain day."
  :group 'org-faces)

(defface org-scheduled-today '((t (:inherit (org-scheduled))))
  "Face for items scheduled for a certain day."
  :group 'org-faces)

(defface org-scheduled-previously '((t (:inherit (org-warning org-bold))))
  "Face for items scheduled previously, and not yet done."
  :group 'org-faces)

;;; Dates and deadlines

;; TODO: Is this necessary?
(defface org-upcoming-distant-deadline '((t :inherit (org-default)))
  "Face for items scheduled previously, not done, and have a distant deadline.
See also `org-agenda-deadline-faces'.")

(defface org-upcoming-deadline '((t (:inherit (org-warning org-bold)))) 
  "Face for items scheduled previously, and not yet done."
  :group 'org-faces)

(defface org-clock-overlay '((t (:inherit (org-subtle-background))))
  "Basic face for displaying the secondary selection."
  :group 'org-faces)

(defface org-date '((t (:inherit (org-medium-highlight org-underline))))
  "Face for date/time stamps."
  :group 'org-faces)

(defface org-date-selected '((t (:inherit (org-aggressive-background))))
  "Face for highlighting the calendar day when using `org-read-date'.
Using a bold face here might cause discrepancies while displaying the
calendar."
  :group 'org-faces)

(defface org-sexp-date '((t (:inherit org-date)))
  "Face for diary-like sexp date specifications."
  :group 'org-faces)

;;; Agenda faces

(defface org-agenda-done '((t (:inherit (org-success))))
  "Face used in agenda, to indicate lines switched to DONE.
This face is used to de-emphasize items that where brightly colored in the
agenda because they were things to do, or overdue.  The DONE state itself
is of course immediately visible, but for example a passed deadline is
\(by default) very bright read.  This face could be simply the default face
of the frame, for example."
  :group 'org-faces)

(defface org-agenda-structure '((t (:inherit (org-title-highlight))))
  "Face used in agenda for captions and dates."
  :group 'org-faces)

(defface org-agenda-date '((t (:inherit (org-agenda-structure))))
  "Face used in agenda for normal days."
  :group 'org-faces)

(defface org-agenda-highlight '((t (:inherit (org-bold italic))))
  "Face for agenda emphasize."
  :group 'org-faces)

(defface org-agenda-date-today '((t (:inherit (org-agenda-date org-agenda-highlight))))
  "Face used in agenda for today."
  :group 'org-faces)

(defface org-agenda-clocking '((t (:inherit (org-aggressive-background))))
  "Face marking the current clock item in the agenda."
  :group 'org-faces)

(defface org-agenda-date-weekend '((t (:inherit (org-agenda-date org-bold))))
  "Face used in agenda for weekend days.

See the variable `org-agenda-weekend-days' for a definition of
which days belong to the weekend."
  :group 'org-faces)

(defface org-agenda-dimmed-todo-face '((t (:inherit (org-dim))))
  "Face used to dim blocked tasks in the agenda."
  :group 'org-faces)

;; TODO: where is this used?  Can we use org-subtle-background? 
(defface org-agenda-restriction-lock '((t :inherit (org-subtle-background)))
  "Face for showing the agenda restriction lock."
  :group 'org-faces)

(defface org-agenda-current-time '((t (:inherit (org-time-grid))))
  "Face used to show the current time in the time grid."
  :group 'org-faces)

;; TODO: Is this necessary?
(defface org-agenda-diary '((t :inherit (org-default)))
  "Face used for agenda entries that come from the Emacs diary."
  :group 'org-faces)

;; TODO: Is this necessary?
(defface org-agenda-calendar-event '((t :inherit (org-default)))
  "Face used to show events and appointments in the agenda."
  :group 'org-faces)

;; TODO: Is this necessary?
(defface org-agenda-calendar-sexp '((t :inherit (org-default)))
  "Face used to show events computed from a S-expression."
  :group 'org-faces)

;; TODO: 
(defface org-time-grid '((t :inherit (org-text-highlight)))
  "Face used for time grids."
  :group 'org-faces)

;; Modeline

(defface org-agenda-filter-tags '((t :inherit (mode-line)))
  "Face for tag(s) in the mode-line when filtering the agenda."
  :group 'org-faces)

(defface org-agenda-filter-regexp '((t :inherit (mode-line)))
  "Face for regexp(s) in the mode-line when filtering the agenda."
  :group 'org-faces)

(defface org-agenda-filter-category '((t :inherit (mode-line)))
  "Face for categories in the mode-line when filtering the agenda."
  :group 'org-faces)

(defface org-agenda-filter-effort '((t :inherit (mode-line)))
  "Face for effort in the mode-line when filtering the agenda."
  :group 'org-faces)

(defface org-mode-line-clock '((t (:inherit (mode-line))))
  "Face used for clock display in mode line."
  :group 'org-faces)

(defface org-mode-line-clock-overrun '((t (:inherit (org-warning mode-line))))
  "Face used for clock display for overrun tasks in mode line."
  :group 'org-faces)

(provide 'org-faces)

;;; org-faces.el ends here

^ permalink raw reply	[flat|nested] 14+ messages in thread

* Re: Clean up org-faces.el
  2018-04-08 13:27 Clean up org-faces.el Rasmus
@ 2018-04-08 14:03 ` Nicolas Goaziou
  2018-04-08 14:54 ` Daniele Nicolodi
                   ` (2 subsequent siblings)
  3 siblings, 0 replies; 14+ messages in thread
From: Nicolas Goaziou @ 2018-04-08 14:03 UTC (permalink / raw)
  To: Rasmus; +Cc: emacs-orgmode

Rasmus <rasmus@gmx.us> writes:

> I have been wanting to clean up org-faces.el for a couple of years.

Good idea.

> However, it would be useful to know what sort of ideas there are about
> faces.  E.g. I know that faces are eventually to reflect the element
> type.

Faces predate elements, so faces and elements may not perfectly match.
It would be good if they did, though.

^ permalink raw reply	[flat|nested] 14+ messages in thread

* Re: Clean up org-faces.el
  2018-04-08 13:27 Clean up org-faces.el Rasmus
  2018-04-08 14:03 ` Nicolas Goaziou
@ 2018-04-08 14:54 ` Daniele Nicolodi
  2018-04-08 17:33   ` Rasmus
  2018-04-08 15:53 ` stardiviner
  2018-04-08 19:08 ` Samuel Wales
  3 siblings, 1 reply; 14+ messages in thread
From: Daniele Nicolodi @ 2018-04-08 14:54 UTC (permalink / raw)
  To: emacs-orgmode

On 08/04/2018 07:27, Rasmus wrote:
> I have been wanting to clean up org-faces.el for a couple of years.

Only tangentially related: is there a way to have a different face for
tables content and tables structure (ie the grid)?  The default blue
hurts my eyes :-)

Cheers,
Dan

^ permalink raw reply	[flat|nested] 14+ messages in thread

* Re: Clean up org-faces.el
  2018-04-08 13:27 Clean up org-faces.el Rasmus
  2018-04-08 14:03 ` Nicolas Goaziou
  2018-04-08 14:54 ` Daniele Nicolodi
@ 2018-04-08 15:53 ` stardiviner
  2018-04-08 17:34   ` Rasmus
  2018-04-08 19:08 ` Samuel Wales
  3 siblings, 1 reply; 14+ messages in thread
From: stardiviner @ 2018-04-08 15:53 UTC (permalink / raw)
  To: Rasmus; +Cc: emacs-orgmode

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA256

Add face for inline src: src_ruby{require 'library'}

Here is my custom face:

;; inline code face => src_ruby{require 'something'}
;;
;; (REGEXP . FACE)
;;     Highlight REGEXP with FACE
;; (REGEXP N FACE)
;;     Highlight group N in REGEXP with FACE
;; (REGEXP (N1 FACE1) (N2 FACE2) (N3 FACE3) …)
;;     Highlight group Ni in REGEXP with FACEi
;;
;; src_lang{code...}[:header arguments] / NOTE: override by `org-verbatim'.
;; result in following =[result]=

;; src_
(font-lock-add-keywords
 'org-mode
 '(("\\(src_\\)\\([^[{]+\\)\\(\\[:.*\\]\\)\\({\\)\\([^}]*\\)\\(}\\)"
    (1 '(:foreground "black" :weight 'normal :height 0.1)) ; src_ part
    (2 '(:foreground "cyan" :weight 'bold :height 0.8 :box '(:color "light gray"))) ; "lang" part.
    (3 '(:foreground "#555555" :height 0.7)) ; [:header arguments] part.
    (4 '(:foreground "#333333")) ; {
    (5 'org-code) ; "code..." part.
    (6 '(:foreground "#333333")) ; }
    ))
 'append)

;; src without arguments
(font-lock-add-keywords
 'org-mode
 '(("\\(src_\\)\\([^[{]+\\)\\({\\)\\([^}]*\\)\\(}\\)"
    (1 '(:foreground "black" :weight 'normal :height 0.1)) ; src_ part
    (2 '(:foreground "cyan" :weight 'bold :height 0.8 :box '(:color "light gray"))) ; "lang" part.
    (3 '(:foreground "#333333")) ; {
    (4 'org-code) ; "code..." part.
    (5 '(:foreground "#333333")) ; }
    ))
 'append)

;; inline babel call
;; ... call_<name>[<inside header arguments>](<arguments>)[<end header arguments>] ...
(font-lock-add-keywords
 'org-mode
 '(("\\(call_\\)\\([^[(]*\\)\\[\\(.*\\)\\](\\(.*\\))\\[\\(.*\\)\\]"
    ;; "\\(call_\\)\\([^[(]*\\)\\([([][^)]*]\\)+"
    (1 '(:foreground "orange red" :height 0.6)) ; call_
    (2 '(:foreground "yellow" :weight 'bold :underline "dark gray")) ; <name>
    (3 '(:foreground "gray" :height 0.6)) ; [<inside header arguments>]
    (4 '(:foreground "cyan" :weight 'bold)) ; (<arguments>)
    (5 '(:foreground "gray" :height 0.6)) ; [<end header arguments>]
    ))
 'append)

;; call_<name>[<inside header arguments>](<arguments>)
(font-lock-add-keywords
 'org-mode
 '(("\\(call_\\)\\([^[(]*\\)\\[\\(.*\\)\\](\\(.*\\))"
    (1 '(:foreground "orange red" :height 0.6)) ; call_
    (2 '(:foreground "yellow" :weight 'bold :underline "dark gray")) ; <name>
    (3 '(:foreground "gray" :height 0.6)) ; [<inside header argument>]
    (4 '(:foreground "cyan" :weight 'bold)) ; (<arguments>)
    ))
 'append)

;; call_<name>(arguments)
(font-lock-add-keywords
 'org-mode
 '(("\\(call_\\)\\([^[(]*\\)\\((.*)\\)"
    (1 '(:foreground "orange red" :height 0.6)) ; call_
    (2 '(:foreground "yellow" :weight 'bold :underline "dark gray")) ; <name>
    (3 '(:foreground "cyan" :weight 'bold)) ; (<arguments>)
    ))
 'append)

- -- 
[ stardiviner ] don't need to convince with trends.
       Blog: https://stardiviner.github.io/
       IRC(freenode): stardiviner
       GPG: F09F650D7D674819892591401B5DF1C95AE89AC3
      
-----BEGIN PGP SIGNATURE-----

iQEzBAEBCAAdFiEE8J9lDX1nSBmJJZFAG13xyVromsMFAlrKOvwACgkQG13xyVro
msPuAwf/WNhzQi6UNCfO/Oeb6Mh5O+OwXK9wDU8rZI+pxN17XrBhGEqsLgDUO3RF
W/vmMs49a1C45Id5xlRZXiZ16oC6nuIWjP4W7syorf7WIZismk6AncsATin5DfiG
TzrmZ2jjpHhucr8kjbCji3r5/ch/JZUJ52MQVsmD4MqyG/RSVUknbDRJD0qWsaxJ
AComyyaNqQbtWPwi0s896RKa+aWPTXg62Yq26Z0k5ANwh022APRu/ona4FIVMmbN
fEGflIgfXmDPkqZg9O8v9WPVwq0ZhA4kc+3+Efkatwf9nmPW2BtHi2eTo/+c50Jh
WgwPhqMf7CYdUUEOaxx4UdqcDe1JUQ==
=bJNn
-----END PGP SIGNATURE-----

^ permalink raw reply	[flat|nested] 14+ messages in thread

* Re: Clean up org-faces.el
  2018-04-08 14:54 ` Daniele Nicolodi
@ 2018-04-08 17:33   ` Rasmus
  2018-04-08 19:02     ` Daniele Nicolodi
  0 siblings, 1 reply; 14+ messages in thread
From: Rasmus @ 2018-04-08 17:33 UTC (permalink / raw)
  To: emacs-orgmode

Daniele Nicolodi <daniele@grinta.net> writes:

> On 08/04/2018 07:27, Rasmus wrote:
>> I have been wanting to clean up org-faces.el for a couple of years.
>
> Only tangentially related: is there a way to have a different face for
> tables content and tables structure (ie the grid)?  The default blue
> hurts my eyes :-)

That’s a nice idea.

At the moment it’s not possible as it’s the same face for table contents
and table borders.  It shouldn’t be too hard to add since cells are
recognized by org-element.  It would solve another of my issues.  I
typically display links in variable pitch, but when they then go into
tables, it breaks the alignment.

Rasmus

-- 
Dobbelt-A

^ permalink raw reply	[flat|nested] 14+ messages in thread

* Re: Clean up org-faces.el
  2018-04-08 15:53 ` stardiviner
@ 2018-04-08 17:34   ` Rasmus
  2018-04-09  2:46     ` stardiviner
  0 siblings, 1 reply; 14+ messages in thread
From: Rasmus @ 2018-04-08 17:34 UTC (permalink / raw)
  To: emacs-orgmode

Hi,

stardiviner <numbchild@gmail.com> writes:

> Add face for inline src: src_ruby{require 'library'}
>
> Here is my custom face: ...

Are you saying that we should display inline calls better?

Rasmus

-- 
Warning: Everything saved will be lost

^ permalink raw reply	[flat|nested] 14+ messages in thread

* Re: Clean up org-faces.el
  2018-04-08 17:33   ` Rasmus
@ 2018-04-08 19:02     ` Daniele Nicolodi
  0 siblings, 0 replies; 14+ messages in thread
From: Daniele Nicolodi @ 2018-04-08 19:02 UTC (permalink / raw)
  To: emacs-orgmode

On 08/04/2018 11:33, Rasmus wrote:
> Daniele Nicolodi <daniele@grinta.net> writes:
> 
>> On 08/04/2018 07:27, Rasmus wrote:
>>> I have been wanting to clean up org-faces.el for a couple of years.
>>
>> Only tangentially related: is there a way to have a different face for
>> tables content and tables structure (ie the grid)?  The default blue
>> hurts my eyes :-)
> 
> That’s a nice idea.
> 
> At the moment it’s not possible as it’s the same face for table contents
> and table borders.  It shouldn’t be too hard to add since cells are
> recognized by org-element.  It would solve another of my issues.  I
> typically display links in variable pitch, but when they then go into
> tables, it breaks the alignment.

I can look into it, but it may take a while for me to figure it out.

Cheers,
Dan

^ permalink raw reply	[flat|nested] 14+ messages in thread

* Re: Clean up org-faces.el
  2018-04-08 13:27 Clean up org-faces.el Rasmus
                   ` (2 preceding siblings ...)
  2018-04-08 15:53 ` stardiviner
@ 2018-04-08 19:08 ` Samuel Wales
  2018-04-08 19:54   ` Diego Zamboni
  3 siblings, 1 reply; 14+ messages in thread
From: Samuel Wales @ 2018-04-08 19:08 UTC (permalink / raw)
  To: Rasmus; +Cc: emacs-orgmode

On 4/8/18, Rasmus <rasmus@gmx.us> wrote:
> I have been wanting to clean up org-faces.el for a couple of years.

thanks.

fwiw on variable pitch.

i find that variable pitch reads legibly.  is efficient with
horizontal space, and looks great.  it also makes the mode
line short.  took a few days to get used to, then it got awesome.  i
will never go back.

in my .emacs i made tables, example block contents, and
timestamps be fixed-pitch.  you want those to align.

it works great in org.

the only issues i have found in org are:

  1) these items do not seem to have their own face and thus
     cannot yet be made to be fixed pitch:
     1) list bullets
     2) the spaces before list items and contents
     3) source block contents
     4) numbers and number components like .-,+
  2) tags do not get aligned to the same window-pixel
  3) by default, c-c ' does not run prog-mode hooks where necessary to
turn it off.  or something.  trivial workaround is setting mode in the
block.  so not really a problem.


samuel

^ permalink raw reply	[flat|nested] 14+ messages in thread

* Re: Clean up org-faces.el
  2018-04-08 19:08 ` Samuel Wales
@ 2018-04-08 19:54   ` Diego Zamboni
  2018-04-08 20:02     ` Samuel Wales
  0 siblings, 1 reply; 14+ messages in thread
From: Diego Zamboni @ 2018-04-08 19:54 UTC (permalink / raw)
  To: Samuel Wales; +Cc: Diego Zamboni, emacs-orgmode, Rasmus

[-- Attachment #1: Type: text/plain, Size: 1608 bytes --]

Hi Samuel,

Agree, I have started using variable pitch in org-mode and it has made it much more enjoyable.

I recently documented my configuration here: http://zzamboni.org/post/beautifying-org-mode-in-emacs/ <http://zzamboni.org/post/beautifying-org-mode-in-emacs/>

About your point (1.3), I have source blocks set to fixed-pitch by configuring the “org-block” face, works well.

Best,
—Diego



> On 8 Apr 2018, at 21:08, Samuel Wales <samologist@gmail.com> wrote:
> 
> On 4/8/18, Rasmus <rasmus@gmx.us> wrote:
>> I have been wanting to clean up org-faces.el for a couple of years.
> 
> thanks.
> 
> fwiw on variable pitch.
> 
> i find that variable pitch reads legibly.  is efficient with
> horizontal space, and looks great.  it also makes the mode
> line short.  took a few days to get used to, then it got awesome.  i
> will never go back.
> 
> in my .emacs i made tables, example block contents, and
> timestamps be fixed-pitch.  you want those to align.
> 
> it works great in org.
> 
> the only issues i have found in org are:
> 
>  1) these items do not seem to have their own face and thus
>     cannot yet be made to be fixed pitch:
>     1) list bullets
>     2) the spaces before list items and contents
>     3) source block contents
>     4) numbers and number components like .-,+
>  2) tags do not get aligned to the same window-pixel
>  3) by default, c-c ' does not run prog-mode hooks where necessary to
> turn it off.  or something.  trivial workaround is setting mode in the
> block.  so not really a problem.
> 
> 
> samuel
> 


[-- Attachment #2: Type: text/html, Size: 2892 bytes --]

^ permalink raw reply	[flat|nested] 14+ messages in thread

* Re: Clean up org-faces.el
  2018-04-08 19:54   ` Diego Zamboni
@ 2018-04-08 20:02     ` Samuel Wales
  2018-04-08 20:21       ` Samuel Wales
  0 siblings, 1 reply; 14+ messages in thread
From: Samuel Wales @ 2018-04-08 20:02 UTC (permalink / raw)
  To: Diego Zamboni; +Cc: emacs-orgmode, Rasmus

ah, i have org-block fixed also and did not update the list of things
not separate.

       (org-block ((t (:inherit fixed-pitch :foreground "#70b020"))))
       (org-date ((t (:inherit fixed-pitch :foreground "#806ab0"
:underline t))))
       (org-date-selected ((t (:inherit fixed-pitch :background "Pink"))))
       (org-table ((t (:inherit fixed-pitch :foreground "#70a000"))))

also org-code and rcirc-timestamp.


On 4/8/18, Diego Zamboni <diego@zzamboni.org> wrote:
> Hi Samuel,
>
> Agree, I have started using variable pitch in org-mode and it has made it
> much more enjoyable.
>
> I recently documented my configuration here:
> http://zzamboni.org/post/beautifying-org-mode-in-emacs/
> <http://zzamboni.org/post/beautifying-org-mode-in-emacs/>
>
> About your point (1.3), I have source blocks set to fixed-pitch by
> configuring the “org-block” face, works well.
>
> Best,
> —Diego
>
>
>
>> On 8 Apr 2018, at 21:08, Samuel Wales <samologist@gmail.com> wrote:
>>
>> On 4/8/18, Rasmus <rasmus@gmx.us> wrote:
>>> I have been wanting to clean up org-faces.el for a couple of years.
>>
>> thanks.
>>
>> fwiw on variable pitch.
>>
>> i find that variable pitch reads legibly.  is efficient with
>> horizontal space, and looks great.  it also makes the mode
>> line short.  took a few days to get used to, then it got awesome.  i
>> will never go back.
>>
>> in my .emacs i made tables, example block contents, and
>> timestamps be fixed-pitch.  you want those to align.
>>
>> it works great in org.
>>
>> the only issues i have found in org are:
>>
>>  1) these items do not seem to have their own face and thus
>>     cannot yet be made to be fixed pitch:
>>     1) list bullets
>>     2) the spaces before list items and contents
>>     3) source block contents
>>     4) numbers and number components like .-,+
>>  2) tags do not get aligned to the same window-pixel
>>  3) by default, c-c ' does not run prog-mode hooks where necessary to
>> turn it off.  or something.  trivial workaround is setting mode in the
>> block.  so not really a problem.
>>
>>
>> samuel
>>
>
>


-- 
The Kafka Pandemic: <http://thekafkapandemic.blogspot.com>

The disease DOES progress. MANY people have died from it. And ANYBODY
can get it at any time.

"You’ve really gotta quit this and get moving, because this is murder
by neglect." ---
<http://www.meaction.net/2017/02/03/pwme-people-with-me-are-being-murdered-by-neglect>.

^ permalink raw reply	[flat|nested] 14+ messages in thread

* Re: Clean up org-faces.el
  2018-04-08 20:02     ` Samuel Wales
@ 2018-04-08 20:21       ` Samuel Wales
  2018-04-08 20:30         ` Diego Zamboni
  2018-04-09  3:01         ` Vikas Rawal
  0 siblings, 2 replies; 14+ messages in thread
From: Samuel Wales @ 2018-04-08 20:21 UTC (permalink / raw)
  To: Diego Zamboni; +Cc: emacs-orgmode, Rasmus

that is a great blog post!  lots of good detail.  and visually pleasing itself.

off topic here, but the problem with visual-line-mode for me is that
at least in 24.4 it does not respect fill column.  this is a
dealbreaker.  i stick with m-q.

the variable line-spacing is defined in c, so that might need to be
made more subtle in c.  i have not noticed the issue.  at least (list
(frame-width) (frame-height)))) is identical whether variable or
fixed.

in any case pleased that this stuff is being made /even better/ by rasmus.

-- 
The Kafka Pandemic: <http://thekafkapandemic.blogspot.com>

The disease DOES progress. MANY people have died from it. And ANYBODY
can get it at any time.

"You’ve really gotta quit this and get moving, because this is murder
by neglect." ---
<http://www.meaction.net/2017/02/03/pwme-people-with-me-are-being-murdered-by-neglect>.

^ permalink raw reply	[flat|nested] 14+ messages in thread

* Re: Clean up org-faces.el
  2018-04-08 20:21       ` Samuel Wales
@ 2018-04-08 20:30         ` Diego Zamboni
  2018-04-09  3:01         ` Vikas Rawal
  1 sibling, 0 replies; 14+ messages in thread
From: Diego Zamboni @ 2018-04-08 20:30 UTC (permalink / raw)
  To: Samuel Wales; +Cc: Diego Zamboni, emacs-orgmode, Rasmus

[-- Attachment #1: Type: text/plain, Size: 1095 bytes --]


> that is a great blog post!  lots of good detail.  and visually pleasing itself.

Thanks! I recently started using ox-hugo for my blogging, and it works great.

> off topic here, but the problem with visual-line-mode for me is that
> at least in 24.4 it does not respect fill column.  this is a
> dealbreaker.  i stick with m-q.

It still doesn’t (I’m using 25.3.2), but I have become used to adjusting the width of my Emacs window to match what I want to do - make it full-width for coding, and half- or two-thirds for prose. The lines then adjust to the width of the window automatically.

Thinking about it, I’m not sure it’s even possible, since fill-column (just like m-q) works based on number of characters in a line, which is not a good indicator with proportional fonts. There would need to be some other way to indicate where to wrap the line that does not depend on number of characters (I guess this is what setting the window width does, in fact).

> in any case pleased that this stuff is being made /even better/ by rasmus.

Fully agree!

—Diego



[-- Attachment #2: Type: text/html, Size: 4928 bytes --]

^ permalink raw reply	[flat|nested] 14+ messages in thread

* Re: Clean up org-faces.el
  2018-04-08 17:34   ` Rasmus
@ 2018-04-09  2:46     ` stardiviner
  0 siblings, 0 replies; 14+ messages in thread
From: stardiviner @ 2018-04-09  2:46 UTC (permalink / raw)
  To: Rasmus; +Cc: emacs-orgmode

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA256


Rasmus <rasmus@gmx.us> writes:

> Hi,
>
> stardiviner <numbchild@gmail.com> writes:
>
>> Add face for inline src: src_ruby{require 'library'}
>>
>> Here is my custom face: ...
>
> Are you saying that we should display inline calls better?
>
> Rasmus

Yes, currently it seems does not have font-lock yet.

- -- 
[ stardiviner ] don't need to convince with trends.
       Blog: https://stardiviner.github.io/
       IRC(freenode): stardiviner
       GPG: F09F650D7D674819892591401B5DF1C95AE89AC3
      
-----BEGIN PGP SIGNATURE-----

iQEzBAEBCAAdFiEE8J9lDX1nSBmJJZFAG13xyVromsMFAlrK0+kACgkQG13xyVro
msNLhAf8DQlW4Iq/UMq7IpmWUQC0RTifkNbAFrtTABZukjYjbGJesh++EBOMEANJ
8sHPZhD4fIGCRfOx7SmyLNd29vhDCDwMtlopmWMydSvMw7hs9uljtQPSaps3rYrt
R32DZ+rg809aOBHBB/o5ksT1WZNubZIUX+6MuJ1m53J23ZXAo/7sjBubERWpwOqL
M7SGfxy8+7EicuuO7+7HWNP2ATVYW5fHzUFT1bL1kMD7R4g+TjPu7qwCEZrWYNXK
XKnJXuXPt3qk+ASY1r9WwPInTxlz7qVe0bjO3vnTlTtJb596dD+K1eIv54Tyc2+4
ZKNSsJt6kUKouk0iGqryMwgKdAU8kw==
=+sIt
-----END PGP SIGNATURE-----

^ permalink raw reply	[flat|nested] 14+ messages in thread

* Re: Clean up org-faces.el
  2018-04-08 20:21       ` Samuel Wales
  2018-04-08 20:30         ` Diego Zamboni
@ 2018-04-09  3:01         ` Vikas Rawal
  1 sibling, 0 replies; 14+ messages in thread
From: Vikas Rawal @ 2018-04-09  3:01 UTC (permalink / raw)
  To: Samuel Wales; +Cc: Diego Zamboni, org-mode mailing list, Rasmus

> 
> off topic here, but the problem with visual-line-mode for me is that
> at least in 24.4 it does not respect fill column.  this is a
> dealbreaker.  i stick with m-q.

There is a visual-fill-column-mode. Have you tried that?

Vikas

^ permalink raw reply	[flat|nested] 14+ messages in thread

end of thread, other threads:[~2018-04-09  3:01 UTC | newest]

Thread overview: 14+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2018-04-08 13:27 Clean up org-faces.el Rasmus
2018-04-08 14:03 ` Nicolas Goaziou
2018-04-08 14:54 ` Daniele Nicolodi
2018-04-08 17:33   ` Rasmus
2018-04-08 19:02     ` Daniele Nicolodi
2018-04-08 15:53 ` stardiviner
2018-04-08 17:34   ` Rasmus
2018-04-09  2:46     ` stardiviner
2018-04-08 19:08 ` Samuel Wales
2018-04-08 19:54   ` Diego Zamboni
2018-04-08 20:02     ` Samuel Wales
2018-04-08 20:21       ` Samuel Wales
2018-04-08 20:30         ` Diego Zamboni
2018-04-09  3:01         ` Vikas Rawal

Code repositories for project(s) associated with this public inbox

	https://git.savannah.gnu.org/cgit/emacs/org-mode.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).