emacs-orgmode@gnu.org archives
 help / color / mirror / code / Atom feed
a2a1f40e5b747d1e42565f14d9eb4872d26adbf8 blob 4386 bytes (raw)

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
 
;;; ob-java.el --- org-babel functions for java evaluation

;; Copyright (C) 2011-2014 Free Software Foundation, Inc.

;; Author: Eric Schulte
;; Keywords: literate programming, reproducible research
;; Homepage: http://orgmode.org

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; Currently this only supports the external compilation and execution
;; of java code blocks (i.e., no session support).

;;; Code:
(require 'ob)

(defvar org-babel-tangle-lang-exts)
(add-to-list 'org-babel-tangle-lang-exts '("java" . "java"))

(defcustom org-babel-java-command "java"
  "Name of the java command.
May be either a command in the path, like java
or an absolute path name, like /usr/local/bin/java
parameters may be used, like java -verbose"
  :group 'org-babel
  :version "24.3"
  :type 'string)

(defcustom org-babel-java-compiler "javac"
  "Name of the java compiler.
May be either a command in the path, like javac
or an absolute path name, like /usr/local/bin/javac
parameters may be used, like javac -verbose"
  :group 'org-babel
  :version "24.3"
  :type 'string)

(defun org-babel-execute:java (body params)
  (let* ((classname (or (cdr (assoc :classname params))
			(error
			 "Can't compile a java block without a classname")))
	 (packagename (file-name-directory classname))
	 (src-file (concat classname ".java"))
	 (cmpflag (or (cdr (assoc :cmpflag params)) ""))
	 (cmdline (or (cdr (assoc :cmdline params)) ""))
	 (split-body
	  (split-string body (concat classname "[\n\t ]*{")))
	 (full-body
	  (org-babel-expand-body:generic
	   (concat (car split-body) (concat classname " {\n") (org-babel-variable-assignments:java params)
		   (mapconcat 'identity (cdr split-body) (concat classname " {")))
	   params))
	 (compile
	  (progn (with-temp-file src-file (insert full-body))
		 (org-babel-eval
		  (concat org-babel-java-compiler
			  " " cmpflag " " src-file) ""))))
    ;; created package-name directories if missing
    (unless (or (not packagename) (file-exists-p packagename))
      (make-directory packagename 'parents))
    (let ((results (org-babel-eval (concat org-babel-java-command
                                           " " cmdline " " classname) "")))
      (org-babel-reassemble-table
       (org-babel-result-cond (cdr (assoc :result-params params))
	 (org-babel-read results)
         (let ((tmp-file (org-babel-temp-file "c-")))
           (with-temp-file tmp-file (insert results))
           (org-babel-import-elisp-from-file tmp-file)))
       (org-babel-pick-name
        (cdr (assoc :colname-names params)) (cdr (assoc :colnames params)))
       (org-babel-pick-name
        (cdr (assoc :rowname-names params)) (cdr (assoc :rownames params)))))))

(defun org-babel-variable-assignments:java (params)
  "Return an internal Java class assigning the block's variables."
  (concat "    private static class Data {\n"
	  (mapconcat 'identity
		     (mapcar
		      (lambda (pair)
			(format "        public static %s %s = %s;"
				(cond
				 ((stringp (cdr pair)) "String")
				 ((listp (cdr pair)) "java.util.List")
				 ((floatp (cdr pair)) "double")
				 (t "int"))
				(car pair)
				(org-babel-java-var-to-java (cdr pair))))
		      (mapcar #'cdr (org-babel-get-header params :var)))
		     "\n")
	  "\n    }")
  )

(defun org-babel-java-var-to-java (var)
  "Convert an elisp value to a java string.
Convert an elisp value, VAR, into a string of Java source code
specifying a variable of the same value."
  (if (listp var)
      (concat "java.util.Arrays.asList(" (mapconcat #'org-babel-java-var-to-java var ", ") ")")
    (if (equal var 'hline)
	"null"
      (format
       (if (and (stringp var) (string-match "[\n\r]" var)) "\"\"%S\"\"" "%S")
       var))))

(provide 'ob-java)



;;; ob-java.el ends here
debug log:

solving a2a1f40 ...
found a2a1f40 in https://list.orgmode.org/orgmode/87fvixdhfz.fsf@gmail.com/
found 8c64171 in https://git.savannah.gnu.org/cgit/emacs/org-mode.git
preparing index
index prepared:
100644 8c641716a8d155ced566648de337c36567f5611a	lisp/ob-java.el

applying [1/1] https://list.orgmode.org/orgmode/87fvixdhfz.fsf@gmail.com/
diff --git a/lisp/ob-java.el b/lisp/ob-java.el
index 8c64171..a2a1f40 100644

Checking patch lisp/ob-java.el...
Applied patch lisp/ob-java.el cleanly.

index at:
100644 a2a1f40e5b747d1e42565f14d9eb4872d26adbf8	lisp/ob-java.el

Code repositories for project(s) associated with this inbox:

	https://git.savannah.gnu.org/cgit/emacs/org-mode.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).