emacs-orgmode@gnu.org archives
 help / color / mirror / code / Atom feed

From: Thorsten Jolitz <tjolitz@gmail.com>
To: emacs-orgmode@gnu.org
Subject: (Maybe) enhance `org-element-src-block-interpreter'?
Date: Tue, 05 Aug 2014 18:17:27 +0200	[thread overview]
Message-ID: <87tx5qvrl4.fsf@gmail.com> (raw)


Hi, 

a slight enhancement:

#+begin_src emacs-lisp
  (defun tj/src-block-interpreter (src-block contents)
    "Interpret SRC-BLOCK element as Org syntax.  CONTENTS is nil."
    (let ((lang (org-element-property :language src-block))
          (switches (org-element-property :switches src-block))
          (params (org-element-property :parameters src-block))
          (headers (org-element-property :header src-block))
          (value
           (let ((val (org-element-property :value src-block)))
             (cond
              ((or org-src-preserve-indentation
                   (org-element-property :preserve-indent src-block))
               val)
              ((zerop org-edit-src-content-indentation) val)
              (t
               (let ((ind (make-string
                           org-edit-src-content-indentation ?\s)))
                 (replace-regexp-in-string
                  "\\(^\\)[ \t]*\\S-" ind val nil nil 1))))))
          packed-headers)
      (concat (format "%s#+BEGIN_SRC%s\n"
                      (progn
                        (while headers
                          (setq packed-headers
                                (concat
                                 (format "#+HEADER: %s\n"
                                         (pop headers))
                                 packed-headers)))
                        (or packed-headers ""))
                      (concat (and lang (concat " " lang))
                              (and switches (concat " " switches))
                              (and params (concat " " params))))
              (org-escape-code-in-string value)
              ;; (save-match-data
              ;;   (if (looking-at "^$") "" "\n"))
              "#+END_SRC")))
#+end_src

#+results:
: tj/src-block-interpreter

Parse this src-block (with point at beg of block):

,----
| M-: (setq ptree (org-element-at-point))
`----

#+header: :results raw
#+begin_src emacs-lisp
(message "hello world")
#+end_src

#+results:
hello world

Then evaluate

#+begin_src emacs-lisp
(org-element-src-block-interpreter ptree nil)
#+end_src

#+results:
: #+BEGIN_SRC emacs-lisp
:   (message "hello world")
: #+END_SRC

#+begin_src emacs-lisp
(tj/src-block-interpreter ptree nil)
#+end_src

#+results:
: #+HEADER: :results raw
: #+BEGIN_SRC emacs-lisp
:   (message "hello world")
: #+END_SRC


-- 
cheers,
Thorsten

next             reply	other threads:[~2014-08-05 16:18 UTC|newest]

Thread overview: 12+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2014-08-05 16:17 Thorsten Jolitz [this message]
2014-08-06  3:39 ` (Maybe) enhance `org-element-src-block-interpreter'? Aaron Ecay
2014-08-06  8:19   ` Thorsten Jolitz
2014-08-06 11:34     ` Nicolas Goaziou
2014-08-06 12:03       ` Thorsten Jolitz
2014-08-06 12:32         ` Nicolas Goaziou
2014-08-06 13:18           ` Nicolas Goaziou
2014-08-08  8:19             ` Thorsten Jolitz
2014-08-08  8:45               ` Nicolas Goaziou
2014-08-06 14:15           ` Thorsten Jolitz
2014-08-06 14:36             ` Thorsten Jolitz
2014-08-07 12:14             ` Nicolas Goaziou

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

  List information: https://www.orgmode.org/

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=87tx5qvrl4.fsf@gmail.com \
    --to=tjolitz@gmail.com \
    --cc=emacs-orgmode@gnu.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link

Code repositories for project(s) associated with this public inbox

	https://git.savannah.gnu.org/cgit/emacs/org-mode.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).