On Friday, 24 Nov 2017 at 20:37, ma3434tt@openmailbox.org wrote:
> What are good ways of setting up alarms for Deadlines and Scheduling
> in org-mode to integrate with Windows or GNU/Linux environments?

I use the following on Linux and it works very well.  Relies on there
being a notification daemon running (I use dunst as the easiest to
configure).

#+begin_src emacs-lisp
  ;; from Tassilo's blog:
  ;; and from RichardRiley's entry: http://www.emacswiki.org/emacs/OrgMode-OSD
  ;; and from Nick Dokos: http://article.gmane.org/gmane.emacs.orgmode/5271
  (message "ESF-ORG: setting up org->appt link")
  (require 'appt)
  (require 'notifications)
  (defun esf/notification-display (min-to-app new-time msg)
    (let (m delay)
      (setq m (string-to-number min-to-app)
            delay (if (<= m 0) 0 (* 1000 (- 20 m))))
      (notifications-notify :title "Agenda"
                            :body (format "%s\nIn %s minutes." msg min-to-app)
                            :app-name "emacs"
                            :app-icon "PATHTOICONS/emacs-icon.xpm"
                            :timeout delay)))
  (setq appt-display-format 'window)
  (setq appt-disp-window-function (function esf/notification-display))
  (setq appt-delete-window-function '(lambda ()))
  ;; Run once, activate and schedule refresh
  (run-at-time "5 minutes" 3600 'org-agenda-to-appt)
  (appt-activate t)
  (setq appt-time-msg-list nil)
  (defadvice  org-agenda-redo (after org-agenda-redo-add-appts)
    "Pressing `r' on the agenda will also add appointments."
    (progn 
      (setq appt-time-msg-list nil)
      (org-agenda-to-appt)))
  (ad-activate 'org-agenda-redo)
  (message "ESF-ORG: done setting up org->appt link")
#+end_src

-- 
: Eric S Fraga via Emacs 27.0.50, Org release_9.1.3-170-g51234f