emacs-orgmode@gnu.org archives
 help / color / mirror / code / Atom feed

From: "Óscar Fuentes" <ofv@wanadoo.es>
To: emacs-orgmode@gnu.org
Subject: Re: Restricting admisible tags depending on header
Date: Sat, 04 Jun 2016 23:26:46 +0200	[thread overview]
Message-ID: <87eg8cbq7d.fsf@wanadoo.es> (raw)
In-Reply-To: 87inxpbplv.fsf@wanadoo.es

Óscar Fuentes <ofv@wanadoo.es> writes:

> I'll like to offer only certain tags depending on the contents of the
> current header. For instance, if the header is
>
> * Status
>
> I want to see only "open" and "closed" on the options shown by
> org-fast-tag-selection.
>
> Currently I define quite a lot of tags with #+TAGS:, most of them are
> intended to be assigned to a specific header. Having so many tags
> displayed by org-fast-tag-selection is confusing, error-prone and breaks
> the selection method (org-fast-tag-selection runs out of letters).
>
> I'm thinking on advising org-fast-tag-selection and prune the list of
> acceptable tags before calling the real function, but maybe there is a
> better method.

Thanks to all who responded, both off- and on-list.

At the end, I opted for advising org-fast-tag-selection. Now, for a
given heading, a tag group with the same name provides the admisible
tags:

#+TAGS: [ Status : { open closed }  ]
#+TAGS: [ Status : { done(d) postponed cancelled wontfix worksforme invalid } ]
#+TAGS: [ Type : { task defect enhancement feedback test } ]
#+TAGS: [ Severity : { critical major minor cosmetic } ]
#+TAGS: [ Priority : { top high medium low } ]

* Status
* Type
* Severity
* Priority


Code:

(defun ofv-issues-tags-for-heading (h)
  (setq h (org-no-properties h))
  (let (check-name-p collect-tags-p specific-tags)
    (dolist (tag org-tag-alist)
      (cond
       ((eq (car tag) ':endgrouptag)
	(setq collect-tags-p nil))
       ((eq (car tag) ':startgrouptag)
	(setq check-name-p t))
       (collect-tags-p
	(push tag specific-tags))
       (check-name-p
	(setq collect-tags-p (equal (car tag) h))
	(setq check-name-p nil))))
    specific-tags))

(defun ofv-issues-org-fast-tag-selection (args)
  ;; The `table' parameter of `org-fast-tag-selection' contains a
  ;; uniquified list, which removes duplicated group tag names.
  ;; `ofv-issues-tags-for-heading' uses the contents of
  ;; `org-tag-alist'.
  (let ((specific-tags (ofv-issues-tags-for-heading (org-get-heading t t))))
    (when specific-tags
      (setcar (nthcdr 2 args) (nreverse specific-tags))))
  args)

(advice-add 'org-fast-tag-selection :filter-args
	    'ofv-issues-org-fast-tag-selection)

     prev parent reply	other threads:[~2016-06-04 21:27 UTC|newest]

Thread overview: 3+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2016-06-04  3:27 Restricting admisible tags depending on header Óscar Fuentes
2016-06-04 11:31 ` John Kitchin
2016-06-04 21:26 ` Óscar Fuentes [this message]

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

  List information: https://www.orgmode.org/

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=87eg8cbq7d.fsf@wanadoo.es \
    --to=ofv@wanadoo.es \
    --cc=emacs-orgmode@gnu.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link

Code repositories for project(s) associated with this public inbox

	https://git.savannah.gnu.org/cgit/emacs/org-mode.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).