emacs-orgmode@gnu.org archives
 help / color / mirror / code / Atom feed
From: "Eric Schulte" <schulte.eric@gmail.com>
To: Matt Lundin <mdl@imapmail.org>
Cc: Org Mode <emacs-orgmode@gnu.org>
Subject: Re: [PATCH] org-bibtex.el --- convert between Org headings and bibtex entries
Date: Sat, 23 Apr 2011 08:07:06 -0600	[thread overview]
Message-ID: <878vv112ph.fsf@gmail.com> (raw)
In-Reply-To: <87r58tdeaf.fsf@fastmail.fm> (Matt Lundin's message of "Fri, 22 Apr 2011 20:03:52 -0400")

[-- Attachment #1: Type: text/plain, Size: 2057 bytes --]

Matt Lundin <mdl@imapmail.org> writes:

> Matt Lundin <mdl@imapmail.org> writes:
>
>> "Eric Schulte" <schulte.eric@gmail.com> writes:
>>> As one possible solution to this name conflict, I've folded my
>>> org-bibtex.el into the existing org-bibtex.el in the Org-mode core.  The
>>> attached patch performs this integration adding the functionality in my
>>> version of org-bibtex.el into the Org-mode core.
>>>
>>> Does this seem like an appropriate addition?
>>
>> +1 (or maybe +.75 -- see below)
>>
>> I think this could finally tempt me to move all my bibliographical data
>> into org-mode files. (I've been keeping all my data in a central bibtex
>> file and using reftex to generate links to citations.)
>
> I've been testing the patch and have a few comments. 
>
> 1. The prompt for the completing-read on line 440 is missing a space. It
>    shows "Type:" rather than "Type: ".
>

Fixed, Thanks

>
> 2. In addition, since the symbols in org-bibtex-types are keywords, the
>    completions are in the form ":article", ":book", etc. Might I ask why
>    everything is org-bibtex-type is a keyword? Could we use strings or
>    plain symbols instead? (Note: I haven't read the code carefully
>    enough to see if there is a reason.)
>

I tend to prefer keywords for items which are primarily used as keys
(e.g., for alist lookup w/assoc), I like that keywords are only interned
once and are clearly not variables or functions, however you're right
that it may add some extra complexity to this code.

I've changed the code which prompts for fields so that it now strips the
leading ":" from the keyword names, leading to nicer prompts.

>
> 3. The tooltip/help pop-up for org-bibtex-create takes up half a frame.
>

The pop-up buffer with field information should now only be as large as
required for the text (although if you have a vertically split frame the
buffer will not shrink).  It is using the same code used to minimize the
help buffer presented by `org-export'.

>
> Thanks,
> Matt
>

The updated version is contained in the attached patch.

[-- Attachment #2: 0001-org-bibtex-translating-between-Org-mode-headings-and.patch --]
[-- Type: text/x-diff, Size: 20514 bytes --]

From 34f5036409fe77e20c0444ccfcc13cc4be250d92 Mon Sep 17 00:00:00 2001
From: Eric Schulte <schulte.eric@gmail.com>
Date: Sat, 23 Apr 2011 08:05:08 -0600
Subject: [PATCH] org-bibtex: translating between Org-mode headings and Bibtex entries

* lisp/org-bibtex.el: Updating Copyright dates, author information,
  commentary and history notes.
  (org-bibtex-types): List of bibtex types with descriptions and
  required and optional fields.
  (org-bibtex-fields): List of bibtex fields with descriptions.
  (*org-bibtex-entries*): Special variable to hold parsed bibtex
  entries.
  (org-bibtex-autogen-keys): Custom variable controlling whether
  bibtex keys are automatically generated
  (org-bibtex-prefix): Custom variable allowing use of optional prefix
  for bibtex properties in Org-mode headlines.
  (org-bibtex-get): Helper function for accessing bibtex elements of a
  property list.
  (org-bibtex-put): Helper function for inserting bibtex element into
  a property list.
  (org-bibtex-headline): Return a bibtex entry of the given headline
  as a string.
  (org-bibtex-ask): Prompt the user to fill in the value of a bibtex
  field.
  (org-bibtex-autokey): Generate a bibtex key for the current
  headline.
  (org-bibtex-fleshout): Fill in missing bibtex properties of the
  current headline.
  (org-bibtex): Export the current Org-mode buffer to a bibtex buffer.
  (org-bibtex-check): Check that all bibtex properties are present in
  the current headline.
  (org-bibtex-check-all): Check all headlines in the current buffer.
  (org-bibtex-create): Create a new bibtex headline at the current
  level.
  (org-bibtex-read): Read the current bibtex entry from a bibtex file.
  (org-bibtex-write): Write the most recently read bibtex entry into
  an Org-mode file.
---
 lisp/org-bibtex.el |  319 +++++++++++++++++++++++++++++++++++++++++++++++++--
 1 files changed, 306 insertions(+), 13 deletions(-)

diff --git a/lisp/org-bibtex.el b/lisp/org-bibtex.el
index b7b7416..9ee30f1 100644
--- a/lisp/org-bibtex.el
+++ b/lisp/org-bibtex.el
@@ -1,9 +1,10 @@
 ;;; org-bibtex.el --- Org links to BibTeX entries
 ;;
-;; Copyright (C) 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
+;; Copyright (C) 2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
 ;;
 ;; Author: Bastien Guerry <bzg at altern dot org>
 ;;         Carsten Dominik <carsten dot dominik at gmail dot com>
+;;         Eric Schulte <schulte dot eric at gmail dot com>
 ;; Keywords: org, wp, remember
 ;; Version: 7.5
 ;;
@@ -66,12 +67,30 @@
 ;; =====================================================================
 ;; * READ <== [point here]
 ;;
-;; [[file:/file.bib::dolev83][Dolev & Yao 1983: security of public key protocols]]
+;; [[file:file.bib::dolev83][Dolev & Yao 1983: security of public key protocols]]
 ;;
 ;; Danny Dolev and Andrew C. Yao (1983): On the security of public-key protocols
 ;; In IEEE Transaction on Information Theory, 198--208.
 ;; =====================================================================
 ;;
+;; Additionally, the following functions are now available for storing
+;; bibtex entries within Org-mode documents.
+;;
+;; - Run `org-bibtex' to export the current file to a .bib.
+;;
+;; - Run `org-bibtex-check' or `org-bibtex-check-all' to check and
+;;   fill in missing field of either the current, or all headlines
+;;
+;; - Run `org-bibtex-create' to add a bibtex entry
+;;
+;; - Use `org-bibtex-read' to read a bibtex entry after `point' or in
+;;   the active region, then call `org-bibtex-write' in a .org file to
+;;   insert a heading for the read bibtex entry
+;;
+;; - All Bibtex information is taken from the document compiled by
+;;   Andrew Roberts from the Bibtex manual, available at
+;;   http://www.andy-roberts.net/misc/latex/sessions/bibtex/bibentries.pdf
+;;
 ;;; History:
 ;;
 ;; The link creation part has been part of Org-mode for a long time.
@@ -80,12 +99,17 @@
 ;; of Austin Frank: http://article.gmane.org/gmane.emacs.orgmode/4112
 ;; and then implemented by Bastien Guerry.
 ;;
+;; Eric Schulte eventually added the functions for translating between
+;; Org-mode headlines and Bibtex entries, and for fleshing out the Bibtex
+;; fields of existing Org-mode headlines.
+;;
 ;; Org-mode loads this module by default - if this is not what you want,
 ;; configure the variable `org-modules'.
 
 ;;; Code:
 
 (require 'org)
+(require 'bibtex)
 
 (defvar description nil) ; dynamically scoped from org.el
 
@@ -93,21 +117,209 @@
 (declare-function bibtex-generate-autokey "bibtex" ())
 (declare-function bibtex-parse-entry "bibtex" (&optional content))
 (declare-function bibtex-url "bibtex" (&optional pos no-browse))
+(declare-function longlines-mode "longlines" (&optional arg))
+
+\f
+;;; Bibtex data
+(defvar org-bibtex-types
+  '((:article
+     (:description . "An article from a journal or magazine")
+     (:required :author :title :journal :year)
+     (:optional :volume :number :pages :month :note))
+    (:book
+     (:description . "A book with an explicit publisher")
+     (:required (:editor :author) :title :publisher :year)
+     (:optional (:volume :number) :series :address :edition :month :note))
+    (:booklet
+     (:description . "A work that is printed and bound, but without a named publisher or sponsoring institution.")
+     (:required :title)
+     (:optional :author :howpublished :address :month :year :note))
+    (:conference
+     (:description . "")
+     (:required :author :title :booktitle :year)
+     (:optional :editor :pages :organization :publisher :address :month :note))
+    (:inbook
+     (:description . "A part of a book, which may be a chapter (or section or whatever) and/or a range of pages.")
+     (:required (:author :editor) :title (:chapter :pages) :publisher :year)
+     (:optional (:volume :number) :series :type :address :edition :month :note))
+    (:incollection
+     (:description . "A part of a book having its own title.")
+     (:required :author :title :booktitle :publisher :year)
+     (:optional :editor (:volume :number) :series :type :chapter :pages :address :edition :month :note))
+    (:inproceedings
+     (:description . "An article in a conference proceedings")
+     (:required :author :title :booktitle :year)
+     (:optional :editor (:volume :number) :series :pages :address :month :organization :publisher :note))
+    (:manual
+     (:description . "Technical documentation.")
+     (:required :title)
+     (:optional :author :organization :address :edition :month :year :note))
+    (:mastersthesis
+     (:description . "A Master’s thesis.")
+     (:required :author :title :school :year)
+     (:optional :type :address :month :note))
+    (:misc
+     (:description . "Use this type when nothing else fits.")
+     (:required)
+     (:optional :author :title :howpublished :month :year :note))
+    (:phdthesis
+     (:description . "A PhD thesis.")
+     (:required :author :title :school :year)
+     (:optional :type :address :month :note))
+    (:proceedings
+     (:description . "The proceedings of a conference.")
+     (:required :title :year)
+     (:optional :editor (:volume :number) :series :address :month :organization :publisher :note))
+    (:techreport
+     (:description . "A report published by a school or other institution.")
+     (:required :author :title :institution :year)
+     (:optional :type :address :month :note))
+    (:unpublished
+     (:description . "A document having an author and title, but not formally published.")
+     (:required :author :title :note)
+     (:optional :month :year)))
+  "Bibtex entry types with required and optional parameters.")
+
+(defvar org-bibtex-fields
+  '((:address      . "Usually the address of the publisher or other type of institution. For major publishing houses, van Leunen recommends omitting the information entirely.  For small publishers, on the other hand, you can help the reader by giving the complete address.")
+    (:annote       . "An annotation. It is not used by the standard bibliography styles, but may be used by others that produce an annotated bibliography.")
+    (:author       . "The name(s) of the author(s), in the format described in the LaTeX book.  Remember, all names are separated with the and keyword, and not commas.")
+    (:booktitle    . "Title of a book, part of which is being cited. See the LaTeX book for how to type titles. For book entries, use the title field instead.")
+    (:chapter      . "A chapter (or section or whatever) number.")
+    (:crossref     . "The database key of the entry being cross referenced.")
+    (:edition      . "The edition of a book for example, 'Second'. This should be an ordinal, and should have the first letter capitalized, as shown here; the standard styles convert to lower case when necessary.")
+    (:editor       . "Name(s) of editor(s), typed as indicated in the LaTeX book. If there is also an author field, then the editor field gives the editor of the book or collection in which the reference appears.")
+    (:howpublished . "How something strange has been published. The first word should be capitalized.")
+    (:institution  . "The sponsoring institution of a technical report.")
+    (:journal      . "A journal name.")
+    (:key          . "Used for alphabetizing, cross-referencing, and creating a label when the author information is missing. This field should not be confused with the key that appears in the \cite command and at the beginning of the database entry.")
+    (:month        . "The month in which the work was published or, for an unpublished work, in which it was written. You should use the standard three-letter abbreviation,")
+    (:note         . "Any additional information that can help the reader. The first word should be capitalized.")
+    (:number       . "Any additional information that can help the reader. The first word should be capitalized.")
+    (:organization . "The organization that sponsors a conference or that publishes a manual.")
+    (:pages        . "One or more page numbers or range of numbers, such as 42-111 or 7,41,73-97 or 43+ (the ‘+’ in this last example indicates pages following that don’t form simple range). BibTEX requires double dashes for page ranges (--).")
+    (:publisher    . "The publisher’s name.")
+    (:school       . "The name of the school where a thesis was written.")
+    (:series       . "The name of a series or set of books. When citing an entire book, the the title field gives its title and an optional series field gives the name of a series or multi-volume set in which the book is published.")
+    (:title        . "The work’s title, typed as explained in the LaTeX book.")
+    (:type         . "The type of a technical report for example, 'Research Note'.")
+    (:volume       . "The volume of a journal or multi-volume book.")
+    (:year         . "The year of publication or, for an unpublished work, the year it was written.  Generally it should consist of four numerals, such as 1984, although the standard styles can handle any year whose last four nonpunctuation characters are numerals, such as '(about 1984)'"))
+  "Bibtex fields with descriptions.")
+
+(defvar *org-bibtex-entries* nil
+  "List to hold parsed bibtex entries.")
+
+(defcustom org-bibtex-autogen-keys nil
+  "Set to a truthy value to use `bibtex-generate-autokey' to generate keys."
+  :group 'org-bibtex
+  :type  'boolean)
+
+(defcustom org-bibtex-prefix nil
+  "Optional prefix for all bibtex property names.
+For example setting to 'BIB_' would allow interoperability with fireforg."
+  :group 'org-bibtex
+  :type  'string)
+
+\f
+;;; Utility functions
+(defun org-bibtex-get (property)
+  (or (org-entry-get (point) (upcase property))
+      (org-entry-get (point) (concat org-bibtex-prefix (upcase property)))))
 
+(defun org-bibtex-put (property value)
+  (let ((prop (upcase (if (keywordp property)
+                          (substring (symbol-name property) 1)
+                        property))))
+    (org-set-property
+     (concat (unless (string= "CUSTOM_ID" prop) org-bibtex-prefix) prop)
+     value)))
+
+(defun org-bibtex-headline ()
+  "Return a bibtex entry of the given headline as a string."
+  (flet ((get (key lst) (cdr (assoc key lst)))
+         (to-k (string) (intern (concat ":" string)))
+         (from-k (key) (substring (symbol-name key) 1))
+         (flatten (&rest lsts)
+                  (apply #'append (mapcar
+                                   (lambda (e)
+                                     (if (listp e) (apply #'flatten e) (list e)))
+                                   lsts))))
+    (let ((notes (buffer-string))
+          (id (org-bibtex-get "custom_id"))
+          (type (org-bibtex-get "type")))
+      (when type
+        (let ((entry (format
+                      "@%s{%s,\n%s\n}\n" type id
+                      (mapconcat
+                       (lambda (pair) (format "  %s={%s}" (car pair) (cdr pair)))
+                       (remove nil
+			 (mapcar
+			  (lambda (field)
+			    (let ((value (or (org-bibtex-get (from-k field))
+					     (and (equal :title field)
+						  (org-get-heading)))))
+			      (when value (cons (from-k field) value))))
+			  (flatten
+			   (get :required (get (to-k type) org-bibtex-types))
+			   (get :optional (get (to-k type) org-bibtex-types)))))
+                       ",\n"))))
+          (with-temp-buffer
+            (insert entry)
+            (bibtex-reformat) (buffer-string)))))))
+
+(defun org-bibtex-ask (field)
+  (unless (assoc field org-bibtex-fields)
+    (error "field:%s is not known" field))
+  (save-window-excursion
+    (let* ((name (substring (symbol-name field) 1))
+	   (buf-name (format "*Bibtex Help %s*" name)))
+      (with-output-to-temp-buffer buf-name
+	(princ (cdr (assoc field org-bibtex-fields))))
+      (with-current-buffer buf-name (longlines-mode t))
+      (org-fit-window-to-buffer (get-buffer-window buf-name))
+      ((lambda (result) (when (> (length result) 0) result))
+       (read-from-minibuffer (format "%s: " name))))))
+
+(defun org-bibtex-autokey ()
+  "Generate an autokey for the current headline"
+  (org-bibtex-put "CUSTOM_ID"
+                  (if org-bibtex-autogen-keys
+                      (let ((entry (org-bibtex-headline)))
+                        (with-temp-buffer
+                          (insert entry)
+                          (bibtex-generate-autokey)))
+                    (read-from-minibuffer "id: "))))
+
+(defun org-bibtex-fleshout (type &optional optional)
+  "Fleshout the current heading, ensuring that all required fields are present.
+With optional argument OPTIONAL, also prompt for optional fields."
+  (flet ((get (key lst) (cdr (assoc key lst)))
+	 (keyword (name) (intern (concat ":" (downcase name))))
+         (name (keyword) (upcase (substring (symbol-name keyword) 1))))
+    (dolist (field (append
+		    (remove :title (get :required (get type org-bibtex-types)))
+		    (when optional (get :optional (get type org-bibtex-types)))))
+      (when (consp field) ; or'd pair of fields e.g., (:editor :author)
+        (let ((present (first (remove nil
+                                (mapcar
+                                 (lambda (f) (when (org-bibtex-get (name f)) f))
+                                 field)))))
+          (setf field (or present (keyword (org-icompleting-read
+					    "Field: " (mapcar #'name field)))))))
+      (let ((name (name field)))
+        (unless (org-bibtex-get name)
+          (let ((prop (org-bibtex-ask field)))
+            (when prop (org-bibtex-put name prop)))))))
+  (when (and type (assoc type org-bibtex-types)
+             (not (org-bibtex-get "CUSTOM_ID")))
+    (org-bibtex-autokey)))
+
+\f
+;;; Bibtex link functions
 (org-add-link-type "bibtex" 'org-bibtex-open)
 (add-hook 'org-store-link-functions 'org-bibtex-store-link)
 
-;; (defun org-bibtex-publish (path)
-;;   "Build the description of the BibTeX entry for publishing."
-;;   (let* ((search (when (string-match "::\\(.+\\)\\'" path)
-;; 		   (match-string 1 path)))
-;; 	 (path (substring path 0 (match-beginning 0)))
-;; 	 key)
-;;     (with-temp-buffer
-;;       (org-open-file path t nil search)
-;;       (setq key (org-create-file-search-functions)))
-;;     (or description key)))
-
 (defun org-bibtex-open (path)
   "Visit the bibliography entry on PATH."
   (let* ((search (when (string-match "::\\(.+\\)\\'" path)
@@ -198,6 +410,87 @@
 ;; Finally add the link search function to the right hook.
 (add-hook 'org-execute-file-search-functions 'org-execute-file-search-in-bibtex)
 
+\f
+;;; Bibtex <-> Org-mode headline translation functions
+(defun org-bibtex ()
+  "Export each headline in the current file to a bibtex entry.
+Headlines are exported using `org-bibtex-export-headline'."
+  (interactive)
+  (let ((bibtex-entries (remove nil (org-map-entries #'org-bibtex-headline))))
+    (with-temp-file (concat (file-name-sans-extension (buffer-file-name)) ".bib")
+      (insert (mapconcat #'identity bibtex-entries "\n")))))
+
+(defun org-bibtex-check (&optional optional)
+  "Check the current headline for required fields.
+With prefix argument OPTIONAL also prompt for optional fields."
+  (interactive "P")
+  (save-restriction
+    (org-narrow-to-subtree)
+    (let ((type ((lambda (name) (when name (intern (concat ":" name))))
+                 (org-bibtex-get "TYPE"))))
+      (when type (org-bibtex-fleshout type optional)))))
+
+(defun org-bibtex-check-all (&optional optional)
+  "Check all headlines in the current file.
+With prefix argument OPTIONAL also prompt for optional fields."
+  (interactive) (org-map-entries (lambda () (org-bibtex-check optional))))
+
+(defun org-bibtex-create (type)
+  "Create a new entry at the given level."
+  (interactive
+   (list (org-icompleting-read
+          "Type: "
+	  (mapcar (lambda (type) (symbol-name (car type))) org-bibtex-types))))
+  (let ((type (if (keywordp type) type (intern type))))
+    (unless (assoc type org-bibtex-types)
+      (error "type:%s is not known" type))
+    (org-insert-heading)
+    (let ((title (org-bibtex-ask :title)))
+      (insert title) (org-bibtex-put "TITLE" title))
+    (org-bibtex-put "TYPE" (substring (symbol-name type) 1))
+    (org-bibtex-fleshout type)))
+
+(defun org-bibtex-read ()
+  "Read a bibtex entry and save to `*org-bibtex-entries*'.
+This uses `bibtex-parse-entry'."
+  (interactive)
+  (flet ((keyword (str) (intern (concat ":" (downcase str))))
+         (clean-space (str) (replace-regexp-in-string
+                             "[[:space:]\n\r]+" " " str))
+         (strip-delim (str)	     ; strip enclosing "..." and {...}
+		      (dolist (pair '((34 . 34) (123 . 125)))
+			(when (and (= (aref str 0) (car pair))
+				   (= (aref str (1- (length str))) (cdr pair)))
+			  (setf str (subseq str 1 (1- (length str)))))) str))
+    (push (mapcar
+           (lambda (pair)
+             (cons (let ((field (keyword (car pair))))
+                     (case field
+                       (:=type= :type)
+                       (:=key= :key)
+                       (otherwise field)))
+                   (clean-space (strip-delim (cdr pair)))))
+           (save-excursion (bibtex-beginning-of-entry) (bibtex-parse-entry)))
+          *org-bibtex-entries*)))
+
+(defun org-bibtex-write ()
+  "Insert a heading built from the first element of `*org-bibtex-entries*'."
+  (interactive)
+  (when (= (length *org-bibtex-entries*) 0)
+    (error "No entries in `*org-bibtex-entries*'."))
+  (let ((entry (pop *org-bibtex-entries*)))
+    (flet ((get (field) (cdr (assoc field entry))))
+      (org-insert-heading)
+      (insert (get :title))
+      (org-bibtex-put "TITLE" (get :title))
+      (org-bibtex-put "TYPE"  (downcase (get :type)))
+      (dolist (pair entry)
+        (case (car pair)
+          (:title    nil)
+          (:type     nil)
+          (:key      (org-bibtex-put "CUSTOM_ID" (cdr pair)))
+          (otherwise (org-bibtex-put (car pair)  (cdr pair))))))))
+
 (provide 'org-bibtex)
 
 ;; arch-tag: 83987d5a-01b8-41c7-85bc-77700f1285f5
-- 
1.7.1


[-- Attachment #3: Type: text/plain, Size: 266 bytes --]


Thanks for your feedback.  I hope to hear from Carsten or Bastien (the
authors of the current org-bibtex) about whether this is the right place
for this functionality or if it should live somewhere else.

Best -- Eric

-- 
Eric Schulte
http://cs.unm.edu/~eschulte/

  reply	other threads:[~2011-04-23 14:07 UTC|newest]

Thread overview: 33+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2011-04-19 23:52 [ANN] org-bibtex.el --- convert between Org headings and bibtex entries Eric Schulte
2011-04-20  1:01 ` Jeff Horn
2011-04-20  1:13   ` Eric Schulte
2011-04-20  7:54 ` Thomas S. Dye
2011-04-20 13:25   ` Matt Lundin
2011-04-20 14:29     ` Matt Lundin
2011-04-20 19:59     ` Eric Schulte
2011-04-20 19:00   ` Eric Schulte
2011-04-21 16:36     ` Thomas S. Dye
2011-04-21 21:06       ` Eric Schulte
2011-04-23 16:23         ` Thomas S. Dye
2011-04-23 22:59           ` Alan E. Davis
2011-04-24  0:40             ` Matt Lundin
2011-04-24 14:21               ` Eric Schulte
2011-04-24 16:53                 ` Christian Moe
2011-04-25 13:19                   ` Matt Lundin
2011-04-25 13:34                     ` Eric Schulte
2011-04-25 15:15                 ` Matt Lundin
2011-04-27 22:16                   ` Eric Schulte
2011-04-24  0:52             ` Eric Schulte
2011-04-24  4:49               ` Alan E. Davis
2011-04-24 14:29                 ` Eric Schulte
2011-04-24 20:40                   ` Alan E. Davis
2011-04-25 13:31                     ` Eric Schulte
2011-04-20  9:26 ` Christian Moe
2011-04-20 20:15   ` Eric Schulte
2011-04-20 12:10 ` Matt Lundin
2011-04-20 20:16   ` Eric Schulte
2011-04-22 14:05   ` [PATCH] " Eric Schulte
2011-04-22 15:45     ` Matt Lundin
2011-04-23  0:03       ` Matt Lundin
2011-04-23 14:07         ` Eric Schulte [this message]
2011-04-23 22:46           ` Matt Lundin

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

  List information: https://www.orgmode.org/

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=878vv112ph.fsf@gmail.com \
    --to=schulte.eric@gmail.com \
    --cc=emacs-orgmode@gnu.org \
    --cc=mdl@imapmail.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line before the message body.
Code repositories for project(s) associated with this public inbox

	https://git.savannah.gnu.org/cgit/emacs/org-mode.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).