From: Adam Porter <adam@alphapapa.net>
To: emacs-orgmode@gnu.org
Subject: New org-count-words function
Date: Tue, 12 Jun 2018 14:58:00 -0500 [thread overview]
Message-ID: <87602nrd4n.fsf@alphapapa.net> (raw)
Hi friends,
Here's a new function that counts lines, words, and characters in the
region or the subtree at point. It prints a message like `count-words`
does, like:
Subtree "Heading" has 7 line, 5 words, and 28 characters.
Note that it does *not* count words in heading lines, planning lines,
and drawers, so it gives a more useful count for the "prose" in the
subtree.
Here's the code:
#+BEGIN_SRC elisp
(defun ap/org-count-words ()
"If region is active, count words in it; otherwise count words in current subtree."
(interactive)
(if (use-region-p)
(funcall-interactively #'count-words-region (region-beginning) (region-end))
(org-with-wide-buffer
(cl-loop for (lines words characters)
in (org-map-entries
(lambda ()
(ap/org-forward-to-entry-content 'unsafe)
(let ((end (org-entry-end-position)))
(list (count-lines (point) end)
(count-words (point) end)
(- end (point)))))
nil 'tree)
sum lines into total-lines
sum words into total-words
sum characters into total-characters
finally do (message "Subtree \"%s\" has %s lines, %s words, and %s characters."
(org-get-heading t t)
total-lines total-words
total-characters)))))
#+END_SRC
It requires this supporting function:
#+BEGIN_SRC elisp
(defun ap/org-forward-to-entry-content (&optional unsafe)
"Skip headline, planning line, and all drawers in current entry.
If UNSAFE is non-nil, assume point is on headline."
(unless unsafe
;; To improve performance in loops (e.g. with `org-map-entries')
(org-back-to-heading))
(cl-loop for element = (org-element-at-point)
for pos = (pcase element
(`(headline . ,_)
(org-element-property :contents-begin element))
(`(,(or 'planning 'property-drawer 'drawer) . ,_)
(org-element-property :end element)))
while pos
do (goto-char pos)))
#+END_SRC
I think it's an improvement over the functions I've seen that do this.
Hope someone finds it useful.
next reply other threads:[~2018-06-12 19:58 UTC|newest]
Thread overview: 2+ messages / expand[flat|nested] mbox.gz Atom feed top
2018-06-12 19:58 Adam Porter [this message]
2018-06-15 16:13 ` New org-count-words function Grant Rettke
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
List information: https://www.orgmode.org/
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=87602nrd4n.fsf@alphapapa.net \
--to=adam@alphapapa.net \
--cc=emacs-orgmode@gnu.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.savannah.gnu.org/cgit/emacs/org-mode.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).