emacs-orgmode@gnu.org archives
 help / color / mirror / code / Atom feed
* A much simpler way of handling dependent tasks
@ 2009-01-26 21:16 John Wiegley
  2009-01-26 23:48 ` Oliver Charles
                   ` (4 more replies)
  0 siblings, 5 replies; 12+ messages in thread
From: John Wiegley @ 2009-01-26 21:16 UTC (permalink / raw)
  To: Carsten Dominik; +Cc: emacs-orgmode Org-Mode

[-- Attachment #1: Type: text/plain, Size: 553 bytes --]

I've been wanting a simple method for managing dependent tasks for  
some time now, and only now did it occur to me that I could just  
implement a much simpler method using your current blocking mechanism.

The attached file, confusingly named org-depends.el, implements the  
following scheme:

  1. Any TODO which has incomplete child TODOs is blocked.

  2. If a parent TODO has the ORDERED property, it's children must be
     completed in order.  Undone siblings block later siblings.

  3. Blocked items are greyed out in the agenda list.

John


[-- Attachment #2: org-depends.el --]
[-- Type: application/octet-stream, Size: 4353 bytes --]

;;; org-depends.el --- Hierarchical TODO dependencies for Org-mode
;; Copyright (C) 2008 Free Software Foundation, Inc.
;;
;; Author: John Wiegley <johnw at newartisans dot com>
;; Keywords: outlines, hypermedia, calendar, wp
;; Homepage: http://www.newartisans.com/
;; Version: 0.01
;;
;; This file is not part of GNU Emacs.
;;
;; This file is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 3, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;;; Commentary:
;;

(require 'org)

(defun org-depends-block-todo (change-plist)
  "Block turning an entry into a TODO.
This checks whether the current task should be blocked from state
changes.  Such blocking occurs when:

  1. The task has children which are not all in a completed state.

  2. A task has a parent with the property :ORDERED:, and there
     are siblings prior to the current task with incomplete
     status."
  (catch 'dont-block
    ;; If this task has children, and any are undone, it's blocked
    (save-excursion
      (outline-back-to-heading)
      (let ((this-level (funcall outline-level)))
	(outline-next-heading)
	(let ((child-level (funcall outline-level)))
	  (while (and (not (eobp))
		      (> child-level this-level))
	    ;; this todo has children, check whether they are all
	    ;; completed
	    (if (and (not (org-entry-is-done-p))
		     (org-entry-is-todo-p))
		(throw 'dont-block nil))
	    (outline-next-heading)
	    (setq child-level (funcall outline-level))))))
    ;; Otherwise, if the task's parent has the :ORDERED: property, and
    ;; any previous siblings are undone, it's blocked
    (save-excursion
      (outline-back-to-heading)
      (when (save-excursion
	      (outline-up-heading 1)
	      (org-entry-get (point) "ORDERED"))
	(let* ((this-level (funcall outline-level))
	       (current-level this-level))
	  (while (and (not (bobp))
		      (= current-level this-level))
	    (outline-previous-heading)
	    (setq current-level (funcall outline-level))
	    (if (= current-level this-level)
		;; this todo has children, check whether they are all
		;; completed
		(if (and (not (org-entry-is-done-p))
			 (org-entry-is-todo-p))
		    (throw 'dont-block nil)))))))
    t))					; don't block

(add-hook 'org-blocker-hook 'org-depends-block-todo)

(defface org-depends-dimmed-todo-face
  '((((background light)) (:foreground "grey50"))
    (((background dark)) (:foreground "grey50")))
  "Face used to hide leading stars in headlines.
The foreground color of this face should be equal to the background
color of the frame."
  :group 'org-depends)

(defun org-depends-dim-blocked-todos ()
  "Dim currently blocked TODO's in the agenda display."
  (interactive)
  (mapc (lambda (o) (if (eq (org-overlay-get o 'org-type) 'org-blocked-todo)
		   (org-delete-overlay o)))
	(org-overlays-in (point-min) (point-max)))
  (save-excursion
    (let ((inhibit-read-only t)
	  b e p ov h l)
      (goto-char (point-min))
      (while (let ((pos (next-single-property-change (point) 'todo-state)))
	       (and pos (goto-char (1+ pos))))
	(let ((marker (get-text-property (point) 'org-hd-marker)))
	  (when (and marker
		     (not (with-current-buffer (marker-buffer marker)
			    (save-excursion
			      (goto-char marker)
			      (org-depends-block-todo (list :type 'todo-state-change
							   :position marker
							   :from "TODO"
							   :to "DONE"))))))
	    (setq b (point) e (point-at-eol)
		  ov (org-make-overlay b e))
	    (org-overlay-put ov 'face 'org-depends-dimmed-todo-face)
	    (org-overlay-put ov 'org-type 'org-blocked-todo)))))))

(add-hook 'org-finalize-agenda-hook 'org-depends-dim-blocked-todos)

(provide 'org-depends)

;;; org-depends.el ends here

[-- Attachment #3: Type: text/plain, Size: 1 bytes --]



[-- Attachment #4: Type: text/plain, Size: 204 bytes --]

_______________________________________________
Emacs-orgmode mailing list
Remember: use `Reply All' to send replies to the list.
Emacs-orgmode@gnu.org
http://lists.gnu.org/mailman/listinfo/emacs-orgmode

^ permalink raw reply	[flat|nested] 12+ messages in thread

end of thread, other threads:[~2009-01-30 20:07 UTC | newest]

Thread overview: 12+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2009-01-26 21:16 A much simpler way of handling dependent tasks John Wiegley
2009-01-26 23:48 ` Oliver Charles
2009-01-27  1:18   ` Jesse Alama
2009-01-27  6:46     ` Carsten Dominik
2009-01-27  6:47 ` John Wiegley
2009-01-27  6:47 ` Carsten Dominik
2009-01-27  7:31   ` John Wiegley
2009-01-27  7:43     ` Carsten Dominik
2009-01-27 22:51 ` Mike Newman
2009-01-30 15:02 ` Rainer Stengele
2009-01-30 17:37   ` Carsten Dominik
2009-01-30 20:07     ` John Wiegley

Code repositories for project(s) associated with this public inbox

	https://git.savannah.gnu.org/cgit/emacs/org-mode.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).