Re: A puzzle to solve: saved categories vs. tags

From: Carsten Dominik <dominik@science.uva.nl>
To: Bastien <bzg@altern.org>
Cc: org-mode list <emacs-orgmode@gnu.org>
Subject: Re: A puzzle to solve: saved categories vs. tags
Date: Mon, 8 Oct 2007 13:48:18 +0200	[thread overview]
Message-ID: <4d056197e283a9e8c04025b4ad022c2e@science.uva.nl> (raw)
In-Reply-To: <87tzp14w7h.fsf@bzg.ath.cx>

[-- Attachment #1: Type: text/plain, Size: 397 bytes --]

On Oct 8, 2007, at 14:39, Bastien wrote:

> Carsten Dominik <dominik@science.uva.nl> writes:
>
>> Arrrgh!
>>
>> make that (org-buffer-property-keys t) for now, bug fix in next
>> release.
>
> This patch is also needed:

Indeed, thanks a lot.  So to make this simpler, here is
the modified version that should work out of the box.
Sorry once again for the mess and the bandwidth waste.

- Carsten

[-- Attachment #2: org-sparse-tree-interactive.el --]
[-- Type: application/octet-stream, Size: 1615 bytes --]

(defun org-sparse-tree (&optional arg)
  "Create a sparse tree, prompt for the details.
This command can create sparse trees.  You first need to select the type
of match used to create the tree:

t      Show entries with a specific TODO keyword.
T      Show entries selected by a tags match.
p      Enter a property name and its value (both with completion on existing
       names/values) and show entries with that property.
r      Show entries matching a regular expression"
  (interactive "P")
  (let (ans kwd value)
    (message "Sparse tree: [r]egexp   [t]odo-kwd   [T]ag   [p]roperty")
    (setq ans (read-char-exclusive))
    (cond
     ((equal ans ?t)
      (org-show-todo-tree '(4)))
     ((equal ans ?T)
      (call-interactively 'org-tags-sparse-tree))
     ((member ans '(?p ?P))
      (setq kwd (completing-read "Property: " 
				 (mapcar 'list (org-buffer-property-keys))))
      (setq value (completing-read "Value: "
				   (mapcar 'list (org-property-values kwd))))
      (unless (string-match "\\`{.*}\\'" value)
	(setq value (concat "\"" value "\"")))
      (org-tags-sparse-tree arg (concat kwd "=" value)))
     ((member ans '(?r ?R))
      (call-interactively 'org-occur))
     (t (error "No such sparse tree command \"%c\"" ans)))))

(defun org-property-values (key)
  "Return a list of all values of property KEY."
  (save-excursion
    (save-restriction
      (widen)
      (goto-char (point-min))
      (let ((re (concat "^[ \t]*:" key ":[ \t]*\\(\\S-.*\\)"))
	    values)
	(while (re-search-forward re nil t)
	  (add-to-list 'values (org-trim (match-string 1))))
	(delete "" values)))))

[-- Attachment #3: Type: text/plain, Size: 204 bytes --]

_______________________________________________
Emacs-orgmode mailing list
Remember: use `Reply All' to send replies to the list.
Emacs-orgmode@gnu.org
http://lists.gnu.org/mailman/listinfo/emacs-orgmode