Re: graphing from org-tables

From: "Eric Schulte" <schulte.eric@gmail.com>
To: James TD Smith <ahktenzero@mohorovi.cc>
Cc: Org-mode <emacs-orgmode@gnu.org>
Subject: Re: graphing from org-tables
Date: Fri, 25 Jul 2008 12:07:00 -0700	[thread overview]
Message-ID: <488a2450.1e078e0a.2bc0.181f@mx.google.com> (raw)
In-Reply-To: <20080725162527.GA54528@yog-sothoth.mohorovi.cc>

I had some time waiting for things to execute, so I condensed your
process into a single command (borrowing heavily from
org-export-table).

(defun org-table/gnuplot (&optional x-col)
  "Plot the current table using gnuplot.  Use a prefix argument
to specify a column to use for the x-coordinates, to use the row
number for the x-coordinates provide a prefix argument of 0."
  (interactive "p")
  (message (format "%S" x-col))
  (unless (org-at-table-p)
    (error "No table at point"))
  (require 'org-exp)
  (require 'gnuplot)
  (org-table-align) ;; make sure we have everything we need
  (let* ((beg (org-table-begin))
	 (end (org-table-end))
	 (cols (save-excursion
		 (goto-char end)
		 (backward-char 3)
		 (org-table-current-column)))
	 (data-beg (if (and 
			(goto-char beg)
			(re-search-forward org-table-dataline-regexp end t)
			(re-search-forward org-table-hline-regexp end t)
			(re-search-forward org-table-dataline-regexp end t))
		       (match-beginning 0)
		     beg))
	 (skip (- (line-number-at-pos data-beg) (line-number-at-pos beg)))
	 (exp-format (format "orgtbl-to-tsv :skip %d" skip))
	 (file (make-temp-file "org-table-plot")))
    ;; export table
    (org-table-export file exp-format)
    (with-temp-buffer
      ;; write script
      (insert (org-table/gnuplot-script file x-col cols))
      ;; graph table
      (gnuplot-mode)
      (gnuplot-send-buffer-to-gnuplot)
      (bury-buffer (get-buffer "*gnuplot*")))
    (delete-file file)))

(defun org-table/gnuplot-script (file x-col num-cols)
  (let ((plot-str "'%s' using %s:%d with lines title '%d'");; "\\\n    ,"
	script)
    (dotimes (col (+ 1 num-cols))
      (unless (or (and x-col (equal col x-col)) (equal col 0))
	(setf script (cons (format plot-str file (or (and x-col (format "%d" x-col)) "") col col) script))))
    (concat "plot " (mapconcat 'identity (reverse script) "\\\n    ,"))))

On Friday, July 25, at 17:25, James TD Smith wrote:
 > On 2008-07-25 08:53:31(-0700), Eric Schulte wrote:
 > > 
 > > Any advice for quick graphing of a table in org-mode?
 > > 
 > 
 > I have a setup for plotting data from tables. I'm not sure if it's exactly what
 > you want, but yoy may find it useful.
 > 
 > 1. Add the following to your .emacs:
 > 
 > (defun ahkt-plot-table (script)
 >   "util function to export and plot a table using the supplied
 > gnuplot `script'"
 >   (org-table-export)
 >   (let ((cbuf (current-buffer))
 > 	(cwin (selected-window)))
 >     (save-restriction
 >       (save-excursion
 > 	(find-file script)
 > 	(gnuplot-send-buffer-to-gnuplot)
 > 	(bury-buffer)
 > 	(bury-buffer (get-buffer "*gnuplot*"))))
 >     (and (window-live-p cwin) (select-window cwin))
 >     (switch-to-buffer cbuf)
 >     (delete-other-windows)))
 > 
 > 2. Create a gnuplot script which plots data from a file.
 > 
 > 3. Add the following properties to the headline containing the table.
 > TABLE_EXPORT_FILE <filename in the gnuploy script>
 > TABLE_EXPORT_FORMAT orgtbl-to-generic :skip 4 :splice t :sep "\t"
 > 
 > 4. Add an org link in the table (it must be in the table otherwise the export
 > doesn't work) as below:
 > [[elisp:(ahkt-plot-table "<gnuplot script>")][plot table]] 
 > 
 > I suggest you put it at the top of the table.
 > You will then need to adjust the 'skip' parameter in the export format depending
 > on the number of lines at the top of the table which should not be exported
 > (hlines, more than one plotting link etc). 
 > 
 > 5. You should then be able to open the link, and get a plot of the table
 > contents.
 > 
 > 
 > --
 > |-<James TD Smith>-<email/ahktenzero@mohorovi.cc>-|
 > 
 > 
 > _______________________________________________
 > Emacs-orgmode mailing list
 > Remember: use `Reply All' to send replies to the list.
 > Emacs-orgmode@gnu.org
 > http://lists.gnu.org/mailman/listinfo/emacs-orgmode

-- 
schulte