;;; ob-ditaa.el --- org-babel functions for ditaa evaluation

;; Copyright (C) 2009-2011  Free Software Foundation, Inc.

;; Author: Eric Schulte
;; Keywords: literate programming, reproducible research
;; Homepage: http://orgmode.org

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; Org-Babel support for evaluating ditaa source code.
;;
;; This differs from most standard languages in that
;;
;; 1) there is no such thing as a "session" in ditaa
;;
;; 2) we are generally only going to return results of type "file"
;;
;; 3) we are adding the "file" and "cmdline" header arguments
;;
;; 4) there are no variables (at least for now)

;;; Code:
(require 'ob)

(defvar org-babel-default-header-args:ditaa
  '((:results . "file") (:exports . "results") (:java . "-Dfile.encoding=UTF-8"))
  "Default arguments for evaluating a ditaa source block.")

;;; Not having delete-if-not from cl package is rather annoying,
;;; but, alright, we'll do it live.
(defun org-ditaa-delete-if-not (pred seq)
  "Destructively remove all elements of SEQ that do not satisfy predicat PRED"
  (dolist (elt seq seq)
    (when (not (apply pred (list elt)))
      (setq seq (delete elt seq)))))

(defun org-ditaa-try-find-file-in (dir filename)
  "Traverse directory tree supplied in DIR and search for FILENAME.
Return full path to FILENAME if found."
  (let ((candidate-file (expand-file-name filename dir)))
    (cond ((file-exists-p candidate-file)
	   candidate-file)
	  ((file-directory-p dir)
	   (do ((path-to-file nil)
		;; List of sub-directories with . , .. and all
		;; items that are not directories filtered out
		(subdir-list
		 (org-ditaa-delete-if-not
		  (lambda (e) (file-directory-p
			  (file-name-as-directory
			   (expand-file-name e dir))))
		  (delete
		   ".."
		   (delete
		    "."
		    ;;  Access to some directories might result in
		    ;;  "Permission denied" file error. Wrap the call
		    ;;  in condition-case to avoid that
		    (condition-case ex
			(directory-files dir)
		      ('file-error)))))
		 (setq subdir-list (cdr subdir-list))))
	       ((or (not subdir-list)
		    path-to-file) path-to-file)
	     (when subdir-list
	       (let ((subdir (file-name-as-directory
			      (expand-file-name (car subdir-list) dir))))
		 (setq path-to-file (when (and subdir
					       (file-directory-p subdir))
				      (org-ditaa-try-find-file-in subdir filename)))))))
	  (t
	   nil))))

;;; When looking for ditaa.jar go through predefined list of most
;;; likely places to have it, then if else fails try to find it
;;; somwhere in /usr/share or /usr/lib
(defvar org-ditaa-jar-path
  (let* ((potential-path-list
	  (list "/usr/share/ditaa/ditaa.jar" ; Ubuntu 10.10 installed via apt-get
		(expand-file-name            ; Bundled with emacs
		 "ditaa.jar"
		 (file-name-as-directory
		  (expand-file-name
		   "scripts"
		   (file-name-as-directory
		    (expand-file-name
		     "../contrib"
		     (file-name-directory (or load-file-name
					      buffer-file-name)))))))))
	 (actual-path (car potential-path-list)))
    (while (and actual-path
		(not (file-exists-p actual-path)))
      (setq potential-path-list (cdr potential-path-list))
      (setq actual-path (car potential-path-list)))
    (when (not actual-path)
      (setq actual-path (or (org-ditaa-try-find-file-in "/usr/share" "ditaa.jar")
			    (org-ditaa-try-find-file-in "/usr/lib" "ditaa.jar"))))
    actual-path))

(defun org-babel-execute:ditaa (body params)
  "Execute a block of Ditaa code with org-babel.
This function is called by `org-babel-execute-src-block'."
  (let* ((result-params (split-string (or (cdr (assoc :results params)) "")))
	 (out-file ((lambda (el)
		      (or el
			  (error
			   "ditaa code block requires :file header argument")))
		    (cdr (assoc :file params))))
	 (cmdline (cdr (assoc :cmdline params)))
	 (java (cdr (assoc :java params)))
	 (in-file (org-babel-temp-file "ditaa-"))
	 (cmd (concat "java " java " -jar "
		      (shell-quote-argument
		       (expand-file-name org-ditaa-jar-path))
		      " " cmdline
		      " " (org-babel-process-file-name in-file)
		      " " (org-babel-process-file-name out-file))))
    (unless (file-exists-p org-ditaa-jar-path)
      (error "Could not find ditaa.jar at %s" org-ditaa-jar-path))
    (with-temp-file in-file (insert body))
    (message cmd) (shell-command cmd)
    nil)) ;; signal that output has already been written to file

(defun org-babel-prep-session:ditaa (session params)
  "Return an error because ditaa does not support sessions."
  (error "Ditaa does not support sessions"))

(provide 'ob-ditaa)



;;; ob-ditaa.el ends here