emacs-orgmode@gnu.org archives
 help / color / mirror / code / Atom feed
* [PROPOSAL] New function `org-headings-to-point' and displayer.
@ 2019-12-03  2:56 Karl Fogel
  2019-12-03  7:30 ` Diego Zamboni
                   ` (2 more replies)
  0 siblings, 3 replies; 12+ messages in thread
From: Karl Fogel @ 2019-12-03  2:56 UTC (permalink / raw)
  To: Org-mode

Hi.  I've been using this for a while and find it very handy.

If people like this and want it in Org Mode, I'll do the rest of the work to package it up as a patch, with ChangeLog entry, NEWS, etc, and post it here for review before committing.

To try it out, just evaluate both functions and then run

  `M-x org-display-headings-to-point'

from somewhere deep in an org subtree.  Comments/feedback welcome.

Best regards,
-Karl

(defun org-headings-to-point ()
  "Return all the Org Mode headings leading to point."
  (when (not (eq major-mode 'org-mode))
    (error "ERROR: this only works in Org Mode"))
  (let ((headings (list (org-heading-components))))
    (save-excursion
      (save-match-data
        (save-restriction
          (widen)
          (while (org-up-heading-safe)
            (setq headings (cons (org-heading-components) headings)))))
      headings)))

(defun org-display-headings-to-point ()
  "Display Org Mode heading titles from level 1 to current subtree.
Display each title on its own line, indented proportionally to its level."
  (interactive)
  (let* ((heading-titles (mapcar (lambda (heading)
                                   (nth 4 heading))
                                 (org-headings-to-point)))
         (level 0)
         (hierarchy (mapcar (lambda (title)
                              (prog1
                                  (if (zerop level)
                                      (concat "• " title)
                                    (concat "\n" 
                                            (make-string (* level 2) ? )
                                            "→ " title))
                                (setq level (1+ level))))
                            heading-titles)))
    (display-message-or-buffer (string-join hierarchy))))

^ permalink raw reply	[flat|nested] 12+ messages in thread

end of thread, other threads:[~2019-12-05 22:37 UTC | newest]

Thread overview: 12+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2019-12-03  2:56 [PROPOSAL] New function `org-headings-to-point' and displayer Karl Fogel
2019-12-03  7:30 ` Diego Zamboni
2019-12-03  8:47 ` Cheong Yiu Fung
2019-12-03 22:06 ` Adam Porter
2019-12-03 23:34   ` Karl Fogel
2019-12-04  2:38     ` Adam Porter
2019-12-05  3:04       ` Karl Fogel
2019-12-05  8:42         ` Adam Porter
2019-12-05  8:47         ` Adam Porter
2019-12-05 22:36           ` Karl Fogel
2019-12-03 23:36   ` Karl Fogel
2019-12-04  2:20     ` Adam Porter

Code repositories for project(s) associated with this public inbox

	https://git.savannah.gnu.org/cgit/emacs/org-mode.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).